Есть ли способ предотвратить CL_SALV_TABLE от удаления пробелов?

Question

Есть ли способ предотвратить случай CL_SALV_TABLE от удаления ведущих пробелов на дисплее?

У меня есть следующий кусок кода, в котором я ставлю один пробел перед Master текст и два пробела перед Slave текст.

REPORT zzy.

CLASS lcl_main DEFINITION FINAL CREATE PRIVATE.
  PUBLIC SECTION.
    CLASS-METHODS:
      main.
ENDCLASS.

CLASS lcl_main IMPLEMENTATION.
  METHOD main.
    TYPES: BEGIN OF l_tys_test,
      name  TYPE string,
      value TYPE i,
    END OF l_tys_test,
    l_tyt_test TYPE STANDARD TABLE OF l_tys_test WITH EMPTY KEY.

    DATA(lt_test) = VALUE l_tyt_test(
      ( name = `Root` value = 0 )
      ( name = ` Master` value = 1 )
      ( name = `  Slave` value = 2 )
    ).

    cl_salv_table=>factory(
      IMPORTING
        r_salv_table = DATA(lo_salv_table)
      CHANGING
        t_table = lt_test
    ).
    lo_salv_table->display( ).
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  lcl_main=>main( ).

К сожалению, ведущие пространства урезаны в представлении.

В этом уроке парень, кажется, сделал это как-то.

Answer 1

Да, есть:

lo_salv_table->get_columns( )->get_column( 'NAME' )->set_leading_spaces( abap_true ).