Чтение DWORD неправильно с AS3?

Question

В этом вопросе я получил ответ о том, как использовать эту информацию для чтения BLB-файлов. Итак, я следовал инструкциям, и оказалось, что я правильно читаю заголовок.

Однако, когда я пытаюсь прочитать идентификаторы файлов, я получаю сообщение об ошибке завершения файла:

[Fault] exception, information=Error: Error #2030: End of file was encountered.

Вот мой код

Базовый класс:

package  
{
    import flash.display.Sprite;
    import flash.filesystem.File;
    import flash.filesystem.FileStream;
    import flash.utils.ByteArray;
    import flash.utils.IDataInput;
    import flash.filesystem.FileMode;

    public class BLBDecompress extends Sprite 
    {
        private var _file:File;
        private var _stream:FileStream;

        private var _blbBytes:ByteArray;

        private var _header:Header;
        private var _fileIDs:Array;

        public function BLBDecompress() 
        {
            decompress();
        }

        private function decompress():void
        {
            _file = File.applicationDirectory.resolvePath("testfiles/t.blb");
            _blbBytes = new ByteArray();

            _stream = new FileStream();
            _stream.open(_file, FileMode.READ);
            _stream.readBytes(_blbBytes);
            _stream.close();

            _header = readHeader(_blbBytes);

            _fileIDs = new Array();

            for (var i:int = 0; i < _header.dwNumber; i++)
            {
                _fileIDs.push(readFileID(_blbBytes));
            }
        }

        private function readHeader(input:IDataInput):Header
        {
            var header:Header = new Header();

            header.szID = new ByteArray();
            input.readBytes(header.szID, 0, 4);

            header.bID = input.readUnsignedByte();
            header.bUnknown = input.readUnsignedByte();
            header.wDataSize = input.readUnsignedShort();
            header.dwFileSize = input.readUnsignedInt();
            header.dwNumber = input.readUnsignedInt();

            return header;
        }

        private function readFileID(input:IDataInput):uint
        {
            var fileID:uint = input.readUnsignedInt();

            return fileID;
        }
    }
}

Класс заголовка:

package  
{
    import flash.utils.ByteArray;

    public class Header 
    {
        public var szID:ByteArray;
        public var bID:uint;
        public var bUnknown:uint;
        public var wDataSize:uint;
        public var dwFileSize:uint;
        public var dwNumber:uint;

        public function Header() 
        {

        }
    }
}

Дело в том, что _header.dwNumber возвращает / отслеживает как 1090650112 (41020000 в базе 16), так что я могу представить, что достигнет конца файла. Так что я читаю это неправильно, использую это неправильно или делаю что-то еще неправильно? Остаток от

Если это помогает, это приложение AIR, и я использую FlashDevelop с Flex 4 SDK.

Answer 1

Это похоже на простую проблему Big/Little endian: 4 байта, составляющие DWORD, находятся в файле в порядке, отличном от того, который используется вашим процессором.

Вам нужно изменить порядок байтов в DWORD, чтобы получить 00000241 и любой другой многобайтовый номер