Фатальная ошибка сборки PlatformIO: LiquidCrystal.h "Нет такого файла или каталога"

Я довольно новичок в Atom / PlatformIO и пытался использовать его для разработки с Arduino в качестве альтернативы Arduino IDE.

~ Спецификации ~

base code used: Arduino ESP sample code "WifiBlueToothSwitch.ino"
Board: ESP-WROOM-32
Additional Components: 1602A (2x16) LCD

Я успешно выполнил другой пример кода на модуле ESP через PlatformIO до того, как попытался использовать ЖК-экран, однако, когда я попытался включить библиотеку LiquidCrystal.h, он выдает ошибку сборки:

src\main.cpp:22:27: fatal error: LiquidCrystal.h: No such file or directory
compilation terminated.
*** [.pioenvs\esp32dev\src\main.o] Error 1
[ERROR] Took 3.34 seconds

Так что из нескольких сайтов, которые я искал по этой проблеме до сих пор, большинство указывают на отсутствующее добавление заголовочного файла "wire.h", однако, даже после включения его в программу, он все еще дает мне эту ошибку.

Мое включает в себя следующие:

#include <Arduino.h>
#include <WiFi.h>
#include <Wire.h>
#include <LiquidCrystal.h>

Поэтому я не совсем уверен, почему эта проблема возникает. Как я могу решить эту проблему?


Изменить 1:

Я недавно наткнулся на другой сайт, который предлагал попробовать обновить PlatformIO через консоль, однако это было безрезультатно. Все было помечено как "Современное".

Documents\PlatformIO\Projects\171031-143050-esp32dev> platformio update
Updating tool-scons                      @ 3.20501.2      [Up-to-date]
Updating tool-unity                      @ 1.20302.1      [Up-to-date]
Updating pysite-pioplus                  @ 0.4.2          [Up-to-date]
Updating contrib-piohome                 @ 0.3.1          [Up-to-date]
Updating tool-pioplus                    @ 0.10.11        [Up-to-date]

Platform Manager
================
Platform Espressif 32
--------
Updating espressif32                     @ 0.10.0         [Up-to-date]

Updating tool-esptoolpy                  @ 1.20000.0      [Up-to-date]
Updating toolchain-xtensa32              @ 1.50200.0      [Up-to-date]
Updating framework-arduinoespressif32    @ 1.2.0          [Up-to-date]
Updating tool-espotapy                   @ 1.0.0          [Up-to-date]


Library Manager
===============
Documents\PlatformIO\Projects\171031-143050-esp32dev>

Изменить 2:

Я скомпилировал и запустил этот код через Arduino IDE и могу подтвердить, что он работает, поэтому проблема, похоже, связана с IDE PlatformIO...


Изменить 3:

Следуя предложению BMelis, я изучил файл PlatformIO.ini и добавил к нему следующую строку:

lib_extra_dirs = C:\Program Files (x86)\Arduino\hardware\espressif\esp32\libraries

Это исправило первоначальную ошибку для LiquidCrystal.h, однако это также привело к следующей ошибке зависимости во время сборки:

[11/06/17 08:52:58] Processing esp32dev (platform: espressif32; lib_extra_dirs: C:\Program Files (x86)\Arduino\hardware\espressif\esp32\libraries; board: esp32dev; framework: arduino)

Verbose mode can be enabled via `-v, --verbose` option
Collected 49 compatible libraries
Looking for dependencies...
Library Dependency Graph
|-- <WiFi> v1.0

|-- <Wire> v1.0
|-- <LiquidCrystal> v1.0.7
Compiling .pioenvs\esp32dev\lib\WiFi\WiFiAP.o
Compiling .pioenvs\esp32dev\lib\WiFi\WiFiGeneric.o
Compiling .pioenvs\esp32dev\lib\WiFi\WiFiMulti.o
Compiling .pioenvs\esp32dev\lib\WiFi\WiFiSTA.o

