Воспроизведите функцию `expand.grid` из R в Julia

expand.grid это очень удобная функция в R для расчета всех возможных комбинаций из нескольких списков. Вот как это работает:

> x = c(1,2,3)
> y = c("a","b")
> z = c(10,12)
> d = expand.grid(x,y,z)
> d
   Var1 Var2 Var3
1     1    a   10
2     2    a   10
3     3    a   10
4     1    b   10
5     2    b   10
6     3    b   10
7     1    a   12
8     2    a   12
9     3    a   12
10    1    b   12
11    2    b   12
12    3    b   12

Как я могу воспроизвести эту функцию в Юлии?

Источник

5 ответов

Решение

Благодаря комментарию @Henrik:

using Iterators    
x = [1,2,3]
y = ["a","b"]
z = [10,12]
d = collect(product(x,y,z))

Вот еще одно решение, использующее понимание списка

reshape([ [x,y,z]  for x=x, y=y, z=z ],length(x)*length(y)*length(z))
Источник

Вот мое полностью (?) Общее решение с использованием рекурсии, переменных и сплаттинга:

function expandgrid(args...)
    if length(args) == 0
        return Any[]
    elseif length(args) == 1
        return args[1]
    else
        rest = expandgrid(args[2:end]...)
        ret  = Any[]
        for i in args[1]
            for r in rest
                push!(ret, vcat(i,r))
            end
        end
        return ret
    end
end

eg = expandgrid([1,2,3], ["a","b"], [10,12])
@assert length(eg) == 3*2*2
@show eg

Это дает массив массивов, но вы можете объединить это в матрицу тривиально, если это то, что вы хотели.

Источник

Я знаю, что это довольно старый вопрос, но я также преобразовал функцию expand.grid из R в Julia почти построчно за несколько дней до того, как нашел этот пост... Он все еще может быть интересен для кого-то, потому что он возвращает DataFrame, что может быть удобнее. Вот ссылка на Gist, а вот код на всякий случай:

using DataFrames

"""
Create a Data Frame from All Combinations of Factor Variables (see R's base::expand.grid)
# Arguments
... Array, Dict, or Tuple containing at least one value
# Return
A DataFrame containing one row for each combination of the supplied argument. The first factors vary fastest.
# Examples
```julia
expand_grid([1,2],["owl","cat"])
expand_grid((1,2),("owl","cat"))
expand_grid((1,2)) # -> Returns a DataFrame with 2 rows of 1 and 2.
```
"""
function expand_grid(args...)
    nargs= length(args)

    if nargs == 0
      error("expand_grid need at least one argument")
    end

    iArgs= 1:nargs
    nmc= "Var" .* string.(iArgs)
    nm= nmc
    d= map(length, args)
    orep= prod(d)
    rep_fac= [1]
    # cargs = []

    if orep == 0
        error("One or more argument(s) have a length of 0")
    end

    cargs= Array{Any}(undef,orep,nargs)

    for i in iArgs
        x= args[i]
        nx= length(x)
        orep= Int(orep/nx)
        mapped_nx= vcat(map((x,y) -> repeat([x],y), collect(1:nx), repeat(rep_fac,nx))...)
        cargs[:,i] .= x[repeat(mapped_nx,orep)]
        rep_fac= rep_fac * nx
    end

    convert(DataFrame,cargs)
end
Источник 
      using DataFrames

function expand_grid(; kw...)
  values = [v for (_, v) in kw]
  names = keys(kw) |> collect
  DataFrame(collect(Iterators.product(values...))[:], names)
end

julia> dims = (x = 1:2, y = [3, 4], z = ["a", "b", "c"]);

julia> expand_grid(;dims...)
12×3 DataFrame
 Row │ x      y      z      
     │ Int64  Int64  String 
─────┼──────────────────────
   1 │     1      3  a
   2 │     2      3  a
   3 │     1      4  a
   4 │     2      4  a
   5 │     1      3  b
   6 │     2      3  b
   7 │     1      4  b
   8 │     2      4  b
   9 │     1      3  c
  10 │     2      3  c
  11 │     1      4  c
  12 │     2      4  c
Источник

Я знаю, что это старый вопрос, но в случае, если кто-то все еще ищет решение, которое работает как функция R expand.grid (т.е. передает список именованных переменных любого типа и возвращает фрейм данных с именами переменных в качестве имен столбцов, каждый столбец типа исходной переменной и все возможные комбинации различных переменных), это моя попытка Julia-новичка:

      using DataFrames

function expand_grid(; iters...)
    var_names = collect(keys(iters))
    var_itr = [1:length(x) for x in iters.data]
    var_ix = vcat([collect(x)' for x in Iterators.product(var_itr...)]...)
    out = DataFrame()
    for i = 1:length(var_names)
        out[:,var_names[i]] = collect(iters[i])[var_ix[:,i]]
    end
    return out
end

expand_grid(a=1:2, b=1.0:5.0, c=["one", "two", "three", "four"])

Скорее всего, есть более эффективный или чистый способ сделать это, но это лучшее, что я мог придумать, чтобы дать мне то, что я ожидаю от функции R.

Источник
Другие вопросы по тегам