Как я могу получить цвет фона загруженного SWF-файла?

Question

Я загружаю SWF-файл в основное приложение с помощью URLLoader, я хочу получить цвет фона загруженного SWF-файла. (Я слышал, что одним из решений будет чтение байтового кода загруженного SWF)

Answer 1

Да, вам нужно изучить двоичные данные SWF. Вот краткое описание формата SWF. И это небольшая деталь о различных видах тегов. Вам необходимо найти тег SetBackgroundColor (тип тега = 9), который обычно является первым или вторым тегом swf.
Байты в SWF-файле следуют порядку байтов, поэтому вам нужно быть осторожным при чтении данных. И в основном они будут сжаты (первые три байта будут "CWS"), поэтому начиная с 9-го байта (включая 9-й), все данные должны быть распакованы (ByteArray.decompress) перед обработкой.
Пример кода:)

package {
  import flash.display.*;
  import flash.events.*;
  import flash.net.*;
  import flash.utils.*;
  public class Test1 extends Sprite{
    private var stream:URLStream;
    public function Test1():void {
      stream = new URLStream();
      stream.load(new URLRequest("some.swf"));
      stream.addEventListener(Event.COMPLETE, onComplete);
    }
    private function onComplete(e:Event):void {
      var bytes:ByteArray = new ByteArray();
      bytes.endian = Endian.LITTLE_ENDIAN;
      stream.readBytes(bytes, 0, 8);
      var sig:String = bytes.readUTFBytes(3);
      trace("SIG = " + sig);
      trace("ver = " + bytes.readByte());
      trace("size = " + bytes.readUnsignedInt());
      var compBytes:ByteArray = new ByteArray();
      compBytes.endian = Endian.LITTLE_ENDIAN;
      stream.readBytes(compBytes);
      if (sig == "CWS") {
        compBytes.uncompress();
      }
      var fbyte = compBytes.readUnsignedByte();
      var rect_bitlength = fbyte >> 3;
      var total_bits = rect_bitlength * 4;
      var next_bytes =  Math.ceil((total_bits - 3)/ 8);
      for(var i=0; i<next_bytes; i++) {
        compBytes.readUnsignedByte();
      }
      trace("frameRate = " + compBytes.readUnsignedShort());
      trace("frameCount = " + compBytes.readUnsignedShort());


  while(true) {
    var tagcodelen:Number = compBytes.readUnsignedShort();
    var tagcode:Number = tagcodelen >> 6;
    var taglen:Number = tagcodelen & 0x3F;
    trace("tag code = " + tagcode + "\tlen = " + taglen);
    if (taglen >=63) {
      taglen = compBytes.readUnsignedInt();
    }
    if(tagcode == 9) {
      trace("found background color");
      trace("color is: RED=" + compBytes.readUnsignedByte() +", GREEN = " + compBytes.readUnsignedByte() + ", BLUE = " + compBytes.readUnsignedByte());
      break;
    }
    compBytes.readBytes(new ByteArray(), 0, taglen);
    //break;
  }
}
}}
                                        
                                    
                                

Answer 2

Ваш SWF-файл должен передать его на веб-страницу с помощью JS.

getURL ("javascript: setColour (" + DESIRED COLOR + ")");

Функция setColour, конечно, должна делать то, что вы хотите.