Async.Start vs Async.StartChild

Question

Если предположить, asyncSendMsg ничего не возвращает, и я хочу запустить его внутри другого асинхронного блока, но не ждать его завершения, есть ли разница между этим:

async {
    //(...async stuff...)
    for msg in msgs do 
        asyncSendMsg msg |> Async.Start
    //(...more async stuff...)
}

а также

async {
    //(...async stuff...)
    for msg in msgs do 
        let! child = asyncSendMsg msg |> Async.StartChild
        ()
    //(...more async stuff...)
}

Answer 1

Основное отличие состоит в том, что при запуске рабочего процесса с Async.StartChild, он поделится токеном отмены с родителем. Если вы отмените родителя, все дети будут также аннулированы. Если вы начинаете ребенка с помощью Async.Startтогда это совершенно независимый рабочий процесс.

Вот минимальный пример, который демонстрирует разницу:

// Wait 2 seconds and then print 'finished'
let work i = async {
  do! Async.Sleep(2000)
  printfn "work finished %d" i }

let main = async { 
    for i in 0 .. 5 do
      // (1) Start an independent async workflow:
      work i |> Async.Start
      // (2) Start the workflow as a child computation:
      do! work i |> Async.StartChild |> Async.Ignore 
  }

// Start the computation, wait 1 second and than cancel it
let cts = new System.Threading.CancellationTokenSource()
Async.Start(main, cts.Token)
System.Threading.Thread.Sleep(1000)    
cts.Cancel()

В этом примере, если вы начинаете вычисления с помощью (1), затем все рабочие элементы будут завершены и распечатаны через 2 секунды. Если вы используете (2) все они будут отменены, когда основной рабочий процесс отменен.