Inno Setup Загрузка значений по умолчанию для пользовательских настроек установки из файла (.inf) для автоматической установки

Question

У меня есть скрипт установки, который позволяет пользователю указать, где он хотел бы установить мое приложение. Это в форме сценария Паскаля в пределах [Code] блок.

var
  SelectUsersPage: TInputOptionWizardPage;
  IsUpgrade : Boolean;
  UpgradePage: TOutputMsgWizardPage;

procedure InitializeWizard();
var
  AlreadyInstalledPath: String;
begin
  { Determine if it is an upgrade... }
  { Read from registry to know if this is a fresh install or an upgrade }
  if RegQueryStringValue(HKLM, 'Software\Microsoft\Windows\CurrentVersion\Uninstall\{#MyAppId}_is1', 'Inno Setup: App Path', AlreadyInstalledPath) then
    begin
      { So, this is an upgrade set target directory as installed before }
      WizardForm.DirEdit.Text := AlreadyInstalledPath;
      { and skip SelectUsersPage }
      IsUpgrade := True;

      { Create a page to be viewed instead of Ready To Install }
      UpgradePage := CreateOutputMsgPage(wpReady,
        'Ready To Upgrade', 'Setup is now ready to upgrade {#MyAppName} on your computer.',
        'Click Upgrade to continue, or click Back if you want to review or change any settings.');
    end
  else
    begin
      IsUpgrade:= False;
    end;

  { Create a page to select between "Just Me" or "All Users" }
  SelectUsersPage := CreateInputOptionPage(wpLicense,
    'Select Users', 'For which users do you want to install the application?',
    'Select whether you want to install the library for yourself or for all users of this computer. Click next to continue.',
    True, False);

  { Add items }
  SelectUsersPage.Add('All users');
  SelectUsersPage.Add('Just me');

  { Set initial values (optional) }
  SelectUsersPage.Values[0] := False;
  SelectUsersPage.Values[1] := True;
end;

Итак, вопрос в том, как я могу поддержать установку без вывода сообщений? Когда пользователь вызывает /SILENT или же /VERYSILENT по умолчанию установщик SelectUsersPage.Values[1]для чего Just Me, Я хочу помочь поддержать пользователя, который хочет изменить каталог установки, предоставив файл ответов.

Я не разрабатывал весь этот код, и я новичок в Паскале.

Благодарю.

Answer 1

Вы можете добавить пользовательский ключ (скажем, Users) к .inf файл, созданный /SAVEINF,

Затем в установщике найдите /LOADINF аргумент командной строки и прочитайте ключ и действуйте соответственно:

procedure InitializeWizard();
var
  InfFile: string;
  I: Integer;
  UsersDefault: Integer;
begin
  ...

  InfFile := ExpandConstant('{param:LOADINF}');

  UsersDefault := 0;

  if InfFile <> '' then
  begin
    Log(Format('Reading INF file %s', [InfFile]));
    UsersDefault :=
      GetIniInt('Setup', 'Users', UsersDefault, 0, 0, ExpandFileName(InfFile));
    Log(Format('Read default "Users" selection %d', [UsersDefault]));
  end
    else
  begin
    Log('No INF file');
  end;

  SelectUsersPage.Values[UsersDefault] := True;
end;