Сопоставление с образцом в начале строки в F#

Question

Я пытаюсь сопоставить начало строк в F#. Не уверен, должен ли я рассматривать их как список символов или как. Мы ценим любые предложения.

Вот версия кода psuedo того, что я пытаюсь сделать

let text = "The brown fox.."

match text with
| "The"::_ -> true
| "If"::_ -> true
| _ -> false

Итак, я хочу посмотреть на начало строки и сопоставить. Обратите внимание, что я не совпадаю в списке строк, только что написал выше, как представление о сути того, что я пытаюсь сделать.

Answer 1

Параметризованные активные шаблоны на помощь!

let (|Prefix|_|) (p:string) (s:string) =
    if s.StartsWith(p) then
        Some(s.Substring(p.Length))
    else
        None

match "Hello world" with
| Prefix "The" rest -> printfn "Started with 'The', rest is %s" rest
| Prefix "Hello" rest -> printfn "Started with 'Hello', rest is %s" rest
| _ -> printfn "neither"

Answer 2

Вы также можете использовать охрану на шаблоне:

match text with
| txt when txt.StartsWith("The") -> true
| txt when txt.StartsWith("If") -> true
| _ -> false

Answer 3

Да, вы должны рассматривать их как список символов, если вы хотите использовать выражение соответствия.

Просто преобразуйте строку с помощью:

let text = "The brown fox.." |> Seq.toList

Тогда вы можете использовать выражение соответствия, но вам придется использовать символы (тип элементов в списке) для каждой буквы:

match text with
| 'T'::'h'::'e'::_ -> true
| 'I'::'f'::_ -> true
| _ -> false

Как Брайан предполагает, что параметризованные активные шаблоны гораздо приятнее, здесь есть несколько полезных шаблонов (перейдите в конец страницы).