Захват и отображение STDOUT одновременно

Question

Захват и отображение STDOUT одновременно

У меня есть следующий код для захвата и обработки вывода команды "Выполнить". Как мне изменить его так, чтобы в командном окне "Выполнить" отображался вывод, и в то же время выход регистрировался? Замена @SW_HIDE с @SW_SHOW (или эквивалент) просто показывает пустое командное окно.

Что-то похожее на Linux tee команда, которая записывает в файл, пока он печатает STDOUT.

$CurrentPID = Run(@ComSpec & ' /c ' & $CurrentLogCmd, "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

If Not ProcessWaitClose($CurrentPID,60) Then
    WriteLog("[Warning] Timed-out.Finding date in current hour raw log -" & $CurrentLogFileName)
    $F_LogWarningExist = 1
    Return $C_SUCCESS ; Take chances and proceed with parsing raw logs
EndIf

$CurrentOutput = StdoutRead($CurrentPID)

6

stdout autoit

Источник

user847151 09 май '13 в 14:12

2 ответа

Другие вопросы по тегам stdout autoit

user2097036 16 май '13 в 07:13 2013-05-16 07:13 · Answer 1 · 2013-05-16 07:13

ConsoleWrite(_getDOSOutput('ipconfig /all') & @CRLF)

Func _getDOSOutput($command)
    Local $text = '', $Pid = Run('"' & @ComSpec & '" /c ' & $command, '', @SW_HIDE, 2 + 4)
    While 1
            $text &= StdoutRead($Pid, False, False)
            If @error Then ExitLoop
            Sleep(10)
    WEnd
    Return StringStripWS($text, 7)
EndFunc   ;==>_getDOSOutput

Может быть, это поможет вам.

4

Источник

user2097036 16 май '13 в 07:13

user4157124 27 дек '14 в 00:29 2014-12-27 00:29 · Answer 2 · 2014-12-27 00:29

Что-то похожее на Linux tee команда, которая записывает в файл, пока он печатает STDOUT.

Перенаправление STDOUT делает принимающую сторону (скрипт) ответственной за отображение и ведение журнала. Согласно документации:

StdoutRead() не блокирует, он вернется немедленно. Чтобы получить все данные, они должны вызываться в цикле.

Пример:

#AutoIt3Wrapper_Change2CUI=Y

#include <Constants.au3>
#include <MsgBoxConstants.au3>

Global Enum  $EXIT_OK, _
             $EXIT_NOCOMPILE, _
             $EXIT_ABORT

Global Const $g_sPromptError  = 'Compile this script and run resulting executable instead.', _
             $g_sPromptInput  = 'Enter a command:', _
             $g_sInputDefault = 'ping localhost -n 10'

Global       $g_sCMD = '', _
             $g_sSTD = ''

Main()

Func Main()

    If Not @Compiled Then

        MsgBox($MB_OK + $MB_ICONERROR, @ScriptName, $g_sPromptError)
        Exit $EXIT_NOCOMPILE

    EndIf

    $g_sCMD = InputBox(@ScriptName, $g_sPromptInput, $g_sInputDefault)
    If @error Then Exit $EXIT_ABORT

    $g_sSTD = _getCmdStd($g_sCMD)
    MsgBox($MB_OK + $MB_ICONINFORMATION, $g_sCMD, $g_sSTD)

    Exit $EXIT_OK
EndFunc

Func _getCmdStd(Const $sCMD, Const $sDir = '', Const $iType = $STDERR_MERGED, Const $bShow = False, Const $iDelay = 100)
    Local       $sTMP = ''
    Local       $sSTD = ''
    Local       $sCOM = @ComSpec & ' /c ' & $sCMD
    Local Const $iWin = $bShow ? @SW_SHOW : @SW_HIDE
    Local Const $iPID = Run($sCOM, $sDir, $iWin, $iType)

    While True

        $sTMP = StdoutRead($iPID, False, False)

        If @error Then

            ExitLoop 1

        ElseIf $sTMP Then

            $sTMP  = StringReplace($sTMP, @CR & @CR, '')
            $sSTD &= $sTMP

            ConsoleWrite($sTMP)

        EndIf

        Sleep($iDelay)

    WEnd

    Return SetError(@error, @extended, $sSTD)
EndFunc

Возвращает STDOUT (и STDERR) после завершения выполнения при записи в консоль во время выполнения. замещать MsgBox() по мере необходимости (функция регистрации).