Можете ли вы получить "код как данные" загруженной функции в Clojure?

Другими словами, " Хорошо, значит, код - это данные..."

Этот поток рассматривает, как читать из исходного файла, но мне интересно, как получить s-выражение уже загруженной функции в структуру данных, которую я могу читать и манипулировать.

Другими словами, если я скажу,

(defn example [a b] (+ a b))

я не могу получить этот список во время выполнения? Разве это не весь смысл "кода как данных"?

Это действительно общий вопрос о Лиспе, но я ищу ответ в Clojure.

Источник

3 ответа

Решение

Вы можете использовать clojure.repl/source макрос для получения источника символа:

user> (source max)
(defn max
  "Returns the greatest of the nums."
  {:added "1.0"
   :inline-arities >1?
   :inline (nary-inline 'max)}
  ([x] x)
  ([x y] (. clojure.lang.Numbers (max x y)))
  ([x y & more]
   (reduce1 max (max x y) more)))
nil

Но это только часть ответа. AFAICT source ищет имя файла источника и номер строки, которые определяют данный символ, а затем печатает исходный код из файла. Следовательно, source не будет работать с символами, для которых у вас нет исходного кода, например скомпилированный AOT код clojure.

Возвращаясь к исходному вопросу, вы можете думать о source как чтение метаданных, связанных с данным символом, и просто его печать. Т.е. это обман. Это никоим образом не возвращает вам "код как данные", где под кодом я имею в виду скомпилированную функцию clojure.

На мой взгляд, "код как данные" относится к функции lisps, где исходный код фактически является структурой данных lisp, и, следовательно, он может быть прочитан читателем lisp. То есть я могу создать структуру данных, которая является действительным кодом LISP, и eval тот.

Например:

user=> (eval '(+ 1 1))
2

Вот '(+ 1 1) это буквальный список, который читается читателем clojure, а затем оценивается как код clojure.

Обновление: Yehonathan Sharvit спрашивал в одном из комментариев, возможно ли изменить код для функции. Следующий фрагмент читает в источнике для функции, изменяет результирующую структуру данных и, наконец, оценивает структуру данных, получая новую функцию, my-nth, определяясь:

(eval
 (let [src (read-string (str (source-fn 'clojure.core/nth) "\n"))]
   `(~(first src) my-nth ~@(nnext src))))

syntax-quote линия заменяет nth с my-nth в defn форма.

Источник

Вы можете получить исходный код в последних версиях clojure с помощью source функция.

user=> (source nth)
(defn nth
  "Returns the value at the index. get returns nil if index out of
  bounds, nth throws an exception unless not-found is supplied.  nth
  also works for strings, Java arrays, regex Matchers and Lists, and,
  in O(n) time, for sequences."
  {:inline (fn  [c i & nf] `(. clojure.lang.RT (nth ~c ~i ~@nf)))
   :inline-arities #{2 3}
   :added "1.0"}
  ([coll index] (. clojure.lang.RT (nth coll index)))
  ([coll index not-found] (. clojure.lang.RT (nth coll index not-found))))
nil

чтобы получить строку в качестве значения, вы можете обернуть это в with-out-str:

user=> (with-out-str (source nth))
"(defn nth\n  \"Returns the value at the index. get returns nil if index out of\n  bounds, nth throws an exception unless not-found is supplied.  nth\n  also works for strings, Java arrays, regex Matchers and Lists, and,\n  in O(n) time, for sequences.\"\n  {:inline (fn  [c i & nf] `(. clojure.lang.RT (nth ~c ~i ~@nf)))\n   :inline-arities #{2 3}\n   :added \"1.0\"}\n  ([coll index] (. clojure.lang.RT (nth coll index)))\n  ([coll index not-found] (. clojure.lang.RT (nth coll index not-found))))\n"
user=>
Источник

Это было мое сообщение; приятно познакомиться;-) Кстати, ссылки, приведенные в этой теме для ответов были отличным чтением; так что если вам интересно, вы можете потратить время на их чтение. Вернемся к вашему вопросу, хотя source Кажется, работает для кода, который был загружен через файл, но это работает не во всех случаях. Я думаю, в частности, это не работает для функций, определенных в repl.

user=> (def foo (fn [] (+ 2 2)))
#'user/foo
user=> (source foo)
Source not found
nil
user=> (defn foo2 [] (+ 2 2))
#'user/foo2
user=> (source foo2)
Source not found
nil

Копаем немного...

user=> (source source)
(defmacro source
  "Prints the source code for the given symbol, if it can find it.
  This requires that the symbol resolve to a Var defined in a
  namespace for which the .clj is in the classpath.

  Example: (source filter)"
  [n]
  `(println (or (source-fn '~n) (str "Source not found"))))
nil
user=> (source clojure.repl/source-fn)
(defn source-fn
  "Returns a string of the source code for the given symbol, if it can
  find it.  This requires that the symbol resolve to a Var defined in
  a namespace for which the .clj is in the classpath.  Returns nil if
  it can't find the source.  For most REPL usage, 'source' is more
  convenient.

  Example: (source-fn 'filter)"
  [x]
  (when-let [v (resolve x)]
    (when-let [filepath (:file (meta v))]
      (when-let [strm (.getResourceAsStream (RT/baseLoader) filepath)]
        (with-open [rdr (LineNumberReader. (InputStreamReader. strm))]
          (dotimes [_ (dec (:line (meta v)))] (.readLine rdr))
          (let [text (StringBuilder.)
                pbr (proxy [PushbackReader] [rdr]
                      (read [] (let [i (proxy-super read)]
                                 (.append text (char i))
                                 i)))]
            (read (PushbackReader. pbr))
            (str text)))))))
nil

Так что да, похоже, он пытается загрузить исходный файл из пути к классам, чтобы попытаться выложить его для вас. Одна вещь, которую я узнал, работая с Clojure, состоит в том, что 9 раз из 10 полезно взглянуть на источник.

Источник
Другие вопросы по тегам