Утечка памяти при обработке

Question

Используя Processing, я работаю над проектом, который случайным образом объединяет видеоклипы и строки из текстового файла. Всякий раз, когда я запускаю программу, в конце концов она останавливается, и я получаю беспорядок той же ошибки:

JNA: обратный вызов org.gstreamer.elements.AppSink$3@1bf404f выдал следующее исключение: java.lang.OutofMemoryError: пространство кучи Java

Я подозреваю, что есть утечка памяти с тем, как я обрабатываю создание и освобождение моего объекта Movie, но я не могу понять, что не так. setup() Здесь я впервые создаю экземпляр объекта Movie, чтобы подготовиться к первой итерации. В моем draw()мне кажется, я сбрасываю объект Movie на ноль каждый раз перед тем, как создать его снова, что, на мой взгляд, должно решить проблему с памятью, но, похоже, это не так.

Кто-нибудь может предложить решение? В моих предпочтениях моя память увеличилась до 256 МБ, но я знаю, что увеличение памяти только задерживает неизбежную ошибку. Благодарю вас!

Вот мой код:

import processing.video.*;

PFont font;

String[] posts; // strings loaded in setup()
String[] videos = {"1a.mov", "2a.mov", "3a.mov", "4a.mov", "5a.mov", "6a.mov",
                    "7a.mov", "8a.mov", "9a.mov"}; // video clips

String post;
Post first; // First post
Post p; // Next iteration of posts

Movie myMovie;
String clip;
int count; // Iteration counter

int a = 0; // image()
float duration = 0; // Movie duration
float time = 0; // Movie time

void setup(){

  size(displayWidth, displayHeight);
  background(0);

  posts = loadStrings("posts.txt"); // load strings from file
  font = loadFont("HelveticaNeue-Bold-48.vlw"); // load font
  post = posts[int(random(posts.length))]; // use random post

  textFont(font); // Set text font
  textSize(50);
  textAlign(CENTER);
  fill(255, 248, 43); // Yellow fill

  if (frame != null){
    frame.setResizable(true); // resizable window
  }  

  /** Random generation of initial clip and post */
  clip = videos[int(random(videos.length))];
  myMovie = new Movie(this, clip);
  makeTint();
  myMovie.play();
  count++;
  first = new Post(post);
  println("Playing clip: " + clip + " w/ post: " + "\"" + post + "\"");
  println("Iteration: " + count + "\n");
}

/** Will generate random clips and posts after initial clip **/
void draw(){

  if (a == 0){
    image(myMovie, 0, 0);
  }

  image(myMovie, 0, 0);

  duration = myMovie.duration();
  time = myMovie.time();

  /** If clip is at end **/
  if ((duration - time) < 0.1){

    first = null; // Remove first post

    /** Reset clip **/
    clip = null;
    myMovie = null;
    clip = videos[int(random(videos.length))];
    myMovie = new Movie(this, clip);
    count++;

    makeTint();
    myMovie.play();

    /** Reset post **/
    p = null;
    post = posts[int(random(posts.length))];

    println("Playing clip: " + clip + " w/ post: " + "\"" + post + "\"");
    println("Post length: " + post.length());
    println("Iteration: " + count + "\n");

  }
    p = new Post(post);
}

/** Method needed to play clips **/
void movieEvent(Movie m){  
  m.read();  
}

/** Class for displaying post **/
class Post{

  /*******************************************\
   * Function: Post Object Constructor
   * Parameter Description:
   *-----------------------------------------
   * t, text to display
  \*******************************************/
  Post(String t){
    text(t, width/2, height - 150);  
  }

}

Answer 1

Movie имеет dispose() метод, который, кажется, очищает все распределения gstreamer. Я подозреваю, что это может быть причиной.

В вашем коде попробуйте позвонить: myMovie.dispose(); перед набором myMovie = null Это.

Иногда вам нужно погрузиться в исходный код, чтобы увидеть все, что доступно: https://github.com/processing/processing/blob/master/java/libraries/video/src/processing/video/Movie.java

** Кроме того, увеличение памяти приложения вполне разумно для общего использования. 256МБ довольно мало, у меня установлено 1024МБ. Но я бы исправить эту утечку, прежде чем поднимать ее.

Answer 2

Я сталкиваюсь с той же проблемой, и для меня, по крайней мере, disposte() Метод не решил проблему.

Протестировав и проверив используемую память, я обнаружил, что stop() а также loop() функции продолжают увеличивать память.

Решение, которое я нашел, заключается в использовании jump(0) как только видео закончилось вместо loop() функция и pause() а также jump(0) вместо stop(),

Это остановило утечку памяти для меня.