Удалить дубликаты из массива объектов в jsonnet

Question

У меня есть массив объектов, я хотел бы удалить дубликаты. У моего массива есть общее поле name что я хотел бы использовать для дедупликации.

Я пытаюсь преобразовать массив в карту, а затем из карты обратно в массив, но преобразование карты выдает ошибку duplicate field name: "a":

local arr = [ 
    { "name": "a", "value": 1234},
    { "name": "b", "value": 555},
    { "name": "c", "value": 0}, 
    { "name": "a", "value": 1234} 
];
local map = { [x.name] : x  for x in arr };

Желаемый результат:

[ 
      { "name": "a", "value": 1234},
      { "name": "b", "value": 555}, 
      { "name": "c", "value": 0} 
]

Answer 1

Как отметил @seh в канале ksonnet, последняя версия jsonnet теперь позволяет использовать std.set() на объектах.

 local arr = [
    { name: "a", value: 4321 },
    { name: "b", value: 555 },
    { name: "c", value: 0 },
    { name: "a", value: 1234 },
  ];
 std.set(arr, function(o) o.name)

std.set() заголовок задокументирован в реализации std lib в jsonnet.

Answer 2

Игнорирование оригинального порядка сортировки

Вы можете реализовать это, заменив понимание на std.foldl()Обратите внимание на проблему заказа:

local arr = [
  { name: "a", value: 4321 },
  { name: "b", value: 555 },
  { name: "c", value: 0 },
  { name: "a", value: 1234 },
];

// Use foldl to iterate from array, can't use comprehension because of dup fields
local map = std.foldl(function(x, y) x { [y.name]: y }, arr, {});

// Re-convert map to array, note that it'll not respect original order
// but fields' (ie 'name' key)
[ map[x] for x in std.objectFields(map)]

Сохранение оригинального порядка сортировки

Если вам нужно сохранить исходный порядок сортировки в выходном массиве, вы можете добавить _idx поле для использования в финале sort():

local arr = [
  { name: "a", value: 4321 },
  { name: "b", value: 555 },
  { name: "c", value: 0 },
  { name: "a", value: 1234 },
];

// Overload array elements with there index (`_idx` field)
local idxArray = std.mapWithIndex(function(i, x) x { _idx:: i }, arr);

// Use foldl to iterate from array, can't use comprehension because of dup fields
local map = std.foldl(function(x, y) x { [y.name]: y }, idxArray, {});

// Re-convert map to array, it'll keep original order via added _idx field
std.sort([map[x] for x in std.objectFields(map)], function(e) e._idx)