Гретль - как вычислить матрицу

Question

У меня есть модель линейной регрессии:

yi = α + βxi + ui

и я хочу вычислить:

(\sigma_u)^2(X'X)^(-1)

Могу ли я сделать это в gretl и как? Если нет, то как вывести матрицу X из gretl?

Я очень ценю ваш ответ!!!

Answer 1

Вот один из подходов. Если вы хотите узнать больше, я призываю вас прочитать главу 13 руководства по gretl.

open galton
list xlist = const parent child # or list xlist 0 1 2 
matrix X = {xlist}
ols const child parent --quiet
scalar sigma_u = $sigma
matrix res = sigma_u^2 * inv(X'X)
res

##  res
## res (3 x 3)

##    0.0010799  -1.2533e-05  -3.2771e-06 
##  -1.2533e-05   2.7165e-07  -8.8464e-08 
##  -3.2771e-06  -8.8464e-08   1.3688e-07 

Answer 2

dickoa: я полагаю, ваш ответ хотел быть:

open galton
list xlist = const parent # or list xlist 0 1 2 
matrix X = {xlist}
ols child const parent --quiet
scalar sigma_u = $sigma
matrix res = sigma_u^2 * inv(X'X)
res

В любом случае это еще более простой способ сделать это:

open galton
list xlist = const parent # or list xlist 0 1 2 
matrix X = {xlist}
ols child const parent --quiet
matrix res = $vcv
res