Исправление ошибки длины sql в процессе 4gl 10.2B

Question

Исправление ошибки длины sql в процессе 4gl 10.2B

Я пытаюсь использовать JDBC-коннектор OpenGe для извлечения данных из существующей базы данных прогресса, но я сталкиваюсь с проблемами ширины столбца.

Вот ошибка, которая держит меня.

[DataDirect] [OpenEdge JDBC Driver] [OpenEdge] Столбец TabDisplayName в таблице PUB.Menu имеет значение, превышающее его максимальную длину или точность.

Я просмотрел много постов, в каждом из которых предлагались разные советы, и вот что я дал понять:

Вручную измените ширину SQL через словарь данных.
- Я быстро проверил PUB.Menu.TabDisplayName, чтобы найти максимальное значение в 44 символа
- Установите ширину x(50) безрезультатно, а затем x(100) из-за фиксированной иррациональной ярости, опять же без удачи.
Используйте функцию SQL SUBSTR() для усечения поля - не оптимально, но лучше, чем ничего
- Я получаю странные результаты с этим. Он прекрасно работает в sqlexp, но в среде Java его, как столбец никогда не выбирается.
Используйте dbtool для автоматического исправления проблем ширины с опцией #2
- После выбора всех таблиц и "областей" (не уверен, что это такое...) и отправки окончательного варианта, я возвращаюсь в командную строку proenv, как будто ничего не произошло.
Изменить ширину sql программно через 4gl
- Это единственный вариант, который я обнаружил, но я еще не попробовал.
- Я немного не хочу пробовать это только потому, что ручная модификация не удалась. Кроме того, это живая среда разработки (только для меня), и я пытаюсь запутать ее слишком ужасно, хотя регулярно делаю снимки.

Ход выполнения 10.2B на машине с Unix.

Любые комментарии и предложения будут оценены.

-Спасибо

3

jdbc openedge progress-4gl progress-db

Источник

user1527489 17 авг '12 в 00:36

2 ответа

Решение

Можно создать представления с параметром substring (field.name,1,maxlength) и использовать вместо PUB2.viewname имя PUB2.viewname.

    DROP VIEW PUB2."accounts";
    CREATE VIEW PUB2."accounts" ( 
    "ACC-TYPE",
    "ACCOUNT-NAME",
    ANALITIC,
    ARCH,
    COUNT1,
    CURRENCY,
    PLAN,
    QUANTITY,
    "RID-ANOBJECT",
    "RID-APP",
    TRANSIT ) 
    AS select "acc-type",
    SUBSTRING("account-name", 1, 130),
    "analitic",
    "arch",
    "count1",
    "currency",
    "plan",
    "quantity",
    "rid-anobject",
    "rid-app",
    "transit"
    FROM PUB."accounts";
    COMMIT;

используйте sqlexp для автоматического создания: учетная запись sqlexp -H localhost -S ' + db-port + ' -user sysprogress -password sysprogress -infile refreshateSQLviews.sql -outfile refreshateSQLviews.log

