Proc REPORT перемещает значение группы (заголовок строки) ближе к итоговым значениям

Question

У меня есть некоторые данные, которые структурированы, как показано ниже. Мне нужно создать таблицу с промежуточными итогами, итоговый столбец TypeA + TypeB и заголовок, который охватывает столбцы как заголовок таблицы. Кроме того, было бы идеально отображать разные имена в заголовках столбцов, а не имя переменной из набора данных. Я собрал некоторый предварительный код, чтобы получить промежуточные итоги и итоги, но не остальные.

data tabletest;
    informat referral_total $50. referral_source $20.;
    infile datalines delimiter='|';
    input referral_total referral_source TypeA TypeB ;
    datalines;
    Long Org Name | SubA | 12 | 5
    Long Org Name | SubB | 14 | 3
    Longer Org Name | SubC | 0 | 1
    Longer Org Name | SubD | 4 | 12
    Very Long Org | SubE | 3 | 11
    Very Long Org | SubF | 9 | 19
    Very Long Org | SubG | 1 | 22
    ;
    run;

Код, который я написал:

proc report data=tabletest nofs headline headskip;
column referral_total referral_source TypeA TypeB;
define referral_total / group ;
define referral_source / group;
define TypeA / sum ' ';
define TypeB / sum ' ';
break after referral_total /  summarize style={background=lightblue font_weight=bold };
rbreak after /summarize;
compute referral_total;
    if _break_ = 'referral_total' then
    do;
    referral_total = catx(' ', referral_total, 'Total');
    end;
else if _break_ in ('_RBREAK_') then
    do;
    referral_total='Total';
    end;
endcomp;
run;

Это желаемый результат:

Answer 1

DEFINE Заявление имеет возможность NOPRINT это приводит к тому, что столбец не отображается, однако переменные для него все еще доступны (слева направо) для использования в вычислительном блоке.

Укладка в column Оператор позволяет настраивать заголовки и интервалы столбцов. В блоке вычислений для столбцов, не относящихся к группе, вектор данных Proc REPORT разрешает доступ только к совокупным значениям в строке сведений или итоговой строке, поэтому вам нужно указать это.

В этом примере кода показано, как скрыт столбец _total, а в ячейки _источника в строках итоговых сумм и итогов отчета вводится скрытое значение _total. Переменная _source должна быть удлинена, чтобы вместить более длинные значения в переменной _total.

data tabletest;
  * ensure referral_source big enough to accommodate _total || ' TOTAL';

  length referral_total $50 referral_source $60;

  informat referral_total $50. referral_source $20.;
  infile datalines delimiter='|';
  input referral_total referral_source TypeA TypeB ;
datalines;
Long Org Name | SubA | 12 | 5
Long Org Name | SubB | 14 | 3
Longer Org Name | SubC | 0 | 1
Longer Org Name | SubD | 4 | 12
Very Long Org | SubE | 3 | 11
Very Long Org | SubF | 9 | 19
Very Long Org | SubG | 1 | 22
run;

proc report data=tabletest;
  column 
  ( 'Table 1 - Stacking gives you custom headers and hierarchies'
    referral_total 
    referral_source 
    TypeA TypeB
    TypeTotal
  );
  define referral_total / group noprint;                 * hide this column;
  define referral_source / group;
  define TypeA / sum 'Freq(A)';                          * field labels are column headers;
  define TypeB / sum 'Freq(B)';
  define TypeTotal / computed 'Freq(ALL)';               * specify custom computation;
  break after referral_total /  summarize style={background=lightblue font_weight=bold };
  rbreak after /summarize;

  /*
   * no thanks, doing this in the _source compute block instead;
  compute referral_total;
      if _break_ = 'referral_total' then
      do;
      referral_total = catx(' ', referral_total, 'Total');
      end;
  else if _break_ in ('_RBREAK_') then
      do;
      referral_total='Total';
      end;
  endcomp;
  */

  compute referral_source;
    * the referral_total value is available because it is left of me. It just happens to be invisible;
    * at the break lines override the value that appears in the _source cell, effectively 'moving it over';
    select (_break_);
      when ('referral_total') referral_source = catx(' ', referral_total, 'Total');
      when ('_RBREAK_') referral_source = 'Total';
      otherwise;
    end;
  endcomp;

  compute TypeTotal;
    * .sum is needed because the left of me are groups and only aggregate values available here;
    TypeTotal = Sum(TypeA.sum,TypeB.sum); 
  endcomp;
run;