Играть в FLV, используя NetStream appendBytes

Question

Я знаю, что есть много способов воспроизвести FLV-файл, но, учитывая требования моего проекта, мне нужно воспроизвести FLV, используя URLStream и NetStream

Вот полный пример кода, на котором я делаю свои тесты:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.NetStatusEvent;
    import flash.events.ProgressEvent;
    import flash.utils.ByteArray;
    import flash.net.URLRequest;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.NetStreamAppendBytesAction;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    import flash.net.URLStream;

    /**
     * ...
     * @author Hadi Tavakoli
     */
    public class Main extends Sprite 
    {
        private var netConnection:NetConnection;
        private var netStream:NetStream;
        private var ul:URLStream;
        private var video:Video;
        private var bytes:ByteArray = new ByteArray();
        private var _isSeek:Boolean = false;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point

            video = new Video();
            addChild(video);

            netConnection = new NetConnection();
            netConnection.addEventListener(NetStatusEvent.NET_STATUS, netConnectionStatusHandler);
            netConnection.connect(null);
        }

        private function netConnectionStatusHandler(ev:NetStatusEvent):void
        {
            switch(ev.info.code)
            {
                case 'NetConnection.Connect.Success':

                    ul = new URLStream();
                    ul.addEventListener(ProgressEvent.PROGRESS, onProgress);
                    ul.load(new URLRequest('01.flv'));

                break;
            }
        }

        private function onProgress(e:ProgressEvent):void
        {
            ul.readBytes(bytes, bytes.length);

            if (!netStream) 
            {
                netStream = new NetStream(netConnection);
                netStream.client = { };
                video.attachNetStream(netStream);
                netStream.play(null);
                trace("BEGIN")
                netStream.appendBytesAction(NetStreamAppendBytesAction.RESET_BEGIN);
            }
            else
            {
                if (!_isSeek)
                {
                    trace("SEEK")
                netStream.appendBytesAction(NetStreamAppendBytesAction.RESET_SEEK);
                    _isSeek = true;
                }
            }

            if (bytes.length == e.bytesTotal)
            {
                trace("END")
            netStream.appendBytesAction(NetStreamAppendBytesAction.END_SEQUENCE);
            }

            netStream.appendBytes(bytes);
            trace("-")
        }
    }
}

Я не уверен, правильно ли я использую метод "appendBytes"? видео показывается, но только несколько первых кадров будут воспроизведены, а затем видео остановится!

в моих глазах вроде все ок! Есть ли у вас какие-либо советы о том, где моя проблема?

Answer 1

Я не думаю, что вам нужен блок if (!_IsSeek). Похоже, что вы толкаете байты, когда получаете их в последовательном порядке, и поэтому поиск никогда не происходит. Похоже, что он выдвинет первый набор байтов, а затем добавит действие поиска и добавит остальные байты. Попробуйте просто удалить этот блок и посмотреть, работает ли он.

В противном случае я думаю, что все в порядке.

Answer 2

В "ul.readBytes(bytes, bytes.length);" линия, есть ошибка, я думаю. Это никогда не работало и для меня. Он всегда возвращает полную длину (от 0 до доступных байтов). Так что это огромная утечка памяти. Но если вы используете Flash Player 11.4 или более поздней версии, вы можете изменить его следующим образом.

ul.position = bytes.length;
ul.readBytes(bytes);