Разве ленив в привязках у Вязов?

Question

У меня есть две функции A и B, которые можно либо отключить, либо включить A, либо включить B, но не обе одновременно. После просмотра " Создание невозможных состояний невозможно" я попытался применить это на уровне типов.

Упрощенная версия решения, которое я рассматриваю, заключается в следующем.

module Main exposing (main)

import Browser
import Html exposing (Html, button, div, text)
import Html.Events exposing (onClick)

type Model
  = NoneEnabled
  | AEnabled
  | BEnabled

init : Model
init = NoneEnabled

type Msg
  = EnableA
  | DisableA
  | EnableB
  | DisableB

view : Model -> Html Msg
view model =
  let -- Buttons to enable and disable features
      buttons =
        div [] [ button [onClick EnableA] [text "Enable A"]
               , button [onClick DisableA] [text "Disable A"]
               , button [onClick EnableB] [text "Enable B"]
               , button [onClick DisableB] [text "Disable B"]
               ]

      -- All possible feature states
      aEnabled  = div [] [text "A enabled"]
      aDisabled = div [] [text "A disabled"]
      bEnabled  = div [] [text "B enabled"]
      bDisabled = div [] [text "B disabled"]
  in case model of
       NoneEnabled ->
         div [] [buttons, aDisabled, bDisabled]
       AEnabled ->
         div [] [buttons, aEnabled, bDisabled]
       BEnabled ->
         div [] [buttons, aDisabled, bEnabled]

update : Msg -> Model -> Model
update msg model =
  case (msg, model) of
    (EnableA, _) ->
      AEnabled
    (EnableB, _) ->
      BEnabled
    (DisableA, AEnabled) ->
      NoneEnabled
    (DisableB, BEnabled) ->
      NoneEnabled
    _ ->
      model

main : Program () Model Msg
main =
  Browser.sandbox { init = init, update = update, view = view }

мой aEnabled, aDisabled, bEnabled, а также bDisabled особенности в view потенциально дорого вычислять. Будут ли они оцениваться независимо от того, какая ветвь case model of принимает или могу ли я полагаться только на оцениваемые используемые функции?

Или сформулированный с более коротким примером.

f c x =
  let a = x + 1
      b = x + 2
  in case c of
       True ->
         a
       False ->
         b

Будет f True 0 форсировать оценку b в выражении let?

Answer 1

Элм-х let/in Заявления не лениво оцениваются. Вы можете положить некоторые Debug.log заявления, чтобы доказать точку зрения:

f c x =
  let a = Debug.log "a calculated" <| x + 1
      b = Debug.log "b calculated" <| x + 2
  in case c of
       True ->
         a
       False ->
         b

призвание f только один раз будет записывать оба сообщения на консоль, независимо от ввода. Пример тут.

Одним из способов обойти это препятствие является требование произвольного параметра для a а также bтакие как Блок ():

f c x =
  let a () = Debug.log "a calculated" <| x + 1
      b () = Debug.log "b calculated" <| x + 2
  in case c of
       True ->
         a ()
       False ->
         b ()

Эта вариация будет только оценивать функцию a или же b,