Вызов хранимой процедуры MySQL с использованием VB6 с параметром OUT

Question

Я написал эту процедуру в MySQL (Server 5.5)

DELIMITER $$

DROP PROCEDURE IF EXISTS `InsertList` $$

CREATE DEFINER=`root`@`localhost` PROCEDURE `InsertList`(IN fName VARCHAR(20), IN fType VARCHAR(3), IN fFood varchar(20), Out fResult int)

BEGIN

  insert into tblguest (firstname, confirm, food) values (fName, fType, fFood);

  select count(id) from tblguest into fResult;

END $$

DELIMITER ;

Когда я вызываю эту процедуру из MySQL Query Browser, она возвращается, как и ожидалось

Call InsertList ('V1', 'No', 'F1', @result);

Select @result; 

-> Успешно возвращает количество идентификаторов в таблице

Я написал следующий код в VB6

Dim res As Integer
On Error GoTo chkErr

Set cmd = New ADODB.Command
cmd.ActiveConnection = cn
cmd.CommandType = adCmdStoredProc
cmd.CommandText = "InsertList"

cmd.Parameters.Append cmd.CreateParameter("fName", adVarChar, adParamInput, 20, Text3.Text)
cmd.Parameters.Append cmd.CreateParameter("fType", adVarChar, adParamInput, 3, Text2.Text)
cmd.Parameters.Append cmd.CreateParameter("fFood", adVarChar, adParamInput, 20, Text1.Text)
cmd.Parameters.Append cmd.CreateParameter("fResult", adInteger,adParamOutput)

cmd.Execute

res = cmd("fResult")
MsgBox res
Exit Sub

chkErr:

    Select Case Err.Number
        Case Else
            Text4.Text = Err.Number & " - " & Err.Description
    End Select

Но в тот момент, когда он пытается запустить заявление cmd.execute выдает следующую ошибку:

-2147467259 - [MySQL] [Драйвер ODBC 5.1][mysqld-5.5.34] Аргумент 4 OUT или INOUT для подпрограммы dbtest.InsertList не является переменной или новой псевдопеременной в триггере BEFORE.

Я видел коды, работающие для SQL, поэтому проблема в том, что сам MySQL использует хранимую процедуру с параметром OUT?

Answer 1

Кажется, нерешенная ошибка в MySQL ODBC и C/API

Одним из решений является выполнение этого с помощью команды SQL с подготовленными переменными:

Dim rs As ADODB.Recordset 

Set cmd = New ADODB.Command
cmd.ActiveConnection = cn
cmd.CommandType = adCmdText
cmd.CommandText = "call InsertList(?,?,?,@fResult)"

cmd.Parameters.Append cmd.CreateParameter("fName", adVarChar, adParamInput, 20, Text3.Text)
cmd.Parameters.Append cmd.CreateParameter("fType", adVarChar, adParamInput, 3, Text2.Text)
cmd.Parameters.Append cmd.CreateParameter("fFood", adVarChar, adParamInput, 20, Text1.Text)

cmd.Execute

'And after that, using the same connection, get the value of 
'@fResult from a single query:

Set rs = cn.Execute("select @fResult as fResult")
MsgBox rs!fResult

Вы получите ожидаемое значение.