Вызов API write() C из CL на iSeries
Я пытаюсь написать программу на языке управления, которая создает и заполняет файл конфигурации в IFS до вызова утилиты Java, которая его использует.
Мне удалось вызвать API open () и close() для (повторного) создания файла, но я не могу заставить write() поместить что-либо в файл. До сих пор это был опыт обучения, но без сообщения об ошибке при вызове write() у меня возникли проблемы с пониманием, в чем заключается моя проблема.
Это почти наверняка способ обработки переменных, но сеанс отладки предполагает, что они должны быть такими, какими они должны быть.
/* ========================================================================= */
/* Processing for the PRCMQMSG command */
/* ========================================================================= */
PGM PARM(&ACTION &SRCMQ &TGTMQ)
/* Input parameters */
DCL VAR(&ACTION) TYPE(*CHAR) LEN(5)
DCL VAR(&SRCMQ) TYPE(*CHAR) LEN(125)
DCL VAR(&TGTMQ) TYPE(*CHAR) LEN(125)
/* Parameter elements */
DCL VAR(&SRCHOST) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&SRCMQ 3)
DCL VAR(&SRCPORT) TYPE(*DEC) STG(*DEFINED) +
LEN(5) DEFVAR(&SRCMQ 33)
DCL VAR(&SRCQMGR) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&SRCMQ 36)
DCL VAR(&SRCCHNL) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&SRCMQ 66)
DCL VAR(&SRCQUE) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&SRCMQ 96)
DCL VAR(&TGTHOST) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&TGTMQ 3)
DCL VAR(&TGTPORT) TYPE(*DEC) STG(*DEFINED) +
LEN(5) DEFVAR(&TGTMQ 33)
DCL VAR(&TGTQMGR) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&TGTMQ 36)
DCL VAR(&TGTCHNL) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&TGTMQ 66)
DCL VAR(&TGTQUE) TYPE(*CHAR) STG(*DEFINED) +
LEN(30) DEFVAR(&TGTMQ 96)
/* IFS details */
DCL VAR(&PATH) TYPE(*CHAR) LEN(128) +
VALUE('/mqutil')
DCL VAR(&CFGFILE) TYPE(*CHAR) LEN(20)
DCL VAR(&JOB) TYPE(*CHAR) LEN(6)
/* IFS API flags */
DCL VAR(&O_RDONLY) TYPE(*INT) VALUE(1)
DCL VAR(&O_WRONLY) TYPE(*INT) VALUE(2)
DCL VAR(&O_RDWR) TYPE(*INT) VALUE(4)
DCL VAR(&O_CREAT) TYPE(*INT) VALUE(8)
DCL VAR(&O_EXCL) TYPE(*INT) VALUE(16)
DCL VAR(&O_TRUNC) TYPE(*INT) VALUE(64)
DCL VAR(&O_APPEND) TYPE(*INT) VALUE(256)
DCL VAR(&O_CODEPAGE) TYPE(*INT) VALUE(8388608)
DCL VAR(&O_TEXTDATA) TYPE(*INT) VALUE(16777216)
DCL VAR(&S_IRUSR) TYPE(*INT) VALUE(256)
DCL VAR(&S_IWUSR) TYPE(*INT) VALUE(128)
DCL VAR(&S_IXUSR) TYPE(*INT) VALUE(64)
DCL VAR(&S_IRWXU) TYPE(*INT) VALUE(448)
DCL VAR(&S_IRGRP) TYPE(*INT) VALUE(32)
DCL VAR(&S_IWGRP) TYPE(*INT) VALUE(16)
DCL VAR(&S_IXGRP) TYPE(*INT) VALUE(8)
DCL VAR(&S_IRWXG) TYPE(*INT) VALUE(56)
DCL VAR(&S_IROTH) TYPE(*INT) VALUE(4)
DCL VAR(&S_IWOTH) TYPE(*INT) VALUE(2)
DCL VAR(&S_IXOTH) TYPE(*INT) VALUE(1)
DCL VAR(&S_IRWXO) TYPE(*INT) VALUE(7)
/* IFS API parameters */
DCL VAR(&STROPN) TYPE(*INT) /* Open flags */
DCL VAR(&STRMODE) TYPE(*INT) /* Mode flags */
DCL VAR(&STRPATH) TYPE(*CHAR) LEN(149)
DCL VAR(&STRCODEP) TYPE(*INT) VALUE(819)
DCL VAR(&STRHAND) TYPE(*INT)
DCL VAR(&NULL) TYPE(*CHAR) LEN(1) VALUE(X'00')
DCL VAR(&CRLF) TYPE(*CHAR) LEN(2) VALUE(X'0D25')
DCL VAR(&ERRNO_PTR) TYPE(*PTR)
DCL VAR(&ERRNO) TYPE(*INT) STG(*BASED) +
BASPTR(&ERRNO_PTR)
DCL VAR(&ERRNO_CHR) TYPE(*CHAR) LEN(4)
DCL VAR(&MSGID) TYPE(*CHAR) LEN(7)
DCL VAR(&LINE) TYPE(*CHAR) LEN(250)
DCL VAR(&LINE_PTR) TYPE(*PTR) ADDRESS(&LINE)
DCL VAR(&LINELEN) TYPE(*UINT)
DCL VAR(&LINELEN_D) TYPE(*DEC) LEN(5 0)
/* Create and open a configuration file in the IFS */
RTVJOBA NBR(&JOB)
CHGVAR VAR(&CFGFILE) VALUE('mqconf_' |< &JOB)
CHGVAR VAR(&STRPATH) VALUE(&PATH |< '/' |< &CFGFILE +
|< '.connection' |< &NULL)
CHGVAR VAR(&STROPN) VALUE(&O_WRONLY + &O_CREAT + +
&O_TRUNC + &O_CODEPAGE + &O_TEXTDATA)
CHGVAR VAR(&STRMODE) VALUE(&S_IRWXU + &S_IRWXG + +
&S_IROTH)
CALLPRC PRC('open') PARM((&STRPATH) (&STROPN *BYVAL) +
(&STRMODE *BYVAL) (&STRCODEP *BYVAL)) +
RTNVAL(&STRHAND)
IF COND(&STRHAND = -1) THEN(DO)
CALLPRC PRC('__errno') RTNVAL(&ERRNO_PTR)
CHGVAR VAR(&ERRNO_CHR) VALUE(&ERRNO)
CHGVAR VAR(&MSGID) VALUE('CPE' || &ERRNO_CHR)
SNDPGMMSG MSGID(&MSGID) MSGF(QCPFMSG) MSGTYPE(*ESCAPE)
ENDDO
/* Write a line to the file */
CHGVAR VAR(&LINE) VALUE('This is a line of text in +
a file.' |< &CRLF)
RTVMSG MSGID(CPF9897) MSGF(QCPFMSG) MSGDTA(&LINE) +
MSGLEN(&LINELEN_D)
CHGVAR VAR(&LINELEN) VALUE(&LINELEN_D)
CALLPRC PRC('write') PARM((&STRHAND *BYREF) +
(&LINE_PTR *BYREF) (&LINELEN *BYVAL))
/* Close the configuration file */
CALLPRC PRC('close') PARM((&STRHAND *BYVAL))
ENDPGM
Я пытался объявить переменные &LINE и &LINE_PTR таким же образом, как &ERRNO и &ERRNO_PTR, но это дало мне ошибку "Указатель не установлен", когда я попытался присвоить значение &LINE. Я думаю, это потому, что сначала к &ERRNO_PTR обращаются, тогда как для &LINE_PTR это было не так. Во всяком случае, это может быть красная сельдь.
Команда RTVMSG - это хитрость, чтобы найти длину строки, исключая конечные пробелы.
Я запустил код в отладке, и перед вызовом write() &LINE содержит именно то, что я ожидаю, как и LINELEN, который равен 35. Затем вызывается write() и не вызывает ошибок, но ни одна строка не присутствует в файл. Файл остается пустым.
Последнее замечание Все параметры программы в настоящее время не используются, но я оставил их для полноты на случай, если с ними что-то сделалось глупым. По сути, первые два блока объявлений можно игнорировать.
Любая помощь приветствуется.
4 ответа
Вы можете использовать QSH и перенаправление для записи в IFS намного проще, чем пытаться использовать C API.
/* DISABLE STDOUT */
ADDENVVAR ENVVAR(QIBM_QSH_CMD_OUTPUT) VALUE('NONE') REPLACE(*YES)
/* CREATE THE FILE WITH CCSID 819 */
ADDENVVAR ENVVAR(STRPATH) VALUE(&STRPATH) REPLACE(*YES)
QSH CMD('rm $STRPATH; touch -C 819 $STRPATH')
/* APPEND A LINE TO THE FILE */
ADDENVVAR ENVVAR(LINE) VALUE(&LINE) REPLACE(*YES)
QSH CMD('echo "$LINE">>$STRPATH')
Для дополнительной информации:
- Особенности языка команд Qshell
- Запуск команд Qshell из CL
- rm - удалить записи каталога
- touch - изменить время доступа к файлу и изменения
- echo - записывает аргументы в стандартный вывод
Если вам нужна более высокая производительность, вы можете использовать более гибкий HLL для доступа к API. У Скотта Клемента есть отличная книга под названием " Работа с IFS в RPG IV".
Это просто небольшая ошибка при вызове функции записи, дескриптор должен быть передан по значению, а не byref. Найти ниже исправленный вызов записи, я проверил его и его работу
CALLPRC PRC('write') PARM((&STRHAND *BYVAL) +
(&LINE_PTR *BYREF) (&LINELEN *BYVAL))
Я искал, как использовать API IFS от CL, и наткнулся на ваш код. Я думаю, что ваша проблема с записью - дескриптор файла (первый параметр) должен быть передан по значению. Также не указывайте O_CODEPAGE в переменной &STROPN, так как это конфликтует с параметром кодовой страницы. Я использую этот метод и могу получить хороший файл трассировки для служебной программы, над которой я работаю.
На самом деле ответ - Line Pointer BYVAL
CALLPRC PRC('write') PARM((&STRHAND *BYVAL) +
(&LINE_PTR *BYVAL) (&LINELEN *BYVAL))