Получить текст из буфера обмена с помощью GetText - избежать ошибки в пустом буфере обмена

Я использую такой код, чтобы получить текст из буфера обмена.

Dim DataObj As New MSForms.DataObject
DataObj.GetFromClipboard
myString = DataObj.GetText

Я использую обработку ошибок, чтобы забыть о случае, когда буфер обмена пуст, и все в порядке, пока я сохраняю функцию "Перехват ошибок" на "Разрыв необработанных ошибок".

Однако по несвязанным причинам я хочу установить функцию "Перехват ошибок" на "Разрыв всех ошибок", и это приводит к ошибке в DataObj.GetText когда он находит пустой буфер обмена. Есть ли какой-нибудь тест, который я могу применить дальше, чтобы не пытаться обработать пустой буфер обмена?

Источник

3 ответа

Решение

Это помогает?

Sub GetClipBoardText()
   Dim DataObj As MSForms.DataObject
   Set DataObj = New MsForms.DataObject '<~~ Amended as per jp's suggestion

   On Error GoTo Whoa

   '~~> Get data from the clipboard.
   DataObj.GetFromClipboard

   '~~> Get clipboard contents
   myString = DataObj.GetText(1)
   MsgBox myString

   Exit Sub
Whoa:
   If Err <> 0 Then MsgBox "Data on clipboard is not text or is empty"
End Sub

Вы заметите, что он будет обрабатывать и пустой буфер обмена.

Вы можете очистить буфер обмена перед тестированием приведенного выше кода, используя приведенный ниже код. Пожалуйста, вставьте его в модуль.

Private Declare Function OpenClipboard Lib "User32.dll" _
(ByVal hWndNewOwner As Long) As Long

Private Declare Function EmptyClipboard Lib "User32.dll" () As Long

Private Declare Function CloseClipboard Lib "User32.dll" () As Long

Public Sub ClearClipboard()
    Dim Ret

    Ret = OpenClipboard(0&)
    If Ret <> 0 Then Ret = EmptyClipboard
    CloseClipboard
End Sub

РЕДАКТИРОВАТЬ: новый запрос от OP

Private Declare Function CountClipboardFormats Lib "user32" () As Long

Sub Sample()
    If (CountClipboardFormats() = 0) = True Then
        MsgBox "Clipboard is empty"
    Else
        MsgBox "Clipboard is not empty"
    End If
End Sub
Источник

Надеюсь, это поможет кому-то еще:

Я получаю сообщение об ошибке "Определяемый пользователем тип не определен" в коде, опубликованном siddharth-rout

Оказывается, библиотека "Библиотека объектов Microsoft Forms 2.0" отсутствует / не активирована.

Получил это работать с этим ( http://excel-macro.tutorialhorizon.com/vba-excel-reference-libraries-in-excel-workbook/):

"Иногда вы не можете найти нужные ссылки в списке, например, вы не найдете" Библиотеку объектов Microsoft Forms 2.0 "в списке инструментов / ссылок, в этом случае вам нужно просмотреть файл FM20.DLL из system32".

Источник

Добавить следующий код, просто b4, разрыв строки для отладки.... ошибка исчезла для меня после этого теста.. странно, но это как-то работает (Excel 2010)

myString = DataObj.GetText(1)
MsgBox myString
Источник
Другие вопросы по тегам