Сборка 8086: поместить область переменных в начало сегмента кода
У меня есть сегмент кода, который был расположен в секторе 37 файла boot.img, и в своей основной загрузочной записи я загрузил этот код в память 0x5678:0x1234, вот мой код asm:
[BITS 16] ;Set code generation to 16 bit mode
ORG 0x1234 ;set addressing to begin at 0x5678:0x1234
mov ax, cs
mov ds, ax
mov es, ax
call cls ;call routine to clear screen
call dspmsg ;call routine to display message
startdt:
call date
call cvtmo
call cvtday
call cvtcent
call cvtyear
call dspdate
call time
call cvthrs
call cvtmin
call cvtsec
call dsptime
jmp startdt ;use infinite loop to halt?
cls:
mov ah,06h ;function 06h (Scroll Screen)
mov al, 0 ;scroll all lines
mov bh,0x0a ;Attribute (light green on black)
mov ch,0 ;Upper left row is zero
mov cl,0 ;Upper left column is zero
mov dh,24 ;Lower left row is 24
mov dl,79 ;Lower left column is 79
int 10H ;BIOS Interrupt 10h (video services)
ret
dspmsg:
mov ah,13h ;function 13h (Display String)
mov al,0 ;Write mode is zero
mov bh,0 ;Use video page of zero
mov bl,0x0c ;Attribute (light red on black)
mov cx,msglen ;Character string is 25 long
mov dh,3 ;position on row 3
mov dl,[center] ;and column 28
lea bp,[msg] ;load the offset address of string into BP
int 10H
ret
msg: db 'Pradox V 0.1 Jiansong He',10,13
msglen: equ $-msg
int 10H
ret
date:
;Get date from the system
mov ah,04h ;function 04h (get RTC date)
int 1Ah ;BIOS Interrupt 1Ah (Read Real Time Clock)
ret
;CH - Century
;CL - Year
;DH - Month
;DL - Day
cvtmo:
;Converts the system date from BCD to ASCII
mov bh,dh ;copy contents of month (dh) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [dtfld],bh
mov bh,dh
and bh,0fh
add bh,30h
mov [dtfld + 1],bh
ret
cvtday:
mov bh,dl ;copy contents of day (dl) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [dtfld + 3],bh
mov bh,dl
and bh,0fh
add bh,30h
mov [dtfld + 4],bh
ret
cvtcent:
mov bh,ch ;copy contents of century (ch) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [dtfld + 6],bh
mov bh,ch
and bh,0fh
add bh,30h
mov [dtfld + 7],bh
ret
cvtyear:
mov bh,cl ;copy contents of year (cl) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [dtfld + 8],bh
mov bh,cl
and bh,0fh
add bh,30h
mov [dtfld + 9],bh
ret
dtfld: db '00/00/0000'
dspdate:
;Display the system date
mov ah,13h ;function 13h (Display String)
mov al,0 ;Write mode is zero
mov bh,0 ;Use video page of zero
mov bl,0x0a;Attribute
mov cx,10 ;Character string is 10 long
mov dh,4 ;position on row 4
mov dl,[center] ;and column 28
push ds ;put ds register on stack
pop es ;pop it into es register
lea bp,[dtfld] ;load the offset address of string into BP
int 10H
ret
time:
;Get time from the system
mov ah,02h
int 1Ah
ret
;CH - Hours
;CL - Minutes
;DH - Seconds
cvthrs:
;Converts the system time from BCD to ASCII
mov bh,ch ;copy contents of hours (ch) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [tmfld],bh
mov bh,ch
and bh,0fh
add bh,30h
mov [tmfld + 1],bh
ret
cvtmin:
mov bh,cl ;copy contents of minutes (cl) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [tmfld + 3],bh
mov bh,cl
and bh,0fh
add bh,30h
mov [tmfld + 4],bh
ret
cvtsec:
mov bh,dh ;copy contents of seconds (dh) to bh
shr bh,1
shr bh,1
shr bh,1
shr bh,1
add bh,30h ;add 30h to convert to ascii
mov [tmfld + 6],bh
mov bh,dh
and bh,0fh
add bh,30h
mov [tmfld + 7],bh
ret
tmfld: db '00:00:00'
dsptime:
;Display the system time
mov ah,13h ;function 13h (Display String)
mov al,1 ;Write mode is zero
mov bh,0 ;Use video page of zero
mov bl,0x0a;Attribute
mov cx,8 ;Character string is 8 long
mov dh,5 ;position on row 5
mov dl,[center];and column 0
push ds ;put ds register on stack
pop es ;pop it into es register
lea bp,[tmfld] ;load the offset address of string into BP
int 10H
ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;variables;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
center: db 25
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;end variables;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
мой эмулятор - Dosbox, операционная система - Lubuntu, работающая на виртуальной машине Oracle VM, моя собственная операционная система - Win8 x64. Обратите внимание на поле переменной в конце файла, если я поместил этот файл сверху, сразу после того, как обновил DS и ES зарегистрируйтесь, у меня проблема: подпрограммы cls и dspmsg не будут работать, однако, если я изменю значение на center: db 30 или просто поместите это поле в конец моего кода, оно будет работать. Может кто-нибудь объяснить, почему размещение поля переменной поверх моего кода и изменение значения моего ярлыка повлияет на производительность программы? Это имеет отношение к моему регистру сегмента?
вот мой загрузчик:
;bit16 ; 16bit by default
org 0x7c00
jmp short start
nop
bsOEM db "OS423 v.0.1" ; OEM String
start:
;;load sector into memory & 5678h:1234h
mov bx, 0x5678 ;segmented address
mov es, bx ;move segemented address to es
mov bx,0x1234 ;base address to bx
mov ah, 02 ;function read sectors
mov al, 01 ;# of sectors to load
mov ch, 00 ;track to read
mov cl, 02 ;sector to read
mov dh, 00 ;head to read
mov dl, 00 ;drive number
int 0x13 ;call interrupt 13
jmp 0x5678:0x1234 ;jump to memory address
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;variables;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
msg: db 'Welcome to Pradox OS 0.1! Authored by Jiansong he', 10, 13, '$'
mlen equ $-msg
padding times 510-($-$$) db 0 ;to make MBR 512 bytes
bootSig db 0x55, 0xaa ;signature (optional)
1 ответ
Как упомянул Джестер (и я в вашем последнем вопросе), я настоятельно рекомендую использовать отладчик. Этот комментарий был:
Я бы порекомендовал BOCHS для отладки загрузчиков. Он имеет отладчик командной строки, который понимает адресацию в реальном режиме и может использоваться для просмотра инструкций по мере их выполнения, установки точек останова, отображения регистров, проверки памяти и т. Д.
Если вы хотите увидеть, что произошло, когда вы разместили center: db 25 в верхней части кода вы можете использовать NDISASM для вывода закодированных инструкций. Предполагая, что ваш второй этап еще dt.bin Вы можете использовать эту команду, чтобы получить дизассемблированный вывод этого двоичного файла:
ndisasm -b16 dt.bin
Эта команда разобрана dt.bin с предположением, что это 16-битные инструкции. Если бы вы были на месте center: db 25 перед кодом в верхней части dt.asm и собрав dt.bin и выполнив команду выше, вы получите что-то вроде этого:
00000000 198CC88E sbb [si-0x7138],cx 00000004 D88EC0E8 fmul dword [bp-0x1740] 00000008 2600E8 es add al,ch 0000000B 3400 xor al,0x0 0000000D E86600 call word 0x76
Это не тот код, который вы ожидали! Где это значение 25? Вывод в шестнадцатеричном виде. Это 25 десятичное число 0x19. Если вы посмотрите, что первая инструкция декодирования 198CC88E вот увидишь 19 это первый байт. Этот единственный байт превратил декодирование команд в полную чепуху.
Что произойдет, если вы измените center: db 25 в center: db 30? Если вы попытаетесь собрать его и снова использовать команду NDISASM, вы должны увидеть это:
00000000 1E push ds 00000001 8CC8 mov ax,cs 00000003 8ED8 mov ds,ax 00000005 8EC0 mov es,ax 00000007 E82600 call word 0x30
30 десятичное - 0x1e. Как заметил Джестер, 0x1e является инструкцией сама по себе push ds, Эта однобайтовая инструкция делает что-то бесполезное, но все последующие инструкции соответствуют вашим ожиданиям. Размещение данных над кодом при выводе в двоичные файлы, как это, используя -f bin с NASM может вызвать необычные проблемы. По этой причине лучше размещать ваши данные после кода, где они не будут мешать декодированию команд.