Как мне сохранить порядок ключей, которые я добавляю в хеш Perl?

Question

Как я могу поддерживать порядок фактического списка после подсчета его появления, используя хэш в следующей программе? Например, <DATA> являются

a
b
e
a
c 
d 
a
c
d
b
etc.

Используя хэш, я посчитал вхождение каждого элемента.

и что я хочу это:

a  3
b  2
e  1
c  2
d  2

но следующая программа показывает мне иначе.

my (%count, $line, @array_1, @array_2);
while ($line = <DATA>) {
    $count{$line}++ if ( $line =~ /\S/ );
}
@array_1 = keys(%count);
@array_2 = values(%count);
for(my $i=0; $i<$#array_1; $i++)
{
   print "$array_1[$i]\t $array_2[$i]";
}

Answer 1

Хэши не упорядочены, но, как обычно, CPAN предлагает решение: Tie:: IxHash

use Tie::IxHash;
my %count;
tie %count, 'Tie::IxHash';

while ($line = <DATA>) {
$count{$line}++ if ( $line =~ /\S/ );
}

while( my( $key, $value)= each %count) {
    print "$key\t $value"; 
}

Answer 2

Данные в хеш-таблице хранятся в порядке хеш-кода ключей, который для большинства целей подобен случайному порядку. Вы также хотите сохранить порядок первого появления каждой клавиши. Вот один из способов решения этой проблемы:

my (%count, $line, @display_order);
while ($line = <DATA>) {
    chomp $line;           # strip the \n off the end of $line
    if ($line =~ /\S/) {
        if ($count{$line}++ == 0) {
            # this is the first time we have seen the key "$line"
            push @display_order, $line;
        }
    }
}

# now @display_order holds the keys of %count, in the order of first appearance
foreach my $key (@display_order)
{
    print "$key\t $count{$key}\n";
}

Answer 3

Из ответа perlfaq4 на "Как сделать так, чтобы мой хэш запомнил порядок, в который я помещал элементы?"

---

Как я могу сделать так, чтобы мой хэш запомнил порядок, в который я помещал элементы?

Используйте Tie::IxHash из CPAN.

use Tie::IxHash;

tie my %myhash, 'Tie::IxHash';

for (my $i=0; $i<20; $i++) {
    $myhash{$i} = 2*$i;
    }

my @keys = keys %myhash;
# @keys = (0,1,2,3,...)

Answer 4

Просто:

my (%count, @order);
while(<DATA>) {
  chomp;
  push @order, $_ unless $count{$_}++;
}
print "$_ $count{$_}\n" for @order;
__DATA__
a
b
e
a
c
d
a
c
d
b

Answer 5

Другой вариант - простой чистый perl Дэвида Голдена (@xdg) Hash::Ordered модуль. Вы получаете порядок, но он медленнее, поскольку хеш становится закулисным объектом, и вы используете методы для доступа и изменения элементов хеша.

Вероятно, существуют тесты, которые могут определить, насколько медленнее модуль, чем обычные хэши, но это крутой способ работы со структурами данных ключ / значение в небольших скриптах и ​​достаточно быстрый для меня в такого рода приложениях. В документации упоминается также несколько других подходов к упорядочиванию хеша.

Answer 6

Я не уверен, что это всегда лучший метод, но я использовал его иногда. Вместо того, чтобы просто иметь "видимый" тип хеша, он может хранить как счетчик, так и порядок заметки.

В основном вместо $count{$line} имея количество раз видели, $count{$line}{count} это время видно и $count{$line}{order} это порядок, в котором это было видно.

my %count;
while (my $line = <DATA>) {
    chomp $line;
    if ($line =~ /\S/) {
        $count{$line} ||= { order => scalar(keys(%count)) };
        $count{$line}{count}++;
    }
}

for my $line (sort { $count{$a}{order} <=> $count{$b}{order} } keys %count ) {
    print "$line $count{$line}{count}\n";
}

Answer 7

Хэши - это просто массивы до тех пор, пока они не будут назначены в Perl, поэтому, если вы приведете их в виде массива, вы можете перебрать их в исходном порядке:

my @array = ( z => 6,
              a => 8,
              b => 4 );

for (my $i=0; $ar[$i]; ++$i) {
    next if $i % 2;
    my $key = $ar[$i];
    my $val = $ar[$i+1];

    say "$key: $val"; # in original order
}

Вы потеряете преимущества хеширования, если сделаете это явно. Но поскольку хеш - это просто массив, вы можете создать его, просто назначив массив хешу:

my %hash = @array;
say $hash{z};

Возможно, это всего лишь вариант решения "использовать массив в качестве индекса", но я думаю, что оно более точное, потому что вместо того, чтобы печатать свой индекс вручную (или каким-либо другим способом), вы создаете его непосредственно из исходного массива.