Как мне преобразовать строку в и из JSON с помощью экранированных / специальных символов, используя DBXJSON?

Question

У меня возникли проблемы с преобразованием строки с экранированными символами в TJsonString и из нее. (Я использую Delphi XE 2, обновление 4, исправление 1).

ПРИМЕЧАНИЕ: я знаком с SuperObject, но мои требования - использовать модуль DBXJSON.

Похоже, что TJSONString неправильно экранируется при возврате представления JSON через метод ToString().

Что (если что-то) я делаю неправильно и как правильно преобразовать строку со специальными символами в / из ее правильного представления JSON?

Возможно, я что-то пропустил, но ни один из следующих вопросов и ответов, казалось, не обращался к этому напрямую:

• Delphi декодировать JSON / UTF8 экранированный текст
• Библиотека Delphi JSON для XE2 доступна для сериализации объектов
• Delphi: массив JSON
• Как разобрать вложенный объект JSON в Delphi XE2?
• Десериализация вложенного объекта json с использованием Delphi 2012

РЕДАКТИРОВАТЬ:

Как оказалось, приведенные ниже примеры действительно работали, как и ожидалось.

Что мне не было ясно, так это то, что при создании TJSONString через его конструктор и добавлении его в TJSONObject метод ToString() возвращает экранированное представление. Однако после анализа TJSONObject метод ToString() вернет неэкранированное представление.

Единственным другим предупреждением было то, что функция EscapeString() в приведенном ниже примере кода обрабатывает двойные кавычки. Хотя я не использовал здесь двойные кавычки, некоторые другие мои коды были, и это вызвало сбой синтаксического анализа, потому что TJSONString уже экранирует этот символ. Я обновил мой пример кода, чтобы удалить эту обработку из функции EscapeString(), которую я использовал в своих собственных классах.

Еще раз спасибо @Linas за ответ, который помог мне "получить" его.

Необработанное строковое значение:

Text := 'c:\path\name' +#13 + #10 + 'Next Line';

Text: c:\path\name
Next Line

Что DBXJSON производит (без побегов):

JsonString: "c:\path\name
Next Line"

JsonPair: "MyString":"c:\path\name
Next Line"