****ERROR OCCURRED****
C:\Program Files (x86)\Arduino\hardware\espressif\esp32\libraries\WiFi\src\WiFiAP.cpp:40:37: fatal error: apps/dhcpserver_options.h: No such file or directory
compilation terminated.
*** [.pioenvs\esp32dev\lib\WiFi\WiFiAP.o] Error 1
 [ERROR] Took 8.13 seconds

Я попытался добавить каталог, который он упоминал, добавив в libi вторую команду lib_extra_dirs:

lib_extra_dirs = C:\Program Files (x86)\Arduino\hardware\espressif\esp32\tools\sdk\include\lwip\apps

Однако это не помогло решить проблему. Я в растерянности относительно того, что делать сейчас...


ПОЛНЫЙ КОД:

#include <Arduino.h>
// Copyright 2015-2016 Espressif Systems (Shanghai) PTE LTD
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at

//     http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

// Sketch shows how to switch between WiFi and BlueTooth or use both
// Button is attached between GPIO 0 and GND and modes are switched with each press

#include <WiFi.h>
#include <Wire.h>
#include <LiquidCrystal.h>
#define STA_SSID "HIDDEN FOR SECURITY"
#define STA_PASS "HIDDEN FOR SECURITY"
#define AP_SSID  "esp32 @ my desk"
#define LED_PIN  5

//LCD variables on analog inputs, but used as digital I/O
//lcd_gnd = gnd
//lcd_vcc = +5v
//lcd_v0 = +5v & pot
const int lcd_rs = 27;
//lcd_rw = gnd
const int lcd_e = 14;
//lcd_d0 = n/a
//lcd_d1 = n/a
//lcd_d2 = n/a
//lcd_d3 = n/a
const int lcd_d4 = 32;
const int lcd_d5 = 33;
const int lcd_d6 = 25;
const int lcd_d7 = 26;
//lcd_bl1 = +5v
//lcd_bl2 = gnd
LiquidCrystal lcd(lcd_rs, lcd_e, lcd_d4, lcd_d5, lcd_d6, lcd_d7);

enum { STEP_BTON, STEP_BTOFF, STEP_STA, STEP_AP, STEP_AP_STA, STEP_OFF, STEP_BT_STA, STEP_END };

void onButton(){
  static uint32_t step = STEP_BTON;
  switch(step){
    case STEP_BTON://BT Only
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Starting BT");
      btStart();
    break;
    case STEP_BTOFF://All Off
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Stopping BT");
      btStop();
    break;
    case STEP_STA://STA Only
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Starting STA");
      WiFi.begin(STA_SSID, STA_PASS);
    break;
    case STEP_AP://AP Only
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Stopping STA");
      WiFi.mode(WIFI_AP);

      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Starting AP");
      WiFi.softAP(AP_SSID);
    break;
    case STEP_AP_STA://AP+STA
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Starting STA");
      WiFi.begin(STA_SSID, STA_PASS);
    break;
    case STEP_OFF://All Off
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Stopping WiFi");
      WiFi.mode(WIFI_OFF);
    break;
    case STEP_BT_STA://BT+STA
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Starting STA+BT");
      WiFi.begin(STA_SSID, STA_PASS);
      btStart();
    break;
    case STEP_END://All Off
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Stopping WiFi+BT");
      WiFi.mode(WIFI_OFF);
      btStop();
    break;
    default:
    break;
  }
  if(step == STEP_END){
    step = STEP_BTON;
  } else {
    step++;
  }
  //little debounce
  delay(100);
}

