.NET Generics, получить значение члена объекта по имени

Question

Я передаю 2 общих объекта и строку в функцию, и я хотел бы найти свойство объектов, которые соответствуют строке и сравнить их значения.

Вот пример модели:

Public Structure Foo
    Public Bar As String
    Public Nan As String
    Public Tucket As String
End Structure

и вызывающий класс:

<TestMethod()> 
Public Sub TestEquality_Class_Pass_Identifier()
    _tester = new GeneralAssert
    Dim expectedFoo = New Foo With {.Bar = "asdf", .Nan = "zxcv", .Tucket = "qwer"}
    Dim actualFoo = New Foo With {.Bar = "qwer", .Nan = "zxcv", .Tucket = "qwer"}
    _tester.TestEquality(expectedFoo, actualFoo, "Bar")
End Sub

Класс Generic Assert, который будет выполнять бизнес-логику

Public Class GenericAssert
    Public Sub TestEquality(Of t)(expected As t, actual As t, Optional identifier As String = Nothing)
        Dim expectedType = expected.GetType(), actualType = actual.GetType()
        Assert.AreEqual(expectedType, actualType)

        If (Not identifier Is Nothing) Then
            Dim expectedProperty = expectedType.GetMember(identifier).FirstOrDefault()
            Dim actualProperty = actualType.GetMember(identifier).FirstOrDefault()

            TestEquality(*WhatHere1*, *WhatHere2*)
        End If
    End Sub
End Class

Ожидаемым результатом будет то, что член коллегии expectedFoo ("asdf") и actualFoo ("qwer") будет сравниваться. Я не могу найти значения в FieldInfo, PropertyInfo или MemberInfo, которые позволили бы мне получить значение, назначенное этому свойству по имени.

Answer 1

Поскольку и природа структуры, и то, что проверяется, известны, я использовал объекты FieldInfo как самый простой способ получения значений поля.

Public Sub TestEquality(Of t)(expected As t, actual As t, Optional identifier As String = Nothing)
    Dim expectedType = expected.GetType()
    Dim actualType = actual.GetType()

    Assert.AreEqual(expectedType, actualType)

    If (identifier IsNot Nothing) Then
        Dim expectedField As FieldInfo = expectedType.GetField(identifier, BindingFlags.IgnoreCase Or BindingFlags.Public Or BindingFlags.Instance)
        Dim actualField As FieldInfo = actualType.GetField(identifier, BindingFlags.IgnoreCase Or BindingFlags.Public Or BindingFlags.Instance)

        Assert.AreEqual(expectedField.GetValue(expected), actualField.GetValue(actual))
    End If
End Sub

Answer 2

Я не понимаю, почему это не будет делать в этом случае:

Public Sub AssertEquality(Of T)(ByVal expected As T, ByVal actual As T, identifier As String)

    Dim expected_prop = expected.GetType().GetProperty(identifier, BindingFlags.Instance + BindingFlags.Public)
    Dim actual_prop = actual.GetType().GetProperty(identifier, BindingFlags.Instance + BindingFlags.Public)

    Dim expected_value = expected_prop.GetValue(expected, Nothing)
    Dim actual_value = actual_prop.GetValue(actual, Nothing)

    Assert.AreEqual(expected_value, acutal_value)

End Sub

Sub Main()

    Dim expectedFoo = New Foo With {.Bar = "asdf", .Nan = "zxcv", .Tucket = "qwer"}
    Dim actualFoo = New Foo With {.Bar = "qwer", .Nan = "zxcv", .Tucket = "qwer"}

    AssertEquality(expectedFoo, actualFoo, "Bar")

End Sub