Запись в двоичный файл

Question

Я пытаюсь записать двоичный файл STL в Fortran 90. Файл имеет следующий формат

HEADER: 80-байтовый заголовок ASCII - TITLE

4-байтовое целое число без знака, NO. ЛИЦ

ФОРМАТ ДЛЯ КАЖДОГО ЛИЦА:

Нормальный вектор, 3 плавающих значения по 4 байта каждое;

Вершина 1 XYZ координаты, 3 плавающих значения по 4 байта каждая;

Вершина 2 XYZ координаты, 3 плавающих значения по 4 байта каждая;

Вершина 3 координаты XYZ, 3 плавающих значения по 4 байта каждая;

Целое число без знака, 2 байта, которое должно быть нулем;

Я пытаюсь создать неформатированный файл для записи соответствующей информации, но у меня возникают проблемы с определением правильной длины записи. Предполагая, что у меня есть N аспектов, я использую следующие команды для открытия и записи информации

open(unit = 1, status = 'replace', iostat = ioerror, format = 'unformatted', access = 'direct', recl = 84 + N * 50, file = 'c:\temp\test.stl')

Могу ли я выполнить первый оператор write для записи информации заголовка, за которым следует второй оператор write (в цикле do) для записи информации о фасете?

Если так, какой номер записи мне нужно иметь для каждого оператора записи, поскольку у меня есть заголовок и информация о фасете с различной длиной записи.

write(1,rec=?), *header information*
do,i=1,N,1
   write(1,rec=?), *facet information*
enddo

Answer 1

Это было интересно. Я взломал небольшую программу, которая создает очень простую пирамиду, используя STREAM доступ. Похоже на работу

program write_stl
    use ISO_FORTRAN_ENV
    implicit none
    integer, parameter :: u = 400
    character(len=*), parameter :: fname = 'pyramid.stl'
    integer :: ios
    integer(kind=4) :: num_facets
    character(len=80) :: title
    real(kind=4), dimension(3) :: top_vertex, front_vertex, left_vertex, right_vertex

    top_vertex = (/0.0, 0.0, 2.0/)
    front_vertex = (/0.0, -1.0, 0.0/)
    left_vertex = (/-1.0, 1.0, 0.0/)
    right_vertex = (/1.0, 1.0, 0.0/)

    open(unit=u, file=fname, access='stream', status='replace', &
        action='write', iostat=ios)
    call check(ios, 'open')

    title = "Testpyramid"
    write(u, iostat=ios) title
    call check(ios, 'write title')
    num_facets = 4
    write(u, iostat=ios) num_facets
    call check(ios, 'write number of facets')
    ! bottom facet
    call write_facet(u, front_vertex, left_vertex, right_vertex)
    call write_facet(u, top_vertex, right_vertex, left_vertex)
    call write_facet(u, top_vertex, left_vertex, front_vertex)
    call write_facet(u, top_vertex, front_vertex, right_vertex)

    close(u, iostat=ios)
    call check(ios, 'close')

contains

    subroutine check(ios, operation)
        implicit none
        integer, intent(in) :: ios
        character(len=*), intent(in) :: operation
        if (ios == 0) return
        write(*, '(A, I0, 2A)') "Encountered error ", ios, " while performing ", operation
        stop 1
    end subroutine check

    subroutine write_facet(u, vertex1, vertex2, vertex3)
        implicit none
        integer, intent(in) :: u
        real(kind=4), dimension(3), intent(in) :: vertex1, vertex2, vertex3
        real(kind=4), dimension(3) :: normal
        integer(kind=2), parameter :: zero = 0

        normal = calc_normal(vertex1, vertex2, vertex3)
        write(u, iostat=ios) normal
        call check(ios, 'write normal')
        write(u, iostat=ios) vertex1
        call check(ios, 'write vertex')
        write(u, iostat=ios) vertex2
        call check(ios, 'write vertex')
        write(u, iostat=ios) vertex3
        call check(ios, 'write vertex')
        write(u, iostat=ios) zero
        call check(ios, 'write zero')
    end subroutine write_facet

    function calc_normal(vec1, vec2, vec3)
        implicit none
        real(kind=4), dimension(3), intent(in) :: vec1, vec2, vec3
        real(kind=4), dimension(3) :: calc_normal
        real(kind=4), dimension(3) :: d1, d2
        d1 = vec2 - vec1
        d2 = vec3 - vec1
        calc_normal(1) = d1(2) * d2(3) - d1(3) * d2(2)
        calc_normal(2) = d1(3) * d2(1) - d1(1) * d2(3)
        calc_normal(3) = d1(1) * d2(2) - d1(2) * d2(1)
        calc_normal = calc_normal / norm(calc_normal)
    end function calc_normal

    function norm(vec)
        implicit none
        real(kind=4), dimension(3), intent(in) :: vec
        real(kind=4) :: norm

        norm = sqrt(vec(1)**2 + vec(2)**2 + vec(3)**2)
    end function norm

end program write_stl