Как использовать hsc2hs для привязки к константам, функциям и структурам данных?

Question

Мне нужен пример, как использовать hsc2hs, я подумал, что когда я пишу заголовочный файл, например:

// foo.h
#define PI 3.14159

typedef struct {
    int i1;
    int i2;
} foo;

struct foo2 {
    int i1;
    int i2;
};

int fooFkt(foo f);

и затем создайте файл hsc как:

import Foreign
import Foreign.C

#include "foo.h"

использование hsc2hs:

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

я не понимаю, я думал, что hsc2hs будет импортировать все необходимые вещи для меня, как PI

кто может дать мне лучший пример?

Answer 1

Следуя RWH ch 17, вам нужно представить что-то, что связывает C PI значение символа в Haskell.

Например:

{-# LANGUAGE ForeignFunctionInterface #-}
{-# LANGUAGE CPP                      #-}

import Foreign
import Foreign.C

-- helpers
import Control.Applicative
import Control.Monad

#include "foo.h"

-- binding a symbol

-- Note that hsc2hs can't marshal floating point CPP values, so this will be "3"
-- c_pi :: CInt
-- c_pi = #const PI

-- Instead, bind to a function that returns a CFloat
pi' :: Float
pi' = realToFrac c_pi

foreign import ccall unsafe "my_pi" c_pi :: CFloat

И пока мы здесь, мы также можем упорядочить структуру в и из Haskell:

-- Marshalling for the struct foo

data Foo = Foo { i1, i2 :: Int }
    deriving Show

-- Define how to marshal foo structs

instance Storable Foo where
    sizeOf    _ = #{size foo}

    alignment _ = alignment (undefined :: CInt)

    poke p foo  = do
        #{poke foo, i1} p $ i1 foo
        #{poke foo, i2} p $ i2 foo

    peek p = return Foo
              `ap` (#{peek foo, i1} p)
              `ap` (#{peek foo, i2} p)

И привязать к fooFkt функция:

-- Import the function too

foreign import ccall "foo.h fooFkt"
    c_fooFkt :: Ptr Foo -> IO CInt

-- Marshal data to and from C

fooFkt :: Foo -> IO Int
fooFkt f = fromIntegral <$> with f c_fooFkt

Готово.

Answer 2

Это работает, если вы действительно используете некоторые определения из foo.h:

import Foreign
import Foreign.C

#include "foo.h"

pi = #const PI

дает

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

pi = 3
{-# LINE 7 "test.hsc" #-}

Вот реальный пример использования из сетевого пакета: https://github.com/haskell/network/blob/master/Network/Socket/ByteString/MsgHdr.hsc