Как выполнять фильтрацию префиксов в нижнем регистре с помощью Stratio Cassandra Lucene Index

Question

Можно ли выполнять фильтрацию / запросы префиксов в нижнем регистре с помощью Stratio Cassandra Lucene Index? Я не смог найти документацию по этому конкретному случаю использования.

Answer 1

Расстановка запросов зависит от того, как труд анализатора текста Lucene используется во время индексации, и не может быть решена во время запроса. Если вы хотите выполнять поиск префиксов без учета регистра, вам следует использовать маппер с анализатором, который выдает термины в нижнем регистре. Эти термины будут проиндексированы и сопоставлены во время поиска. Например:

CREATE KEYSPACE test
WITH REPLICATION = {'class' : 'SimpleStrategy', 'replication_factor': 1};
USE test;
CREATE TABLE test (
    id INT PRIMARY KEY,
    body TEXT
);

CREATE CUSTOM INDEX test_index ON test ()
USING 'com.stratio.cassandra.lucene.Index'
WITH OPTIONS = {
    'refresh_seconds' : '1',
    'schema' : '{
        fields : {
            body1 : {type :"string", column:"body", case_sensitive:false},
            body2 : {type :"string", column:"body", case_sensitive:true}
        }
    }'
};

INSERT INTO test(id,body) VALUES ( 1, 'foo');
INSERT INTO test(id,body) VALUES ( 2, 'Foo');
INSERT INTO test(id,body) VALUES ( 3, 'bar');
INSERT INTO test(id,body) VALUES ( 4, 'Bar');


SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body2", value:"f"}}'); -- Returns foo
SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body2", value:"F"}}'); -- Returns Foo

SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body1", value:"f"}}'); -- Returns foo and Foo
SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body1", value:"F"}}'); -- Returns no results