Как нарисовать линию в Delphi на холсте FMX

Question

Это с Delphi Berlin 10.1, обновление 2

Следующие работы (я получаю линию):

brush := TStrokeBrush.Create(TBrushKind.Solid, TAlphaColors.Lightgray);
brush.Thickness := 2;
with Canvas do
begin
    BeginUpdate;
    DrawLine(PointF(10, 10), PointF(100, 10), 1, brush);
    EndUpdate;
end;

Следующее не работает:

with Canvas do
begin
    BeginUpdate;
    Stroke.Color := TAlphaColors.Black;
    Stroke.Thickness := 2.0;
    DrawLine(PointF(10, 10), PointF(100, 10), 1);
    EndUpdate;
end;

Почему я не могу использовать второй? Как я могу заставить его работать, или я должен придерживаться создания мазка, как в первом примере?

Я включил минимальное приложение:

Main.pas

unit main;

interface

uses
    System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.Objects;

type
    TMainForm = class(TForm)
        PaintBox: TPaintBox;
        procedure OnPaint(Sender: TObject; Canvas: TCanvas);
    private
        { Private declarations }
    public
        { Public declarations }
    end;

var
    MainForm: TMainForm;

implementation

{$R *.fmx}

procedure TMainForm.OnPaint(Sender: TObject; Canvas: TCanvas);
begin
    with Canvas do
    begin
        BeginUpdate;
        Stroke.Color := TAlphaColors.Black;
        Stroke.Thickness := 2.0;
        DrawLine(PointF(10, 10), PointF(100, 10), 1);
        EndUpdate;
    end;
end;

end.

main.fmx:

object MainForm: TMainForm
    Left = 0
    Top = 0
    Caption = 'Form1'
    ClientHeight = 480
    ClientWidth = 640
    FormFactor.Width = 320
    FormFactor.Height = 480
    FormFactor.Devices = [Desktop]
    DesignerMasterStyle = 0
    object PaintBox: TPaintBox
        Position.X = 16.000000000000000000
        Position.Y = 16.000000000000000000
        Size.Width = 609.000000000000000000
        Size.Height = 449.000000000000000000
        Size.PlatformDefault = False
        OnPaint = OnPaint
    end
end

test.dpr:

program test;

uses
   System.StartUpCopy,
   FMX.Forms,
   main in 'main.pas' {MainForm};

{$R *.res}

begin
    Application.Initialize;
    Application.CreateForm(TMainForm, MainForm);
    Application.Run;
end.

Answer 1

Более ранние версии Delphi имели разные значения по умолчанию для Stroke.Kind в зависимости от платформы.

Начиная с Delphi 10.1 Berlin, значением по умолчанию является Noneдля всех платформ. (Спасибо @TomBrunberg)

Чтобы линия появилась, установите Stroke.Kind := TBrushKind.Solid;

Примечание: протестировано на Windows 8.1

---

Я также создал новое приложение Metropolis FMX, где рисование работало без установки Stroke.Kind, Хотя не могу этого объяснить.

---

Аналогичный отчет был подан в QP, RSP-16313. Canvas.DrawLine не работает в Windows XP (32-битных) формах. Здесь проблема проявляется в Windows-XP, но не в Windows-7.

Answer 2

Очень странно, что первый случай - это работа.

Вы должны использовать мазок кисти.

И вы должны использовать BeginScene и EndScene вместо BeginUpdate и EndUpdate. Этот фрагмент отлично работает:

  Brush := TStrokeBrush.Create(TBrushKind.Solid, TAlphaColors.Black);
  Brush.Thickness := 2;
  with Canvas do
  begin
    BeginScene();
    DrawLine(PointF(10, 10), PointF(100, 10), 1, Brush);
    EndScene;
  end;