Агрегат-функция для суммы и произведения в XPath

Question

Аналогично этому вопросу (http://stackru.com/q/1333558/948404) Я хочу использовать XPath для расчета суммы по продуктам в структуре, подобной этой:

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

Есть ли выражение XPath, которое вычисляет сумму произведений каждого элемента value а также quantity?

Обновление: решение должно работать с классом PHPs XSLTProcessor, что означает, что оно, вероятно, должно быть совместимо с XSLT 1.0. Вот почему я еще не принял два, вероятно, правильных ответа, используя XSLT 2.0. Я не смог проверить их ни в своей реализации PHP, ни в своем браузере, ни в редакторе Tryit [1] из w3schools. Сожалею!

1. http://w3schools.com/xsl/tryxslt.asp?xmlfile=cdcatalog&xsltfile=cdcatalog

Answer 1

Используйте это выражение XPath 2.0:

sum(/items/item/(value * quantity))

Вот преобразование XSLT 2.0 в качестве проверки:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному документу XML:

<items>
    <item>
        <value>1.0</value>
        <quantity>3</quantity>
    </item>
    <item>
        <value>2.5</value>
        <quantity>2</quantity>
    </item>
    <!-- ... -->
</items>

выражение XPath вычисляется, и результат этой оценки выводится:

8

Пояснение:

В XPath 2.0 законно, чтобы шаг местоположения был

/(expression),

или даже

/someFunction(argumentList)

---

II. Решение XSLT 1.0:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:call-template name="sumProducts">
    <xsl:with-param name="pNodes" select="item"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="sumProducts">
   <xsl:param name="pNodes" select="/.."/>
   <xsl:param name="pAccum" select="0"/>

   <xsl:choose>
    <xsl:when test="not($pNodes)">
     <xsl:value-of select="$pAccum"/>
    </xsl:when>
    <xsl:otherwise>
     <xsl:call-template name="sumProducts">
      <xsl:with-param name="pNodes" select="$pNodes[position() >1]"/>
      <xsl:with-param name="pAccum" select=
      "$pAccum + $pNodes[1]/value * $pNodes[1]/quantity"/>
     </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному XML-документу (см. выше), снова получается нужный, правильный результат:

8

Обратите внимание: такие проблемы легко решить с помощью библиотеки FXSL. Шаблон для вызова transform-and-sum,

Answer 2

Попробуй это:

<xsl:stylesheet version="2.0"xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:sequence select="sum(/items/item/(value * quantity))"/>
    </xsl:template>
</xsl:stylesheet>

Answer 3

Основываясь на этом предложении /questions/31031976/xslt-dlya-summirovaniya-proizvedenij-dvuh-atributov/31031985#31031985 я пришел к решению, совместимому с XSLT 1.0 и XPath 1.0, которые реализованы libxml/libxslt, используемыми PHP-реализацией XSLTProcessor (спасибо @Dimitre Novatchev за подтверждение).

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/items">
        <xsl:call-template name="recursivesum">
            <xsl:with-param name="items" select="*" />
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="recursivesum">
        <xsl:param name="items" />
        <xsl:param name="sum" select="0" />
        <xsl:variable name="head" select="$items[1]" />
        <xsl:variable name="tail" select="$items[position()>1]" />
        <xsl:variable name="thissum" select="$head/value * $head/quantity" />
        <xsl:choose>
            <xsl:when test="not($tail)">
                <xsl:value-of select="$sum+$thissum" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="recursivesum">
                    <xsl:with-param name="sum" select="$sum+$thissum" />
                    <xsl:with-param name="items" select="$tail" />
                </xsl:call-template>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:transform>