void WiFiEvent(WiFiEvent_t event){
    switch(event) {
        case SYSTEM_EVENT_AP_START:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("AP Started");
            Serial.print("AP Started");
            WiFi.softAPsetHostname(AP_SSID);
            break;
        case SYSTEM_EVENT_AP_STOP:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("AP Stopped");
            Serial.print("AP Stopped");
            break;
        case SYSTEM_EVENT_STA_START:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("STA Started");
            Serial.print("STA Started");
            WiFi.setHostname(AP_SSID);
            break;
        case SYSTEM_EVENT_STA_CONNECTED:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("STA Connected");
            Serial.print("STA Connected");
            WiFi.enableIpV6();
            break;
        case SYSTEM_EVENT_AP_STA_GOT_IP6:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("STA IPv6: ");
            Serial.print("STA IPv6: ");
            Serial.println(WiFi.localIPv6());
            break;
        case SYSTEM_EVENT_STA_GOT_IP:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("STA IPv4: ");
            Serial.print("STA IPv4: ");
            lcd.setCursor(0,1);
            lcd.print(WiFi.localIP());
            Serial.print(WiFi.localIP());
            break;
        case SYSTEM_EVENT_STA_DISCONNECTED:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("STA Disconnected");
            Serial.print("STA Disconnected");
            break;
        case SYSTEM_EVENT_STA_STOP:
            lcd.clear();
            lcd.setCursor(0, 0);
            lcd.print("STA Stopped");
            Serial.print("STA Stopped");
            break;
        default:
            break;
    }
}

void setup() {
    lcd.begin(16, 2); //tells arduino that the LCD is a 16x2 size LCD
    lcd.clear(); //clear any previous text
    lcd.setCursor(0, 0); // set cursor to column 0 of row 0 (first row, first block)

    pinMode(LED_PIN, OUTPUT);
    digitalWrite(LED_PIN, LOW); // LED off
    Serial.begin(115200);
    pinMode(0, INPUT_PULLUP);
    WiFi.onEvent(WiFiEvent);
    Serial.print("ESP32 SDK: ");
    Serial.println(ESP.getSdkVersion());
    Serial.println("Press the button to select the next mode");
    lcd.setCursor(0, 0);
    lcd.println("Press mode btn");
}

void loop() {
    digitalWrite(LED_PIN, HIGH); // Turn on LED
    static uint8_t lastPinState = 1;
    uint8_t pinState = digitalRead(0);
    if(!pinState && lastPinState){
        onButton();
    }
    lastPinState = pinState;
}

5 ответов

В терминале типа:

pio lib install "LiquidCrystal"

Я думаю, вам нужно скачать пакет LiquidCrystal или не устанавливать его с помощью PlatformIO CLI. Проверьте это: http://platformio.org/lib/show/887/LiquidCrystal/installation

Скопируйте разархивированную папку LiquidCrystal в ваш проект /lib папку пожалуйста и попробуйте собрать заново.

PS: частные / сторонние библиотеки должны быть размещены /lib папка.

Для platformio я работаю так (я на Win10): все мои проекты находятся в "моих документах". Библиотеки общего назначения находятся в "моих документах / библиотеках". Конкретные находятся в папке "lib" проекта pio.

В platformio.ini у меня есть, например, следующее:

[env:lolin32]
;platform = espressif32
platform = https://github.com/platformio/platform-espressif32.git#feature/stage
board = lolin32
framework = arduino
lib_extra_dirs = ..\libraries
lib_deps = 
  https://urltotherepo.git

для платформы вы можете закомментировать правильный (этап или релиз, но для Arduino ESP32 "релиз" довольно... нестабилен)

поместите правильный путь в lib_extra_dirs и постарайтесь не прятать все библиотеки в папке "Program Files", так как при необходимости изменить что-либо там не очень удобно.

Я тоже столкнулся с этой проблемой. Я считаю, что лучшим решением будет добавить запись в свойplatformio.iniфайл для проекта и доски. Таким образом, вам не нужно добавлять код библиотеки в ваше собственное дерево исходного кода, и это решение устойчиво к "работает на моем компьютере", поскольку проект не полагается на то, что библиотека находится где-то в вашей файловой системе. Обратите внимание, что здесь я нацелен на конкретную версию для максимальной предсказуемости, но вам это не обязательно.

[env:nanoatmega328]
platform = atmelavr
board = nanoatmega328
framework = arduino
lib_deps = LiquidCrystal@1.5.0 #<--important line

Мне пришлось вручную добавить библиотеку жидких кристаллов в PlatformIO, и это решило эту проблему для меня со следующими шагами:

  1. Перейти на главную страницу PIO
  2. Нажмите «Библиотеки» под кнопкой перезагрузки.
  3. Найдите и выберите жидкий кристалл от arduino.
  4. Нажмите добавить в проект
Другие вопросы по тегам