Проблема с блоком PL/SQL: данные не найдены

SET SERVEROUTPUT ON
DECLARE
    v_student_id NUMBER := &sv_student_id;
    v_section_id NUMBER := 89;
    v_final_grade NUMBER;
    v_letter_grade CHAR(1);
BEGIN
    SELECT final_grade
    INTO v_final_grade
    FROM enrollment
    WHERE student_id = v_student_id
    AND section_id = v_section_id;

    CASE -- outer CASE
        WHEN v_final_grade IS NULL THEN
            DBMS_OUTPUT.PUT_LINE ('There is no final grade.');
        ELSE
            CASE -- inner CASE
                WHEN v_final_grade >= 90 THEN v_letter_grade := 'A';
                WHEN v_final_grade >= 80 THEN v_letter_grade := 'B';
                WHEN v_final_grade >= 70 THEN v_letter_grade := 'C';
                WHEN v_final_grade >= 60 THEN v_letter_grade := 'D';
                ELSE v_letter_grade := 'F';
            END CASE;

            -- control resumes here after inner CASE terminates
            DBMS_OUTPUT.PUT_LINE ('Letter grade is: '||v_letter_grade);
    END CASE;
    -- control resumes here after outer CASE terminates
END;

Приведенный выше код, который я взял из книги "Oracle PL/SQL на примере, 4-е издание 2009", моя проблема, когда я вхожу student_id нет в таблице, он возвращает мне следующую ошибку

Отчет об ошибке: ORA-01403: данные не найдены
ORA-06512: в строке 7
01403. 00000 -  "данные не найдены"
* Причина:    
* Действие:

но согласно книге он должен был вернуть нулевое значение и затем следовать за регистром.

Источник

5 ответов

Решение

Когда вы выбираете INTO переменную и записи не возвращаются, вы должны получить ошибку NO DATA FOUND. Я полагаю, что правильный способ написания приведенного выше кода - заключить оператор SELECT в собственный блок BEGIN/EXCEPTION/END. Пример:

...
v_final_grade NUMBER;
v_letter_grade CHAR(1);
BEGIN

    BEGIN
    SELECT final_grade
      INTO v_final_grade
      FROM enrollment
     WHERE student_id = v_student_id
       AND section_id = v_section_id;

    EXCEPTION
      WHEN NO_DATA_FOUND THEN
        v_final_grade := NULL;
    END;

    CASE -- outer CASE
      WHEN v_final_grade IS NULL THEN
      ...
Источник

Есть альтернативный подход, который я использовал, когда не мог положиться на EXCEPTION блок в нижней части моей процедуры. У меня были переменные, объявленные в начале:

my_value VARCHAR := 'default';
number_rows NUMBER := 0;
.
.
.
SELECT count(*) FROM TABLE INTO number_rows (etc.)

IF number_rows > 0 -- Then obtain my_value with a query or constant, etc.
END IF;
Источник

Ваш SELECT Заявление не находит данные, которые вы ищете. То есть в ENROLLMENT таблица с учетом STUDENT_ID а также SECTION_ID, Вы можете попробовать положить некоторые DBMS_OUTPUT.PUT_LINE перед запуском запроса, выводя значения v_student_id а также v_section_id, Они могут не содержать то, что вы ожидаете от них.

Источник

Возможно, стоит проверить в Интернете раздел ошибок для вашей книги.

Вот пример обработки этого исключения здесь http://www.dba-oracle.com/sf_ora_01403_no_data_found.htm

Источник

Эти данные не найдены причины из-за некоторого типа данных, который мы используем.

как выбрать empid в v_test

выше empid и v_test должен быть числовым типом, тогда будут храниться только данные.

Так что следите за типом данных, при получении этой ошибки может быть это поможет

Источник
Другие вопросы по тегам