вот код:

    def var num-port as integer.
    for first _Servers where _Servers._Server-Type = "Login" no-lock:
        num-port = _Servers._Server-PortNum.
    end.
    if num-port < 0 then num-port = num-port + 65536.
    if num-port = 0 then do:
       message "Define -S parameter for Database" view-as alert-box.
       RETURN.
    end.
    message num-port.

    /* ttSQLWidth table: SQL WIDTH for all tables */

    def var execstr as char.
    def var rez-str as char.
    def var db-port as char. /* -S port */
    db-port = STRING(num-port).

    DEFINE TEMP-TABLE ttSQLWidth NO-UNDO
        FIELD tableName   AS CHARACTER
        FIELD tableNum    AS INTEGER
        FIELD fieldName   AS CHARACTER
        FIELD sqlWidth    AS INTEGER
        FIELD requireFix  AS LOGICAL INIT FALSE
        FIELD actualWidth AS INTEGER
        FIELD newWidth    AS INTEGER
    INDEX tableNum  tableNum
    INDEX tableName tableName.

    FOR EACH _File NO-LOCK WHERE _Tbl-Type = "T":
        FOR EACH _Field OF _File WHERE _Field._Data-type = "character":
            if _field._extent > 0 then next.
            CREATE ttSQLWidth.
            ASSIGN tableName = _File._File-name
                tableNum = _File._File-num
        fieldName = _Field._Field-name
        sqlWidth = _Field._Width.
        RELEASE ttSQLWidth.
        END. /* FOR EACH _Field */
    END. /* FOR EACH _File */

    DEFINE VARIABLE bTab        AS HANDLE      NO-UNDO.
    DEFINE VARIABLE hQuery      AS HANDLE      NO-UNDO.
    DEFINE VARIABLE queryString AS CHARACTER   NO-UNDO.

    FOR EACH ttSQLWidth:
        CREATE BUFFER bTab FOR TABLE tableName.
        CREATE QUERY hQuery.
        hQuery:ADD-BUFFER(bTab).

        message tablename.
        queryString = "FOR EACH " + tableName + " WHERE LENGTH(" + fieldName + ") >= " + STRING(sqlWidth) + " BY LENGTH(" + fieldName + ") DESC".
        hQuery:QUERY-PREPARE(queryString).
        hQuery:QUERY-OPEN().

        IF hQuery:GET-NEXT() THEN DO:
            ASSIGN actualWidth = LENGTH(bTab:BUFFER-FIELD(fieldName):BUFFER-VALUE)
                   requireFix = TRUE.
        END. /* IF .. THEN DO */

        hQuery:QUERY-CLOSE.
        DELETE OBJECT hQuery.

        bTab:BUFFER-RELEASE().
        DELETE OBJECT bTab.

    END. /* FOR EACH ttSQLWidth */

    def var add-pr   as integer initial 10.  /* % from max */
    def var maxWidth as integer initial 249. /* maxwidth */

    FOR EACH ttSQLWidth WHERE ttSQLWidth.requireFix = TRUE:

        ttSQLWidth.newWidth = TRUNCATE ( (ttSQLWidth.actualWidth + add-pr) / add-pr, 0 ) * add-pr.
        ttSQLWidth.newWidth = INTEGER( ttSQLWidth.newWidth).
        if ttSQLWidth.newWidth > maxWidth then ttSQLWidth.newWidth = maxWidth.

    END.

    /* sql script generation */ 

    OUTPUT TO value("recreateSQLviews.sql").
    def var lst-field as char.
    FOR EACH ttSQLWidth WHERE BREAK BY ttSQLWidth.tableName:
       IF FIRST-OF(ttSQLWidth.tableName) 
          THEN run MakeSQLViews(ttSQLWidth.tableName).

    END.
    OUTPUT CLOSE. 

    /* sql script execution */

    execstr = 'sqlexp account -H localhost -S ' + db-port + ' -user sysprogress -password sysprogress -infile recreateSQLviews.sql -outfile recreateSQLviews.log'.

    input through value(execstr).
    repeat:
      IMPORT UNFORMAT rez-str.
      message rez-str.
    end.
    INPUT CLOSE.

    RETURN.

    PROCEDURE MakeSQLViews:
    define input parameter tableName as character.

    def var str_tmp as char.
    def var str_tmp1 as char.
    def var str as char initial "count,sum,double,row,date,level,area,number,primary".

    def var fieldName  as char.
    def var fieldName1 as char.

    FOR EACH _file WHERE _file._file-name = tableName AND 
                         _file._file-num GT 0 AND _file._file-num LT 32000 NO-LOCK:   
       fieldName = "".    
       FOR EACH _Field OF _File NO-LOCK:            

              str_tmp = '"' + _Field._Field-name + '"'.
              FOR FIRST ttSQLWidth where ttSQLWidth.tableName = _file._file-name   and 
                                         ttSQLWidth.fieldName = _Field._Field-name and 
                                         ttSQLWidth.requireFix = TRUE:
                  str_tmp = 'SUBSTRING("' + _Field._Field-name + '", 1, ' + STRING(ttSQLWidth.newWidth) + ')'. 
              END.
              fieldName  = fieldName + (IF(fieldName = "") THEN ("") ELSE ("," + chr(10) + chr(9))) + str_tmp.    
              str_tmp1   = ( IF ( INDEX ( _Field._Field-name, "-" ) = 0 ) 
                                THEN ( _Field._Field-name ) 
                                ELSE ( '"' + _Field._Field-name + '"' )).

              if LOOKUP ( _Field._Field-name, str, "," ) > 0 then str_tmp1 = '"' + _Field._Field-name + '"'.

              fieldName1 = fieldName1 + (IF(fieldName1 = "") THEN ("") ELSE ("," + chr(10) + chr(9))) + UPPER(str_tmp1). 

       END. /* FOR EACH _Field */    

       PUT UNFORMATTED 'DROP VIEW PUB2."' + _file._file-name + '";' SKIP.     
       PUT UNFORMATTED 'CREATE VIEW PUB2."' + _file._file-name + '" ( ' + chr(10) chr(9) + fieldName1 +  ' ) ' + chr(10) + 
           'AS select ' + fieldName + chr(10) + 
           'FROM PUB."' + _file._file-name + '";' SKIP.     
       PUT UNFORMATTED 'COMMIT;' SKIP(1). 
    END.

    END.

1

Источник

user6414928 02 июн '16 в 13:13

Другие вопросы по тегам jdbc openedge progress-4gl progress-db

user123238 17 авг '12 в 01:52 2012-08-17 01:52 · Accepted Answer · 2012-08-17 01:52

Опция dbtool является лучшей. Он предназначен для этого. Из proenv вы должны увидеть что-то вроде этого:

proenv> dbtool s2k
       DATABASE TOOLS MENU - 10.2B
       ---------------------------

  1. SQL Width & Date Scan w/Report Option
  2. SQL Width Scan w/Fix Option
  3. Record Validation
  4. Record Version Validation
  5. Read or Validate Database Block(s)
  6. Record Fixup
  7. Schema Validation
  9. Enable/Disable File Logging
          Q. Quit

  Choice: 2
: (0 = однопользовательский 1= самообслуживание>1=# темы)? 1
% Заполнения выше текущего максимума: 100
: (Номер таблицы или все)? все
: (Номер зоны или все)? все
: (подробный уровень 0-3)? 0
Всего записей прочитано: 31357
Обнаружены ошибки SQLWidth: 0, Найдено ошибок даты: 0
Исправлены ошибки SQLWidth: 0

Если ваша база данных имеет работающий сервер, выберите "1" в приглашении connect:. Если нет, выберите "0".

Выберите 100 для заполнения, чтобы удвоить ширину полей.

Попробуйте это на копии "спортивной" базы данных, если вы не уверены. Используйте более высокий уровень многословия, если вы хотите получить представление о том, что он делает.

Работа с небольшой базой данных разработки не займет много времени. (Это в основном мгновенно на "спорт".)