Как войти в DUnitX?

Question

Используя Rad Studio 10 Seattle, DUnitX и TestInsight, мне нужно было бы показать некоторые тексты в консоли или на любом экране журнала. Как это можно сделать? Я не смог найти его в Интернете.

Answer 1

  procedure CreateRunner;
  var fn : TFileName;
  begin
    runner := TDUnitX.CreateRunner;
    runner.UseRTTI := True;

    fn := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName)) + 'dUnitX.Log';

    ConsoleLogger := TDUnitXConsoleLogger.Create(false);
    TextFileLogger:= TDUnitXTextFileLogger.Create(fn);
    nunitLogger   := TDUnitXXMLNUnitFileLogger.Create(TDUnitX.Options.XMLOutputFile);

    runner.AddLogger(ConsoleLogger );
    runner.AddLogger(TextFileLogger);
    runner.AddLogger(nunitLogger);
  end;

Вот как можно добавить сообщения журнала, фрагменты, скопированные с https://github.com/VSoftTechnologies/DUnitX/blob/d5861ce0de6a9fbfdc8c158b0b1c8614082c188d/Examples/DUnitX.Examples.General.pas

 [TestFixture('ExampleFixture1','General Example Tests')]
   TMyExampleTests = class
   public
     [Test]
     procedure LogMessageTypes;
   end;

procedure TMyExampleTests.LogMessageTypes;
begin
  TDUnitX.CurrentRunner.Log(TLogLevel.Information, 'Information');
  TDUnitX.CurrentRunner.Log(TLogLevel.Warning, 'Warning');
  TDUnitX.CurrentRunner.Log(TLogLevel.Error, 'Error');
end;

Если вы хотите иметь менее сложный синтаксис, вы всегда можете добавить промежуточный элемент для Assert класс как так

Assert = class(DUnitX.Assert.Assert) //Or (DunitX.Assert.Ex.Assert)
public
  class procedure Log(const message: string);
end;

class procedure Assert.Log(const message: string);
begin
  TDUnitX.CurrentRunner.Log(TLogLevel.Information, message);
end;

Answer 2

https://github.com/jsf3rd/DUnitX.git/trunk/Examples

var
  runner : ITestRunner;
  logger : ITestLogger;
begin
  try
    //Create the runner
    runner := TDUnitX.CreateRunner;
    runner.UseRTTI := True;

    //tell the runner how we will log things

    if TDUnitX.Options.ConsoleMode <> TDunitXConsoleMode.Off then
    begin
      logger := TDUnitXConsoleLogger.Create(TDUnitX.Options.ConsoleMode = TDunitXConsoleMode.Quiet);
      runner.AddLogger(logger);
    end;

    //Run tests
    results := runner.Execute;

    System.Write('Done.. press <Enter> key to quit.');
    System.Readln;
  except
    on E: Exception do
      System.Writeln(E.ClassName, ': ', E.Message);
  end;