Groovy HttpBuilder - получить ответ об ошибке

Question

Я пытаюсь использовать Groovy HTTPBuilder для написания интеграционного теста, который проверит правильное сообщение об ошибке в теле и сообщение о состоянии HTTP 409. Тем не менее, я не могу понять, как на самом деле получить доступ к телу HTTP-ответа в случаях сбоя.

http.request(ENV_URL, Method.POST, ContentType.TEXT) {
    uri.path = "/curate/${id}/submit"
    contentType = ContentType.JSON
    response.failure = { failresp_inner ->
        failresp = failresp_inner
    }
}

then:
assert failresp.status == 409
// I would like something like 
//assert failresp.data == "expected error message"

Вот как выглядит HTTP-ответ от сервера:

2013-11-13 18:17:58,726 DEBUG  wire - << "HTTP/1.1 409 Conflict[\r][\n]"
2013-11-13 18:17:58,726 DEBUG  wire - << "Date: Wed, 13 Nov 2013 23:17:58 GMT[\r][\n]"
2013-11-13 18:17:58,726 DEBUG  wire - << "Content-Type: text/plain[\r][\n]"
2013-11-13 18:17:58,726 DEBUG  wire - << "Transfer-Encoding: chunked[\r][\n]"
2013-11-13 18:17:58,727 DEBUG  wire - << "[\r][\n]"
2013-11-13 18:17:58,728 DEBUG  wire - << "E[\r][\n]"
2013-11-13 18:17:58,728 DEBUG  wire - << "expected error message"
2013-11-13 18:17:58,728 DEBUG  wire - << "[\r][\n]"
2013-11-13 18:17:58,728 DEBUG  wire - << "0[\r][\n]"
2013-11-13 18:17:58,728 DEBUG  wire - << "[\r][\n]"

Answer 1

Недавно я боролся с этим, пытаясь провести интеграционное тестирование моих конечных точек REST с помощью Spock. Я использовал ответ Сэма как источник вдохновения и в итоге улучшил его, чтобы продолжать использовать автоматическое приведение, которое предоставляет HttpBuilder. Поработав некоторое время, у меня появилась блестящая идея просто назначить закрытие обработчика успеха обработчику ошибок, чтобы стандартизировать поведение независимо от того, какой код состояния возвращается.

client.handler.failure = client.handler.success

Пример этого в действии:

...

import static org.apache.http.HttpStatus.*

...

private RESTClient createClient(String username = null, String password = null) {
    def client = new RESTClient(BASE_URL)
    client.handler.failure = client.handler.success

    if(username != null)
        client.auth.basic(username, password)

    return client
}

...

def unauthenticatedClient = createClient()
def userClient = createClient(USER_USERNAME, USER_PASSWORD)
def adminClient = createClient(ADMIN_USERNAME, ADMIN_PASSWORD)

...

def 'get account'() {
    expect:
    // unauthenticated tries to get user's account
    unauthenticatedClient.get([path: "account/$USER_EMAIL"]).status == SC_UNAUTHENTICATED

    // user gets user's account
    with(userClient.get([path: "account/$USER_EMAIL"])) {
        status == SC_OK
        with(responseData) {
            email == USER_EMAIL
            ...
        }
    }

    // user tries to get user2's account
    with(userClient.get([path: "account/$USER2_EMAIL"])) {
        status == SC_FORBIDDEN
        with(responseData) {
            message.contains(USER_EMAIL)
            message.contains(USER2_EMAIL)
            ...
        }
    }

    // admin to get user's account
    with(adminClient.get([path: "account/$USER_EMAIL"])) {
        status == SC_OK
        with(responseData) {
            email == USER_EMAIL
            ...
        }
    }
}

Answer 2

Это работает, если вы используете:

response.failure = { resp, reader ->
    failstatus = resp.statusLine
    failresp   = reader.text
}

Answer 3

Я также боролся с этим, когда начал использовать HttpBuilder. Решение, которое я придумала, состояло в том, чтобы определить успешное и неудачное закрытие HTTPBuilder для получения согласованных значений, например:

HTTPBuilder http = new HTTPBuilder()
http.handler.failure = { resp, reader ->
    [response:resp, reader:reader]
}
http.handler.success = { resp, reader ->
    [response:resp, reader:reader]
}

Определенный таким образом, ваш экземпляр HTTPBuilder будет последовательно возвращать карту, содержащую объект ответа (экземпляр HttpResponseDecorator) и объект чтения. Ваш запрос будет выглядеть так:

def map = http.request(ENV_URL, Method.POST, ContentType.TEXT) {
    uri.path = "/curate/${id}/submit"
    contentType = ContentType.JSON
}

def response = map['response']
def reader = map['reader']

assert response.status == 409

The reader will be some kind of object that'll give you access to the response body, the type of which you can determine by calling the getClass() method:

println "reader type: ${reader.getClass()}"

The reader object's type will be determined by the Content-Type header in the response. You can tell the server specifically what you'd like returned by adding an "Accept" header to the request.