Складные и моноидные типы

Question

Я пытаюсь написать функции, которые добавляют и умножают все элементы в списке, используя моноиды и Foldable. Я установил некоторый код, который, я думаю, работает:

data Rose a = a :> [Rose a]
    deriving (Eq, Show)

instance Functor Rose where
    fmap f rose@(a:>b) = (f a :> map (fmap f) b) 

class Monoid a where
    mempty ::           a
    (<>)   :: a -> a -> a

instance Monoid [a] where
    mempty = []
    (<>)   = (++)

newtype Sum     a = Sum     { unSum     :: a } deriving (Eq, Show)
newtype Product a = Product { unProduct :: a } deriving (Eq, Show)

instance Num a => Monoid (Sum a) where
    mempty           = Sum 0
    Sum n1 <> Sum n2 = Sum (n1 + n2)

instance Num a => Monoid (Product a) where
    mempty                   = Product 1
    Product n1 <> Product n2 = Product (n1 * n2)

class Functor f => Foldable f where
    fold    :: Monoid m =>             f m -> m
    foldMap :: Monoid m => (a -> m) -> f a -> m
    foldMap f a = fold (fmap f a)

instance Foldable [] where
    fold = foldr (<>) mempty

instance Foldable Rose where
    fold (a:>[]) = a <> mempty
    fold (a:>b)  = a <> (fold (map fold b))

И затем, после определения различных экземпляров Foldable и типов Sum и Product, я хочу определить две функции, которые соответственно умножают элементы в структуре данных, но это приводит к ошибкам, которые я не знаю, как интерпретировать, я должен признать, что я это это была скорее догадка, чем реальная логика, так что подробное объяснение вашего ответа будет приветствоваться.

fsum, fproduct :: (Foldable f, Num a) => f a -> a
fsum b     = foldMap Sum b
fproduct b = foldMap Product b

Ошибка:

Assignment3.hs:68:14: error:
    * Occurs check: cannot construct the infinite type: a ~ Sum a
    * In the expression: foldMap Sum b
      In an equation for `fsum': fsum b = foldMap Sum b
    * Relevant bindings include
        b :: f a (bound at Assignment3.hs:68:6)
        fsum :: f a -> a (bound at Assignment3.hs:68:1)
   |
68 | fsum b     = foldMap Sum b
   |              ^^^^^^^^^^^^^

Assignment3.hs:69:14: error:
    * Occurs check: cannot construct the infinite type: a ~ Product a
    * In the expression: foldMap Product b
      In an equation for `fproduct': fproduct b = foldMap Product b
    * Relevant bindings include
        b :: f a (bound at Assignment3.hs:69:10)
        fproduct :: f a -> a (bound at Assignment3.hs:69:1)
   |
69 | fproduct b = foldMap Product b
   |              ^^^^^^^^^^^^^^^^^

Answer 1

Если вы используете Sum (или же Product) в foldMap, вы сначала сопоставите элементы в Foldable в Sumс (или Productс). Поэтому результат fsum будет - как вы определили это - будет Sum aне a:

fsum :: (Foldable f, Num a) => f a -> Sum a
fsum b = foldMap Sum b

Для того, чтобы получить значение, которое обернуто в Sum конструктор, вы можете получить его с unSum :: Sum a -> a геттер:

fsum :: (Foldable f, Num a) => f a -> a
fsum b = unSum (foldMap Sum b)

или после eta-сокращения:

fsum :: (Foldable f, Num a) => f a -> a
fsum = unSum . foldMap Sum

То же самое должно произойти для Product,