Как отформатировать строку в регистр Pascal в XSLT?

Я пытаюсь отформатировать строки в XSLT, которые должны быть в паскале, чтобы использовать их соответствующим образом для приложения, с которым я работаю.

Например:

this_text станет ThisText
this_long_text станет ThisLongText

Можно ли также настроить это, где я могу отправить входные данные в формате, чтобы мне не пришлось повторно создавать формат несколько раз?

Источник

5 ответов

Решение

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vLower" select=
  "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:variable name="vUpper" select=
  "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()">
  <xsl:call-template name="Pascalize">
   <xsl:with-param name="pText" select="concat(., '_')"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="Pascalize">
  <xsl:param name="pText"/>

  <xsl:if test="$pText">
   <xsl:value-of select=
    "translate(substring($pText,1,1), $vLower, $vUpper)"/>

   <xsl:value-of select="substring-before(substring($pText,2), '_')"/>

   <xsl:call-template name="Pascalize">
     <xsl:with-param name="pText"
       select="substring-after(substring($pText,2), '_')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML:

<t>
  <a>this_text</a>
  <b>this_long_text</b>
</t>

дает желаемый результат:

<t>
    <a>ThisText</a>
    <b>ThisLongText</b>
</t>

Кстати, это CamelCase, а это PascalCase

Источник

Вот, спустя два года, это решение XSLT 2.0:

<xsl:function name="fn:pascal-case">
    <xsl:param name="string"/>
    <xsl:value-of select="string-join(for $s in tokenize($string,'\W+') return concat(upper-case(substring($s,1,1)),substring($s,2)),'')"/>
</xsl:function>

Он будет паскализировать 'this_long_text' или 'this-long-text' в 'ThisLongText', потому что он разбит на любые несловарные символы.

В разновидностях регулярных выражений, с которыми я больше всего знаком (perl, pcre и т. Д.), Подчеркивание считается частью класса символов '\w' (поэтому не является частью \W), но для XSLT 2.0 используются типы данных XSD (http://www.w3.org/TR/xmlschema-2/) и '\w' определяется как:

[#x0000-#x10FFFF]-[\p{P}\p{Z}\p{C}] (all characters except the set of "punctuation", "separator" and "other" characters)

поэтому "\ W" включает в себя подчеркивание.

Источник

Эта версия работала для меня. Я добавил выбор, который выводит "остаток" строки, когда больше нет подчеркивания.

<xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

<xsl:template name="Pascalize">
    <xsl:param name="pText" />
    <xsl:if test="$pText">
        <xsl:value-of select="translate(substring($pText,1,1), $vLower, $vUpper)" />
        <xsl:choose>
            <xsl:when test="contains($pText, '_')"> 
                <xsl:value-of select="substring-before(substring($pText,2), '_')" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="substring($pText,2)" />
            </xsl:otherwise>
        </xsl:choose>
        <xsl:call-template name="Pascalize">
            <xsl:with-param name="pText" select="substring-after(substring($pText,2), '_')" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

Кроме того, на случай, если кто-нибудь придет сюда в поисках обратного процесса (который я тоже сегодня требовал и не смог найти ни одного примера где-либо)...

<xsl:variable name="vLower" select="'abcdefghijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

<xsl:template name="TitleCase">
    <xsl:param name="pText" />
    <xsl:call-template name="TitleCase_recurse">
        <xsl:with-param name="pText" select="concat(translate(substring($pText,1,1), $vLower, $vUpper), substring($pText,2))" />
    </xsl:call-template>
</xsl:template>

<xsl:template name="TitleCase_recurse">
    <xsl:param name="pText" />
    <xsl:if test="string-length($pText) &gt; 1">
        <xsl:if test="not(substring($pText,1,1) = ' ' and substring($pText,1,1) = ' ')">
            <xsl:value-of select="substring($pText,1,1)" />
        </xsl:if>
        <xsl:if test="translate(substring($pText,1,1), $vLower, $vUpper) != substring($pText,1,1)">
            <xsl:if test="translate(substring($pText,2,1), $vLower, $vUpper) = substring($pText,2,1)">
                <xsl:text> </xsl:text>
            </xsl:if>
        </xsl:if>
        <xsl:call-template name="TitleCase_recurse">
            <xsl:with-param name="pText" select="substring($pText,2)" />
        </xsl:call-template>
    </xsl:if>
    <xsl:if test="string-length($pText) = 1">
        <xsl:value-of select="$pText" />
    </xsl:if>
</xsl:template>

Мне нравится, когда мое подсознание выдает ответ через несколько часов после того, как я полностью сдался сознательно.;-)

Источник

Я пытался добиться "паскализации" с помощью следующего вызова функции XLST:

<xsl:value-of select="fn:replace(@name,'_(\w{1})','\U$1')"/>

К сожалению, процессор выдает сообщение об ошибке "Неверная строка замены в replace(): за символом \ следует символ \ или $"

проблема заключается в модификаторе \U, который должен выполнять преобразование сопоставленного шаблона в верхнем регистре. Если я изменю это на

<xsl:value-of select="fn:replace(@name,'_(\w{1})','\\U$1')"/>

выходная строка содержит последовательность '\U', потому что она теперь исключена, но я не хочу ее избегать, я хочу, чтобы она была эффективной;-) . Я сделал тест

<xsl:value-of select="fn:replace(@name,'_(\w{1})','$1')"/>

(без преобразования соответствия в верхний регистр), и это прекрасно работает. Но, конечно, он не использует заглавные буквы, а только удаляет подчеркивание и заменяет букву после подчеркивания на себя, а не на заглавную. Я что-то не так делаю или модификатор \U просто не поддерживается в реализации regex моего процессора XSLT?

Источник

Благодаря Димитру, я смог пройти большую часть пути туда. При запуске моих строк через шаблон Pascalize, бит после последнего '_' обрезался. Вероятно, есть более чистый способ сделать это, но вот код, который я использовал:

<xsl:template name="Pascalize">
    <xsl:param name="pText"/>

    <xsl:if test="$pText">
        <xsl:value-of select="translate(substring($pText,1,1), $vLower, $vUpper)"/>

        <xsl:value-of select="substring-before(substring($pText,2), '_')"/>

        <xsl:call-template name="Pascalize">
            <xsl:with-param name="pText" select="substring-after(substring($pText,2), '_')"/>
        </xsl:call-template>

        <xsl:call-template name="GrabLastPart">
            <xsl:with-param name="pText" select="$pText"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template name="GrabLastPart">
    <xsl:param name="pText"/>

    <xsl:choose>
        <xsl:when test="contains($pText, '_')">
            <xsl:call-template name="GrabLastPart">
                <xsl:with-param name="pText" expr="substring-after($pText, '_')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="substring($pText, 2)"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
Источник
Другие вопросы по тегам