Perl Tkx: как передать переменную в качестве параметра для обратного вызова кнопки

Question

Учитывая этот фрагмент кода Perl/Tkx:

@itemList = ({'attrib1' => 'name1', 'attrib2' => 'value1'},
             {'attrib1' => 'name2', 'attrib2' => 'value2'});
$row = 0;
foreach $item (@itemList) {
  push(@btn_list, new_ttk__button(-text => $item->{'attrib1'}, -command => sub {do_something($item->{'attrib2'});}));
  $btn_list[-1]->g_grid(-column => 0, -row => $row);
  $row++;
}

(В реальной программе @itemList заполняется из редактируемого пользователем файла конфигурации.)

Я вижу две кнопки с именами "name1" и "name2". Но когда я нажимаю на любую кнопку, кажется, что параметр, который передается в обратный вызов всегда $itemList[1]->{'attrib2'}; то есть 'attrib2' последнего элемента массива @itemList. То, что я хотел бы, чтобы иметь первый вызов кнопки do_something($itemList[0]->{'attrib2'} и второй звонок do_something($itemList[1]->{'attrib2'},

Что я делаю не так, пожалуйста и спасибо?

Answer 1

Вы столкнулись с тонкой чертой for петли в Perl. Первое решение: использовать my в цикле for. затем $item сможет создать правильное замыкание в анонимной подпрограмме, которую вы объявите позже в цикле.

for my $item (@itemlist) {
    push(@btn_list, new_ttk__button(
                       -text => $item->{'attrib1'}, 
                       -command => sub {do_something($item->{'attrib2'});}));
    $btn_list[-1]->g_grid(-column => 0, -row => $row);
    $row++;
}

Дальнейшее объяснение: Perl неявно локализует предметную переменную цикла for. Если вы не используете my в цикле for цикл будет использовать локализованную версию переменной пакета. Это делает ваш код эквивалентным:

package main;
$main::item = undef;
@itemList = ({'attrib1' => 'name1', 'attrib2' => 'value1'},
             {'attrib1' => 'name2', 'attrib2' => 'value2'});
$row = 0;
foreach (@itemList) {
    local $main::item = $_;
    push(@btn_list, new_ttk__button(
        -text => $main::item->{'attrib1'},
        -command => sub {do_something($main::item->{'attrib2'});}));
    $btn_list[-1]->g_grid(-column => 0, -row => $row);
    $row++;
}
# at the end of the loop, value of $main::item restored to  undef

Ваши анонимные подписчики все еще ссылаются на $main::item переменная пакета, любое значение, которое эта переменная содержит во время вызова этих подпрограмм, что, вероятно, undef,

Короче решение: use strict

Дополнительное подтверждение концепции. Попробуйте угадать, что выводит следующая программа:

@foo = ( { foo => 'abc', bar => 123 },
         { foo => 'def', bar => 456 } );

my @fn;
foreach $foo (@foo) {
    push @fn, sub { "42" . $foo->{bar} . "\n" };
}
foreach my $foo (@foo) {
    push @fn, sub { "19" . $foo->{foo} . "\n" };
}
print $_->() for @fn;

Вот ответ:

42
42
19abc
19def