Perl: проблема с благословенным объектом

Я создаю бота, который подключается к серверу Matrix. Для этого я использую http://p3rl.org/Net::Async::Matrix.

Код:

#!/usr/bin/perl
use strict;
use warnings;
use Net::Async::Matrix;
use Net::Async::Matrix::Utils qw ( parse_formatted_message );
use IO::Async::Loop;
use Data::Dumper;


my $loop = IO::Async::Loop->new;

my $matrix = Net::Async::Matrix->new(
server => 'matrix.server.net',
    on_error => sub {
            my ( undef, $message ) = @_;
            warn "error: $message\n";
    },
);
$loop->add( $matrix );

$matrix->login(
    user_id  => '@bot:matrix.server.net',
    password => 'password',
)->get;

my $room = $matrix->join_room( '#Lobby:matrix.server.net' )->get;

$room->configure(
    on_message => sub {
            my ( undef, $member, $content, $event ) = @_;
            my $msg = parse_formatted_message( $content );
            my $sendername = $member->displayname;
print Dumper $sendername;
            &sendmsg("$sendername said: $msg");
    },
);

my $stream = $matrix->start;

sub sendmsg {
        my $input = shift;
        if ($input) {
                $room->send_message(
                        type => "m.text",
                        body => $input,
                 ),
        }
}

$loop->run;

По сути, я хочу, чтобы бот повторил сказанное.

Я получаю следующий вывод:

$ VAR1 = 'm1ndgames'; Ошибка Longpoll - обнаружен объект "m1ndgames said: test", но ни параметры allow_blessed, convert_blessed, ни allow_tags не включены (или отсутствует метод TO_JSON/FREEZE) в /usr/local/share/perl/5.24.1/Net/Async/Matrix. вечера 292.

и я не понимаю этого Когда я ввожу строку, как test в тело, оно отправляется в комнату.

Источник

2 ответа

Решение

parse_formatted_message возвращает объект String::Tagged. Этот класс перегружает конкатенацию, так что "$sendername said: $msg" также возвращает объект String::Tagged. Этот объект передается sendmsg который пытается сериализовать его в JSON, но отказывается сериализовать объекты.

Исправить: заменить

my $msg = parse_formatted_message( $content );

с

my $msg = parse_formatted_message( $content )->str;
Источник

Я предполагаю, что это ошибка цитирования. Если вы посмотрите на Net::Async::Matrix::Room:

sub send_message
{
   my $self = shift;
   my %args = ( @_ == 1 ) ? ( type => "m.text", body => shift ) : @_;

   my $type = $args{msgtype} = delete $args{type} or
      croak "Require a 'type' field";

   $MSG_REQUIRED_FIELDS{$type} or
      croak "Unrecognised message type '$type'";

   foreach (@{ $MSG_REQUIRED_FIELDS{$type} } ) {
      $args{$_} or croak "'$type' messages require a '$_' field";
   }

   if( defined( my $txn_id = $args{txn_id} ) ) {
      $self->_do_PUT_json( "/send/m.room.message/$txn_id", \%args )
         ->then_done()
   }
   else {
      $self->_do_POST_json( "/send/m.room.message", \%args )
         ->then_done()
   }
}

type отправленное вами сообщение обрабатывается этим подпунктом, а затем фактическое сообщение передается _do_POST_json в Net::Async::Matrix,

Но вы отправили строку, содержащую :,

Так что я думаю, что происходит то, что это кодируется так:

use JSON;
use Data::Dumper;

my $json = encode_json ( {body => "m1ndgames: said test"});
print Dumper  $json;

Но ответ, который возвращается, в строке 292:

if( length $content and $content ne q("") ) {
         eval {
            $content = decode_json( $content );
            1;
         } or
            return Future->fail( "Unable to parse JSON response $content" );
         return Future->done( $content, $response );
      }

Поэтому я думаю, что происходит то, что удаленный сервер посылает вам неисправный код ошибки, а модуль не обрабатывает его должным образом - он ожидает JSON но на самом деле это не так.

Мое лучшее предположение будет - попробуйте бросить : из вашего сообщения, потому что я предполагаю, что происходит плохое цитирование. Но не видя код на стороне сервера, я не могу сказать точно.

Источник
Другие вопросы по тегам