Как войти в систему под именем пользователя?

Как получить текущее имя пользователя в проекте Firemonkey Delphi? Я ориентируюсь как на Windows, так и на Mac.

У меня есть XE2, но я полагаю, что любая версия подходит, потому что я буду обновлять при необходимости.

Источник

3 ответа

Решение

Для Windows вы можете использовать GetUserName Функция WinAPi, для OSX вы можете использовать NSUserName и / или NSFullUserName методы.

Попробуйте этот пример для OSX

{$APPTYPE CONSOLE}

{$R *.res}

uses
  Macapi.CoreFoundation,
  Macapi.Foundation,
  System.SysUtils;

function NSUserName: Pointer; cdecl; external '/System/Library/Frameworks/Foundation.framework/Foundation' name _PU +'NSUserName';
function NSFullUserName: Pointer; cdecl; external '/System/Library/Frameworks/Foundation.framework/Foundation' name _PU + 'NSFullUserName';

begin
  try
    Writeln(Format('User Name      %s',[TNSString.Wrap(NSUserName).UTF8String]));
    Writeln(Format('Full User Name %s',[TNSString.Wrap(NSFullUserName).UTF8String]))
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Для Windows

{$APPTYPE CONSOLE}


uses
  Windows,
  SysUtils;

function WUserName: String;
var
  nSize: DWord;
begin
 nSize := 1024;
 SetLength(Result, nSize);
 if GetUserName(PChar(Result), nSize) then
   SetLength(Result, nSize-1)
 else
   RaiseLastOSError;
end;


begin
  try
   Writeln(WUserName);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  readln;
end.

Составлено в единый блок:

uses
  {$IFDEF MACOS}
  MacApi.CoreFoundation, MacApi.Foundation,
  {$ENDIF}
  {$IFDEF MSWINDOWS}
  Windows,
  {$ENDIF}
  System.SysUtils;

{$IFDEF MACOS}
function NSUserName: Pointer; cdecl; external '/System/Library/Frameworks/Foundation.framework/Foundation' name '_NSUserName';
{$ENDIF}

function GetUserName: String;
{$IFDEF MSWINDOWS}
var
  nSize: DWord;
{$ENDIF}
begin
  {$IFDEF MACOS}
  Result := TNSString.Wrap(NSUserName).UTF8String;
  {$ENDIF}
  {$IFDEF MSWINDOWS}
  nSize := 1024;
  SetLength(Result, nSize);
  if Windows.GetUserName(PChar(Result), nSize) then
  begin
    SetLength(Result, nSize - 1)
  end
  else
  begin
    RaiseLastOSError;
  end
  {$ENDIF}
end;
Источник

Другое простое решение - получить имя компьютера через переменную окружения с помощью функции GetEnvironmentVariable следующим образом:

Result := GetEnvironmentVariable('USERNAME');

Это решение предназначено для Windows и Linux, но вам нужно проверить исходный код Delphi, если он поддерживается.

Источник

Более простой ответ для пользователей Windows

      function CurrentUserName:String;  
var  
  UserName: array[0..127] of Char;  
  Size:DWord;  
begin  
  Size:=SizeOf(UserName);  
  GetUserName(UserName,Size);  
  Result:=UserName;  
end;

от edn

Источник
Другие вопросы по тегам