Как динамически ссылаться на другого пользователя базы данных?

Question

У меня есть случай, когда мне нужно обратиться к другому пользователю базы данных. Я имею в виду жесткий код имени пользователя базы данных при обращении к нему.

SELECT * FROM  eg001t3.DUAL; // example.

Есть ли способ обратиться к этому пользователю БД (например,001t3) из представления динамически или на основе настройки базы данных?

Answer 1

В pl/sql вы бы использовали EXECUTE IMMEDIATE или DBMS_SQL для динамической ссылки на объекты.

Пример с EXECUTE IMMEDIATE:

SQL> VARIABLE dyn_user VARCHAR2(30);
SQL> EXEC :dyn_user := 'SYS';

PL/SQL procedure successfully completed
dyn_user
---------
SYS
SQL> DECLARE
  2     ln NUMBER;
  3  BEGIN
  4     EXECUTE IMMEDIATE 'SELECT 1
  5                          FROM ' || dbms_assert.schema_name(:dyn_user) 
  6                                 || '.DUAL'
  7        INTO ln;
  8     dbms_output.put_line(ln);
  9  END;
 10  /

1

PL/SQL procedure successfully completed

Вы также можете использовать динамически созданный REF CURSOR:

SQL> DECLARE
  2     lc SYS_REFCURSOR;
  3     ln NUMBER;
  4  BEGIN
  5     OPEN lc FOR 'SELECT 1
  6                    FROM ' || dbms_assert.schema_name(:dyn_user) || '.DUAL
  7                   CONNECT BY level <= 2';
  8     LOOP
  9        FETCH lc
 10           INTO ln;
 11        EXIT WHEN lc%NOTFOUND;
 12        dbms_output.put_line(ln);
 13     END LOOP;
 14     CLOSE lc;
 15  END;
 16  /

1
1

Как показано, вы можете использовать DBMS_ASSERT для проверки вашего ввода.

Answer 2

Я добавляю новый ответ, чтобы продемонстрировать другой метод, предложенный jva. Все таблицы должны иметь общую структуру (чтобы Oracle мог знать тип данных столбцов представления во время компиляции).

Настроить:

-- create 2 schemas
CREATE USER u1 IDENTIFIED BY u1;
CREATE USER u2 IDENTIFIED BY u2;
GRANT RESOURCE TO u1;
GRANT RESOURCE TO u2;

-- one table in each schema
CREATE TABLE u1.t AS 
   SELECT 2 * ROWNUM ID, 'foo' DATA FROM dual CONNECT BY LEVEL <= 5;
CREATE TABLE u2.t AS 
   SELECT 2 * ROWNUM - 1 ID, 'bar' DATA FROM dual CONNECT BY LEVEL <= 5;
GRANT SELECT ON u2.t TO u1;

-- the common structure
CREATE TYPE u1.t_row AS OBJECT (ID NUMBER, DATA VARCHAR2(3));
/
CREATE TYPE u1.t_row_list AS TABLE OF u1.t_row;
/

CREATE OR REPLACE PACKAGE u1.test_pck IS
   schema_name VARCHAR2(30) := 'U1';
   FUNCTION select_t RETURN u1.t_row_list PIPELINED;
END test_pck;
/

--Definition of the pipelined function and the view:
CREATE OR REPLACE PACKAGE BODY u1.test_pck IS

   FUNCTION select_t RETURN u1.t_row_list PIPELINED IS
      l_rc     SYS_REFCURSOR;
      l_id     NUMBER;
      l_data   VARCHAR2(3);
   BEGIN
      OPEN l_rc FOR 'SELECT id, data 
                       FROM ' || dbms_assert.schema_name(schema_name) || '.t';
      LOOP
         FETCH l_rc
            INTO l_id, l_data;
         EXIT WHEN l_rc%NOTFOUND;
         PIPE ROW (u1.t_row(l_id, l_data));
      END LOOP;
      CLOSE l_rc;
   END select_t;

END test_pck;
/

CREATE OR REPLACE VIEW u1.v AS 
SELECT ID, DATA 
  FROM TABLE(u1.test_pck.select_t);

Затем вы должны определить глобальную переменную в пакете, содержащем имя схемы, а затем запросить представление:

SQL> EXEC u1.test_pck.schema_name := 'U1';

PL/SQL procedure successfully completed
SQL> SELECT * FROM u1.v;

        ID DATA
---------- ----
         2 foo
         4 foo
         6 foo
         8 foo
        10 foo
SQL> EXEC u1.test_pck.schema_name := 'U2';

PL/SQL procedure successfully completed
SQL> SELECT * FROM u1.v;

        ID DATA
---------- ----
         1 bar
         3 bar
         5 bar
         7 bar
         9 bar

Answer 3

Могут быть более элегантные варианты, но вы можете создать синонимы на лету или использовать Dynamic SQL / EXECUTE IMMEDIATE.

Answer 4

Другой вариант, который может работать для вас (в зависимости от среды приложения, из которой вам нужно это сделать), - временно изменить пространство имен на интересующую схему:

1. изменить сессионный набор current_schema = eg001t3;
2. выберите * из таблицы значений независимо от таблицы ToEG001T3; - здесь не нужен квалификатор схемы
3. изменить сеанс set current_schema = ... - вернуться к имени подключаемой схемы

set current_schema никоим образом не обходит модель привилегий Oracle - вам все равно потребуется хотя бы SELECT для таблиц другой схемы, представляющих интерес.