JsonObject: {"MyString":"c:\path\name
Next Line"}

Синтаксический анализ текста без ошибок:

Text to parse: {"MyString":"c:\path\name
Next Line"}

Parsed JsonObject = *NIL*

Что я ожидаю DBXJSON для производства:

Escaped String: c:\\path\\name\r\nNext Line

JsonString: "c:\\path\\name\r\nNext Line"

JsonPair: "MyString":"c:\\path\\name\r\nNext Line"

JsonObject: {"MyString":"c:\\path\\name\r\nNext Line"}

Синтаксический анализ ESCAPED Text (INVALID) (текст для анализа проверен с помощью JSONLint):

Text to parse: {"MyString":"c:\\path\\name\r\nNext Line"}

Parsed JsonObject.ToString(): {"MyString":"c:\path\name
Next Line"}

Я заметил, что единственный специальный символ, который TJSONString обрабатывает правильно, это двойная кавычка (").

Вот код, который я использую:

program JsonTest;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, DbxJson;

function EscapeString(const AValue: string): string;
const
  ESCAPE = '\';
  // QUOTATION_MARK = '"';
  REVERSE_SOLIDUS = '\';
  SOLIDUS = '/';
  BACKSPACE = #8;
  FORM_FEED = #12;
  NEW_LINE = #10;
  CARRIAGE_RETURN = #13;
  HORIZONTAL_TAB = #9;
var
  AChar: Char;
begin
  Result := '';
  for AChar in AValue do
  begin
    case AChar of
      // !! Double quote (") is handled by TJSONString
      // QUOTATION_MARK: Result := Result + ESCAPE + QUOTATION_MARK;
      REVERSE_SOLIDUS: Result := Result + ESCAPE + REVERSE_SOLIDUS;
      SOLIDUS: Result := Result + ESCAPE + SOLIDUS;
      BACKSPACE: Result := Result + ESCAPE + 'b';
      FORM_FEED: Result := Result + ESCAPE + 'f';
      NEW_LINE: Result := Result + ESCAPE + 'n';
      CARRIAGE_RETURN: Result := Result + ESCAPE + 'r';
      HORIZONTAL_TAB: Result := Result + ESCAPE + 't';
      else
      begin
        if (Integer(AChar) < 32) or (Integer(AChar) > 126) then
          Result := Result + ESCAPE + 'u' + IntToHex(Integer(AChar), 4)
        else
          Result := Result + AChar;
      end;
    end;
  end;
end;

procedure Test;
var
  Text: string;
  JsonString: TJsonString;
  JsonPair: TJsonPair;
  JsonObject: TJsonObject;
begin
  try
    Writeln('Raw String Value');
    Writeln('-----------------');
    Text := 'c:\path\name' +#13 + #10 + 'Next Line';
    Writeln('Text: ', Text);
    JsonString := TJsonString.Create(Text);
    JsonPair := TJsonPair.Create('MyString', JsonString);
    JsonObject := TJsonObject.Create(JsonPair);
    // DBXJSON results
    Writeln;
    Writeln('What DBXJSON produces');
    Writeln('---------------------');
    Writeln('JsonString: ', JsonString.ToString);
    Writeln;
    Writeln('JsonPair: ', JsonPair.ToString);
    Writeln;
    Writeln('JsonObject: ', JsonObject.ToString);
    Writeln;

    // assign JSON representation
    Text := JsonObject.ToString;
    // free json object
    JsonObject.Free;
    // parse it
    JsonObject:= TJsonObject.ParseJsonValue(TEncoding.ASCII.GetBytes(
      Text), 0) as TJsonObject;
    Writeln('Parsing UN-escaped Text *FAILS* ');
    Writeln('----------------------------------');
    Writeln('Text to parse: ', Text);
    Writeln;
    if (JsonObject = nil) then
      Writeln('Parsed JsonObject = *NIL*')
    else
      Writeln('Parsed JsonObject: ', JsonObject.ToString);
    Writeln;
    // free json object
    JsonObject.Free;
    // expected results
    Text := 'c:\path\name' +#13 + #10 + 'Next Line';
    Text := EscapeString(Text);
    JsonString := TJsonString.Create(Text);
    JsonPair := TJsonPair.Create('MyString', JsonString);
    JsonObject := TJsonObject.Create(JsonPair);
    Writeln('What I *EXPECT* DBXJSON to produce');
    Writeln('----------------------------------');
    Writeln('Escaped String: ', Text);
    Writeln;
    Writeln('JsonString: ', JsonString.ToString);
    Writeln;
    Writeln('JsonPair: ', JsonPair.ToString);
    Writeln;
    Writeln('JsonObject: ', JsonObject.ToString);
    Writeln;
    // assign JSON representation
    Text := JsonObject.ToString;
    // free json object
    JsonObject.Free;
    // parse it
    JsonObject:= TJsonObject.ParseJsonValue(TEncoding.ASCII.GetBytes(
      Text), 0) as TJsonObject;
    Writeln('Parsing ESCAPED Text (*INVALID*) ');
    Writeln('----------------------------------');
    Writeln('Text to parse: ', Text);
    Writeln;
    Writeln('Parsed JsonObject.ToString(): ', JsonObject.ToString);
    Writeln;
    Readln;
  except
    on E: Exception do
    begin
      Writeln(E.ClassName, ': ', E.Message);
      Readln;
    end;
  end;
end;

begin
  Test;
end.

Answer 1

Вы можете попытаться определить свой собственный тип TJSONString и экранировать строки json там. Например:

uses
  DBXJSON;

type
  TSvJsonString = class(TJSONString)
  private
    function EscapeValue(const AValue: string): string;
  public
    constructor Create(const AValue: string); overload;
  end;

{ TSvJsonString }

constructor TSvJsonString.Create(const AValue: string);
begin
  inherited Create(EscapeValue(AValue));
end;

function TSvJsonString.EscapeValue(const AValue: string): string;

  procedure AddChars(const AChars: string; var Dest: string; var AIndex: Integer); inline;
  begin
    System.Insert(AChars, Dest, AIndex);
    System.Delete(Dest, AIndex + 2, 1);
    Inc(AIndex, 2);
  end;

  procedure AddUnicodeChars(const AChars: string; var Dest: string; var AIndex: Integer); inline;
  begin
    System.Insert(AChars, Dest, AIndex);
    System.Delete(Dest, AIndex + 6, 1);
    Inc(AIndex, 6);
  end;

var
  i, ix: Integer;
  AChar: Char;
begin
  Result := AValue;
  ix := 1;
  for i := 1 to System.Length(AValue) do
  begin
    AChar :=  AValue[i];
    case AChar of
      '/', '\', '"':
      begin
        System.Insert('\', Result, ix);
        Inc(ix, 2);
      end;
      #8:  //backspace \b
      begin
        AddChars('\b', Result, ix);
      end;
      #9:
      begin
        AddChars('\t', Result, ix);
      end;
      #10:
      begin
        AddChars('\n', Result, ix);
      end;
      #12:
      begin
        AddChars('\f', Result, ix);
      end;
      #13:
      begin
        AddChars('\r', Result, ix);
      end;
      #0 .. #7, #11, #14 .. #31:
      begin
        AddUnicodeChars('\u' + IntToHex(Word(AChar), 4), Result, ix);
      end
      else
      begin
        if Word(AChar) > 127 then
        begin
          AddUnicodeChars('\u' + IntToHex(Word(AChar), 4), Result, ix);
        end
        else
        begin
          Inc(ix);
        end;
      end;
    end;
  end;
end;

Пример использования:

procedure Test;
var
  LText, LEscapedText: string;
  LJsonString: TSvJsonString;
  LJsonPair: TJsonPair;
  LJsonObject: TJsonObject;
begin
  LText := 'c:\path\name' + #13 + #10 + 'Next Line';
  LJsonString := TSvJsonString.Create(LText);
  LJsonPair := TJsonPair.Create('MyString', LJsonString);
  LJsonObject := TJsonObject.Create(LJsonPair);
  try
    LEscapedText := LJsonObject.ToString;
    //LEscapedText is: c:\\path\\name\r\nNext Line
  finally
    LJsonObject.Free;
  end;
end;

И вот как должен выполняться анализ:

//AText := '{"MyString":"c:\\path\\name\r\nNext Line"}';
function Parse(const AText: string): string;
var
  obj: TJSONValue;
begin
  obj := TJSONObject.ParseJSONValue(AText);
  try
    Result := obj.ToString;
    //Result := {"MyString":"c:\path\name
   //Next Line"}
  finally
    obj.Free;
  end;
end;

Answer 2

Мы только столкнулись с этой прекрасной проблемой, где наши обратные слэши не избежали (но наши двойные кавычки были, очевидно, лол)...

Решением было прекратить использовать ToString и использовать вместо него ToJSON...

TJSONObject.ToJSON

Это дает вам правильно экранированную строку, в отличие от читаемого человеком формата, который возвращает ToString.

Надеюсь, это поможет кому-то:)

Answer 3

Я столкнулся с той же проблемой с Delphi XE2. Моим решением было изменить файл библиотеки Data.DBXJSON.pas. Я скопировал исходный файл в свой каталог PatchedLibraryXE2 (кто первый в моем пути к библиотеке). Здесь я изменил способ

function TJSONString.ToString: UnicodeString;
begin
  if FStrBuffer <> nil then
//    Exit('"' + AnsiReplaceStr(FStrBuffer.ToString, '"', '\"') + '"');
    Exit('"' + EscapeValue(FStrBuffer.ToString) + '"');
  Result := NullString;
end;

Я использовал метод побега Линаса в его ответе выше. Я не использовал escape-символы для символов больше 127. Для компиляции мне также нужно было скопировать файл Data.DBXCommon.pas в каталог PatchedLibraryXE2. Теперь мой TJSONObject.ToString() работает как положено.