Как автоматически установить пакеты Emacs, указав список имен пакетов?
Я использую package управлять моими расширениями Emacs. Чтобы синхронизировать мои настройки Emacs на разных компьютерах, я бы хотел указать список имен пакетов в .emacs файл, а затем package может автоматически искать и устанавливать пакеты, так что мне не нужно устанавливать их вручную, позвонив M-x package-list-packages, Как это сделать?
13 ответов
Основано на комментариях Profpatsch и ответах ниже:
(defun ensure-package-installed (&rest packages)
"Assure every package is installed, ask for installation if it’s not.
Return a list of installed packages or nil for every skipped package."
(mapcar
(lambda (package)
;; (package-installed-p 'evil)
(if (package-installed-p package)
nil
(if (y-or-n-p (format "Package %s is missing. Install it? " package))
(package-install package)
package)))
packages))
;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
(package-refresh-contents))
(ensure-package-installed 'iedit 'magit) ; --> (nil nil) if iedit and magit are already installed
;; activate installed packages
(package-initialize)
; list the packages you want
(setq package-list '(package1 package2))
; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
("gnu" . "http://elpa.gnu.org/packages/")
("marmalade" . "http://marmalade-repo.org/packages/")))
; activate all the packages (in particular autoloads)
(package-initialize)
; fetch the list of packages available
(unless package-archive-contents
(package-refresh-contents))
; install the missing packages
(dolist (package package-list)
(unless (package-installed-p package)
(package-install package)))
Emacs 25.1+ будет автоматически отслеживать установленные пользователем пакеты в настраиваемом package-selected-packages переменная. package-install обновит переменную customize, и вы сможете установить все выбранные пакеты с помощью package-install-selected-packages функция.
Еще одним удобным преимуществом этого подхода является то, что вы можете использовать package-autoremove автоматически удалять пакеты, которые не включены в package-selected-packages (хотя это сохранит зависимости).
(package-initialize)
(unless package-archive-contents
(package-refresh-contents))
(package-install-selected-packages)
Источник: http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html
Вот код, который я использую для Emacs Prelude:
(require 'package)
(require 'melpa)
(add-to-list 'package-archives
'("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)
(setq url-http-attempt-keepalives nil)
(defvar prelude-packages
'(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
gist haml-mode haskell-mode helm helm-projectile inf-ruby
magit magithub markdown-mode paredit projectile
python sass-mode rainbow-mode scss-mode solarized-theme
volatile-highlights yaml-mode yari yasnippet zenburn-theme)
"A list of packages to ensure are installed at launch.")
(defun prelude-packages-installed-p ()
(loop for p in prelude-packages
when (not (package-installed-p p)) do (return nil)
finally (return t)))
(unless (prelude-packages-installed-p)
;; check for new packages (package versions)
(message "%s" "Emacs Prelude is now refreshing its package database...")
(package-refresh-contents)
(message "%s" " done.")
;; install the missing packages
(dolist (p prelude-packages)
(when (not (package-installed-p p))
(package-install p))))
(provide 'prelude-packages)
Если вы не используете MELPA, вам не нужно это требовать (и если вы melpa.el должен быть на вашем load-path (или устанавливается через MELPA). БД пакета не обновляется каждый раз (поскольку это значительно замедлит запуск) - только там, где присутствуют неустановленные пакеты.
Никто еще не упомянул Cask, но он вполне подходит для этой задачи.
В основном вы создаете ~/.emacs.d/Cask список пакетов, которые вы хотите установить. Например:
(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc
Бег cask из командной строки установит эти пакеты для вас и любые зависимости, которые им нужны.
Также вы можете автоматически обновлять установленные пакеты, используя cask update,
(require 'cl)
(require 'package)
(setq cfg-var:packages '(
emmet-mode
ergoemacs-mode
flycheck
flycheck-pyflakes
monokai-theme
py-autopep8
py-isort
rainbow-mode
yafolding
yasnippet))
(defun cfg:install-packages ()
(let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
(when pkgs
(message "%s" "Emacs refresh packages database...")
(package-refresh-contents)
(message "%s" " done.")
(dolist (p cfg-var:packages)
(package-install p)))))
(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)
(cfg:install-packages)
Вызов package-install с именем пакета в качестве символа. Вы можете найти названия пакетов для ваших пакетов, позвонив package-install интерактивно и заканчивая на имя. Функция package-installed-p даст вам знать, если он уже установлен.
Например:
(mapc
(lambda (package)
(or (package-installed-p package)
(package-install package)))
'(package1 package2 package3))
Мне нравится проверять, хочет ли пользователь сначала установить пакеты, как это сделано в этом ответе. Также я обновляю содержимое пакета перед установкой чего-либо. Я не уверен, что это лучший способ, но я не думаю, что лучшие ответы делали это для меня.
(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))
(require 'cl)
(setq pkgs-to-install
(let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
(remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))
(when (> (length pkgs-to-install) 0)
(package-refresh-contents)
(dolist (pkg pkgs-to-install)
(package-install pkg)))
Близко к ответу Николая :
Пакеты package-1, package-2 и package-3 устанавливаются, если они отсутствуют локально. Если они присутствуют, Emacs загружается без задержки.
(setq package-archives ;
'(("gnu" . "https://elpa.gnu.org/packages/") ; declare repositories
("melpa" . "https://melpa.org/packages/"))) ;
(require 'package) ; activate packages
(package-initialize) ; initialize package facility
(setq my-packages
'(package-1
package-2
package-3))
(unless package-archive-contents ; unless packages are not available locally, dont refresh package archives
(package-refresh-contents)) ; refreshing package contents is time-consuming and should be done on demand
(dolist (pkg my-packages) ;
(unless (package-installed-p pkg) ; iterate over packages and install missing ones
(package-install pkg))) ;
;; other config below
Вот еще способ.
;; assure every package is installed
(defun ensure-package-installed (&rest packages)
(let ((user-required-packages
(seq-remove
(lambda (package) (package-installed-p package))
packages)))
(when user-required-packages
(package-refresh-contents)
(dolist (package user-required-packages)
(package-install package)))))
;; list of packages to install
(ensure-package-installed
'try
'which-key)
Вот мой, он короче:)
(mapc
(lambda (package)
(unless (package-installed-p package)
(progn (message "installing %s" package)
(package-refresh-contents)
(package-install package))))
'(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode rainbow-mode fontawesome))
Я столкнулся с проблемой, что ничего не произошло после добавления (package-install 'org) в .emacs, Я хотел установить актуальную версию org-mode и встроенный org-mode довольно старый
Я выкопал исходный код package-install из Emacs 25.3.1. Функция self уже проверяет, установлен ли пакет или нет, и отказывается устанавливать его, если пакет уже установлен. Итак, проверка (unless (package-installed-p package) ...) из ответа 10093312 фактически не требуется.
(defun package-install (pkg &optional dont-select)
"Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'. Interactively, prompt for its name.
If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.
If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
(interactive
(progn
;; Initialize the package system to get the list of package
;; symbols for completion.
(unless package--initialized
(package-initialize t))
(unless package-archive-contents
(package-refresh-contents))
(list (intern (completing-read
"Install package: "
(delq nil
(mapcar (lambda (elt)
(unless (package-installed-p (car elt))
(symbol-name (car elt))))
package-archive-contents))
nil t))
nil)))
(add-hook 'post-command-hook #'package-menu--post-refresh)
(let ((name (if (package-desc-p pkg)
(package-desc-name pkg)
pkg)))
(unless (or dont-select (package--user-selected-p name))
(package--save-selected-packages
(cons name package-selected-packages)))
(if-let ((transaction
(if (package-desc-p pkg)
(unless (package-installed-p pkg)
(package-compute-transaction (list pkg)
(package-desc-reqs pkg)))
(package-compute-transaction () (list (list pkg))))))
(package-download-transaction transaction)
(message "`%s' is already installed" name))))
Встроенный org-mode также считается установленным и package-install отказывается устанавливать более новую версию от ELPA. Потратив некоторое время на чтение package.el, я пришел к следующему решению.
(dolist (package (package-compute-transaction
() (list (list 'python '(0 25 1))
(list 'org '(20171211)))))
;; package-download-transaction may be more suitable here and
;; I don't have time to check it
(package-install package))
Причина, по которой это работает, заключается в том, что package-* Семейные функции обрабатывают аргументы по-разному в зависимости от того, является ли это символом или package-desc объект. Вы можете указать только информацию о версии для package-install через package-desc объект.
если вы просто хотите сохранить список имен пакетов в своем init.el
и не против вручную выполнить некоторые команды
пример:
(setq package-selected-packages '(
evil
evil-commentary
color-theme-sanityinc-solarized
xclip
))
;; M-x package-refresh-contents
;; M-x package-install-selected-packages
;; M-x package-autoremove
поместите их в свой init.el и
- заменить имена пакетов
(setq package-selected-packages '(
<your-favourite-package-name-1>
<your-favourite-package-name-2>
<your-favourite-package-name-3>
<your-favourite-package-name-4>
))
- ром-команды
M-x package-refresh-contents
# will sync package information to local
M-x package-install-selected-packages
# will install packages in the list above
M-x package-autoremove
# will remove packages beyond the list above
этот метод уже предложен другими ответами
как новичок, я трачу некоторое время, чтобы разобраться в этом, просто хочу, чтобы это было еще более понятно