Как использовать функцию GOOGLEFINANCE(("CURRENCY:EURAUD"))
Эта функция:
GOOGLEFINANCE(("CURRENCY:EURAUD"))
хорошо работает в Google Spreadsheets, я искал в Интернете вверх и вниз некоторую документацию относительно этой функции и как она используется, самое близкое, что я получил, было это
http://www.google.com/finance?q=EURAUD
Кто-нибудь знает, как использовать этот? или где найти документацию по этой функции?
7 ответов
Ну вот:
https://support.google.com/docs/answer/3093281
Это вся документация, которую предоставляет Google.
Конкретные инструкции для того, что вы ищете, находятся здесь: https://support.google.com/docs/answer/3093281
Помните, что в ваших формулах таблиц Google может использоваться точка с запятой (;) вместо запятой (,) в зависимости от региональных настроек.
Однажды сделанная замена на некоторых примерах выглядела бы так:
=GoogleFinance("CURRENCY:USDEUR")
=INDEX(GoogleFinance("USDEUR","price",today()-30,TODAY()),2,2)
=SPARKLINE(GoogleFinance("USDEUR","price",today()-30,today()))
Обменный курс евро к норвежскому крону на первое января 2016 года:
=INDEX(GOOGLEFINANCE("CURRENCY:EURNOK"; "close"; DATE(2016;1;1)); 2; 2)
INDEX() Функция используется потому, что GOOGLEFINANCE() функция на самом деле печатает в 4 отдельных ячейках (2x2), когда вы вызываете ее с этими аргументами, с результатом будет только одна ячейка.
Имейте в виду, что GoogleFinance() функция не работает на 100% в новой версии Google Sheets. Например, преобразование из USD в GBP используя формулу GoogleFinance("CURRENCY:USDGBP") дает 0.603974 в старой версии, но только 0,6 в новой. Похоже, есть ошибка округления.
Некоторые валютные пары не имеют исторических данных за определенные дни.
Сравнить =GOOGLEFINANCE("CURRENCY:EURNOK", "close", DATE(2016,1,1), DATE(2016,1,12):
Date Close
1/1/2016 23:58:00 9.6248922
1/2/2016 23:58:00 9.632922114
1/3/2016 23:58:00 9.579957264
1/4/2016 23:58:00 9.609146435
1/5/2016 23:58:00 9.573877808
1/6/2016 23:58:00 9.639368875
1/7/2016 23:58:00 9.707103569
1/8/2016 23:58:00 9.673324479
1/9/2016 23:58:00 9.702379872
1/10/2016 23:58:00 9.702721875
1/11/2016 23:58:00 9.705679083
а также =GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1), DATE(2016,1,12):
Date Close
1/1/2016 23:58:00 79.44402768
1/4/2016 23:58:00 79.14048175
1/5/2016 23:58:00 80.0452446
1/6/2016 23:58:00 80.3761125
1/7/2016 23:58:00 81.70830185
1/8/2016 23:58:00 81.70680013
1/11/2016 23:58:00 82.50853122
Так, =INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1)), 2, 2) дает
79.44402768
Но =INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2)), 2, 2) дает
#N/A
Следовательно, при работе с валютными парами, для которых нет обменных курсов на выходные / праздничные дни, можно использовать следующую формулу для получения обменного курса на первый следующий рабочий день:
=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2), 4), 2, 2)
=INDEX(GoogleFinance("CURRENCY:" & "EUR" & "USD", "price", A2), 2, 2)
где A2 является ячейкой с датой в формате даты.
Замените "EUR" и "USD" на вашу валютную пару.
Синтаксис:
= GOOGLEFINANCE (тикер, [attribute], [start_date], [num_days|end_date], [interval])
=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")
=GOOGLEFINANCE("GOOG","price",TODAY()-30,TODAY())
=GOOGLEFINANCE(A2,A3)
=117.80*Index(GOOGLEFINANCE("CURRENCY:EURGBP", "close", DATE(2014,1,1)), 2, 2)
Например, если вы хотите конвертировать курс на конкретную дату, вот несколько более сложных примеров:
=IF($C2 = "GBP", "", Index(GoogleFinance(CONCATENATE("CURRENCY:", C2, "GBP"), "close", DATE(year($A2), month($A2), day($A2)), DATE(year($A2), month($A2), day($A2)+1), "DAILY"), 2))
где $A2 ваша дата (например, 01/01/2015) а также C2 ваша валюта (например, EUR).
См. Больше примеров в Справке редактора Документов в Google.
Вы должны использовать знак равенства в поле формулы
=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")