Сортировка детей по значению в Орме

Question

Я знаю, что могу установить конкретный orderby атрибут при создании компонентов, и я могу добавить то же самое к EntityLoad метод. Что, если мне придется как-то сортировать детей сущности?

<cfset u = entityLoadByPk('user', 1)>
<cfset p = u.getPages()> <!-- sort by date? -->

Спасибо!

Answer 1

Использовать orderBy атрибут в определении свойства ваших отношений:

component name="user" accessors=true persistent=true{

 property name="pages" fieldType="one-to-many" cfc="Page" fkColumn="userID" orderBy="date";

}

РЕДАКТИРОВАТЬ

Выше будет установлен порядок по умолчанию дочерних объектов. Чтобы разрешить другие варианты упорядочения, вы можете создать метод упорядочивания страниц в сущности "Пользователь", используя OrmExecuteQuery():

array function pagesOrdered( string column="", string direction="ASC" ){
 //use an array to build up the HQL string
 var hql=[ "FROM Page WHERE User.ID = :userID" ];
 //only allow ordering on specified columns
 if( "title,viewcount,updated".ListFindNoCase( arguments.column ) ){
  hql.Append( "ORDER BY " & arguments.column );
 }
 if( arguments.direction IS NOT "ASC" ){
  hql.Append( "DESC" );
 }
 hql=hql.ToList( " " );
 return OrmExecuteQuery( hql, { userID: variables.ID } );
}

Или для более краткого, но менее ортодоксального подхода попробуйте фильтр гибернации:

array function pagesOrdered( string column="", string direction="ASC" ){
 //use an array to build up the filter
 var filterString=[ "ORDER BY" ];
 //only allow ordering on specified columns
 if( "title,viewcount,updated".ListFindNoCase( arguments.column ) ){
  filterString.Append( arguments.column );
 } else {
  filterString.Append( "dateCreated" );
 }
 if( arguments.direction IS "DESC" ){
  filterString.Append( "DESC" );
 }
 return OrmGetSession().createFilter( variables.pages,filterString.ToList( " " ) ).list();
}