Распаковать несколько переменных из последовательности

Я ожидаю, что код ниже, чтобы напечатать chr7,

import strutils

var splitLine = "chr7    127471196  127472363  Pos1  0  +".split()
var chrom, startPos, endPos = splitLine[0..2]
echo chrom

Вместо этого он печатает @[chr7, 127471196, 127472363],

Есть ли способ распаковать несколько значений из последовательностей одновременно?

И каким был бы самый краткий способ сделать это, если бы элементы не были смежными? Например:

var chrom, startPos, strand = splitLine[0..1, 5]

Выдает ошибку:

read_bed.nim(8, 40) Error: type mismatch: got (seq[string], Slice[system.int], int literal(5))
but expected one of:
system.[](a: array[Idx, T], x: Slice[system.int])
system.[](s: string, x: Slice[system.int])
system.[](a: array[Idx, T], x: Slice[[].Idx])
system.[](s: seq[T], x: Slice[system.int])

  var chrom, startPos, strand = splitLine[0..1, 5]
                                         ^
Источник

2 ответа

Решение

Это можно сделать с помощью макросов.

import macros

macro `..=`*(lhs: untyped, rhs: tuple|seq|array): auto =
  # Check that the lhs is a tuple of identifiers.
  expectKind(lhs, nnkPar)
  for i in 0..len(lhs)-1:
    expectKind(lhs[i], nnkIdent)
  # Result is a statement list starting with an
  # assignment to a tmp variable of rhs.
  let t = genSym()
  result = newStmtList(quote do:
    let `t` = `rhs`)
  # assign each component to the corresponding
  # variable.
  for i in 0..len(lhs)-1:
    let v = lhs[i]
    # skip assignments to _.
    if $v.toStrLit != "_":
      result.add(quote do:
        `v` = `t`[`i`])

macro headAux(count: int, rhs: seq|array|tuple): auto =
  let t = genSym()
  result = quote do:
    let `t` = `rhs`
    ()
  for i in 0..count.intVal-1:
    result[1].add(quote do:
      `t`[`i`])

template head*(count: static[int], rhs: untyped): auto =
  # We need to redirect this through a template because
  # of a bug in the current Nim compiler when using
  # static[int] with macros.
  headAux(count, rhs)

var x, y: int
(x, y) ..= (1, 2)
echo x, y
(x, _) ..= (3, 4)
echo x, y
(x, y) ..= @[4, 5, 6]
echo x, y
let z = head(2, @[4, 5, 6])
echo z
(x, y) ..= head(2, @[7, 8, 9])
echo x, y

..= макрос распаковывает назначения кортежей или последовательностей. Вы можете сделать то же самое с var (x, y) = (1, 2)например, но ..= работает также для секвенций и массивов и позволяет повторно использовать переменные.

head шаблон / макрос извлекает первый count элементы из кортежа, массива или последовательности и возвращает их в виде кортежа (который затем можно использовать как любой другой кортеж, например, для деструктурирования с помощью let или же var).

Источник

Для тех, кто ищет быстрое решение, вот небольшой пакет, который я написал, называется unpack.

Вы можете выполнить распаковку / распаковку последовательности и объекта с помощью следующего синтаксиса:

someSeqOrTupleOrArray.lunpack(a, b, c)
[a2, b2, c2] <- someSeqOrTupleOrArray

{name, job} <- tim

tom.lunpack(job, otherName = name)
{job, name: yetAnotherName} <- john
Источник

В настоящее время сопоставление с образцом в Nim работает только с tuples, Это также имеет смысл, потому что сопоставление с образцом требует статически известной арности. Например, что должно произойти в вашем примере, если seq не имеет длины три? Обратите внимание, что в вашем примере длина последовательности может быть определена только во время выполнения, поэтому компилятор не знает, возможно ли на самом деле извлечь три переменные.

Поэтому я думаю, что решение, которое было связано с @def, шло в правильном направлении. В этом примере используются массивы, которые имеют статически известный размер. В этом случае компилятор знает артерию кортежа, т.е. извлечение хорошо определено.

Если вам нужен альтернативный (возможно, удобный, но небезопасный) подход, вы можете сделать что-то вроде этого:

import macros

macro extract(args: varargs[untyped]): typed =
  ## assumes that the first expression is an expression
  ## which can take a bracket expression. Let's call it
  ## `arr`. The generated AST will then correspond to:
  ##
  ## let <second_arg> = arr[0]
  ## let <third_arg>  = arr[1]
  ## ...
  result = newStmtList()
  # the first vararg is the "array"
  let arr = args[0]
  var i = 0
  # all other varargs are now used as "injected" let bindings
  for arg in args.children:
    if i > 0:
      var rhs = newNimNode(nnkBracketExpr)
      rhs.add(arr)
      rhs.add(newIntLitNode(i-1))

      let assign = newLetStmt(arg, rhs) # could be replaced by newVarStmt
      result.add(assign)
    i += 1
  #echo result.treerepr


let s = @["X", "Y", "Z"]

s.extract(a, b, c)
# this essentially produces:
# let a = s[0]
# let b = s[1]
# let c = s[2]

# check if it works:
echo a, b, c

Я не включил чек на seq длины пока нет, поэтому вы бы просто получили ошибку "за пределами", если у seq нет необходимой длины. Еще одно предупреждение: если первое выражение не является литералом, выражение будет оценено / вычислено несколько раз.

Обратите внимание, что _ допускается использование литерала в привязках let в качестве заполнителя, что означает, что вы можете делать такие вещи:

s.extract(a, b, _, _, _, x)

Это будет решать ваши splitLine[0..1, 5] Например, что, кстати, просто не является допустимым синтаксисом индексации.

Источник

Еще один вариант - пакет definesugar:

import strutils, definesugar

# need to use splitWhitespace instead of split to prevent empty string elements in sequence
var splitLine = "chr7    127471196  127472363  Pos1  0  +".splitWhitespace()
echo splitLine

block:
  (chrom, startPos, endPos) := splitLine[0..2]
  echo chrom # chr7
  echo startPos # 127471196
  echo endPos # 127472363

block:
  (chrom, startPos, strand) := splitLine[0..1] & splitLine[5] # splitLine[0..1, 5] not supported
  echo chrom
  echo startPos
  echo strand # +

# alternative syntax
block:
  (chrom, startPos, *_, strand) := splitLine
  echo chrom
  echo startPos
  echo strand

см. https://forum.nim-lang.org/t/7072 для недавнего обсуждения

Источник
Другие вопросы по тегам