Braintree передавая адрес доставки с запросом

Question

Я новичок в VB.net, когда использую Braintree, он работает нормально, теперь мне нужно передать детали доставки вместе с запросом на оплату. Как мне это сделать

If Request.Form("payment_method_nonce") <> "" Then
    Dim strStatus As String = ""    
    Dim gateway As New Braintree.BraintreeGateway    
    With gateway
        .Environment = Braintree.Environment.SANDBOX
        .PublicKey = "*********"
        .PrivateKey = "*************"
        .MerchantId = "*************"
    End With

    Dim transactionRequest As New Braintree.TransactionRequest    
    With transactionRequest
        .Amount = 100
        .PaymentMethodNonce = Request.Form("payment_method_nonce")
    End With

    Dim result As Braintree.Result(Of Braintree.Transaction) = gateway.Transaction.Sale(transactionRequest)
    If result.Errors Is Nothing Then
        If result.Target.Status.ToString = Braintree.TransactionStatus.AUTHORIZED.ToString Then
            strStatus = "Payment is " & result.Target.Status.ToString
            Dim result1 As Braintree.Result(Of Braintree.Transaction) = gateway.Transaction.SubmitForSettlement(result.Target.Id)
            strStatus = strStatus & " And Now its " & result1.Target.Status.ToString
            Label1.Text = "Paid"
        Else
            strStatus = result.Target.Status.ToString
        End If
    Else
        strStatus = result.Message.ToString
        Label1.Text = "Not Paid"
    End If
    status.Text = strStatus
End If

Answer 1

_{Полное раскрытие: я разработчик в Braintree.}

Вы можете добавить адрес доставки как часть транзакции, указав адрес доставки в своем TransactionRequest объект. ShippingAddress будет создан как AddressRequest объект. Вы можете увидеть полный пример.NET, который включает создание адреса доставки на нашем сайте разработчиков.

Что касается того, как сделать это с VB.net, основываясь на вашем фрагменте кода, вы должны быть в состоянии сделать что-то вроде этого:

Dim shippingAddressRequest As New Braintree.AddressRequest    
With shippingAddressRequest
    .FirstName = "John"
    .LastName = "Smith"
    .StreetAddress = "123 Example St."
    .Locality = "Chicago"
    .Region = "IL"
    .PostalCode = "60601"
    .CountryCodeAlpha2 = "US"
End With

Затем измените ваш transactionRequest быть таким:

Dim transactionRequest As New Braintree.TransactionRequest   
With transactionRequest
    .Amount = 100
    .PaymentMethodNonce = Request.Form("payment_method_nonce")
    .ShippingAddress = shippingAddressRequest
End With

Если вам нужна другая помощь, связанная с этим, я рекомендую обратиться в службу поддержки Braintree.