Common lisp: переопределить существующую функцию в области видимости?

Question

В Common Lisp возможно ли переопределить уже определенную функцию в определенной области? Например, учитывая функцию A, которая вызывает функцию B. Могу ли я временно переопределить B во время вызова A?

Я ищу что-то вроде блока let, но это может переопределить функции.

Answer 1

В рамках данной лексической области, да. Используйте FLET или LABELS. Любая функция, определенная с помощью FLET, не сможет вызывать функции, определенные в той же лексической области, если вы этого хотите (например, для саморекурсивной группы взаимно рекурсивных функций), вам нужно будет использовать LABELS.

Обратите внимание, что как FLET, так и LABELS устанавливают только лексическое теневое копирование, их не следует использовать для теневого копирования функций из пакета COMMON-LISP, и оно не будет динамически изменять то, какая функция вызывается вне лексического контекста, установленного формой.

Answer 2

Локальные функции могут быть введены с помощью FLET и LABELS.

Answer 3

Если вы хотите переопределить / скрыть существующую функцию, используя динамическую область видимости, это макрос, который я использовал некоторое время.

(defmacro! with-shadow ((fname fun) &body body)
  "Shadow the function named fname with fun
   Any call to fname within body will use fun, instead of the default function for fname.
   This macro is intentionally unhygienic:
   fun-orig is the anaphor, and can be used in body to access the shadowed function"
  `(let ((fun-orig))
     (cond ((fboundp ',fname)
            (setf fun-orig (symbol-function ',fname))
            (setf (symbol-function ',fname) ,fun)
            (unwind-protect (progn ,@body)
              (setf (symbol-function ',fname) fun-orig)))
           (t
            (setf (symbol-function ',fname) ,fun)
            (unwind-protect (progn ,@body)
              (fmakunbound ',fname))))))

Использование:

Clozure Common Lisp Version 1.9-r15759  (DarwinX8664)  Port: 4005  Pid: 4728
; SWANK 2012-03-06
CL-USER>  
(defun print-using-another-fname (x)
  (print x))
PRINT-USING-ANOTHER-FNAME

CL-USER> 
(let ((*warn-if-redefine-kernel* nil))
  (with-shadow (print (lambda (x)
                        (funcall fun-orig (+ x 5))))
    (print-using-another-fname 10)))

15 
15
CL-USER>                
(print 10)

10 
10
CL-USER> 

Обратите внимание, что это зависит от defmacro Дуга Хойта! макрос, доступный в Let Over Lambda.

Кроме того, как написано, это анафорический (веселье ориг доступно в теле). Если вы хотите, чтобы это было абсолютно гигиенично, просто измените fun-orig на g! Fun-orig.

Я чаще всего переопределяю функции при написании модульных тестов. Полезно использовать функции имитации в рамках конкретного модульного теста, и иногда это необходимо выполнять с помощью динамической (не лексической) области.

Answer 4

Вы можете смоделировать динамическое связывание для забав:

(defmacro setvfun (symbol function)
      `(progn
         (setf ,symbol ,function)
         (setf (symbol-function ',symbol) (lambda (&rest args) (apply (symbol-value ',symbol) args)))))

а затем, например, с

(setvfun some-fun (lambda() (format t "initial-definition~%")))
(defun test-the-fun (&rest args) (apply #'some-fun args))

(defun test ()
   (test-the-fun)
   (flet ((some-fun () (format t "Lexically REDEFINED (if you see this, something is very wrong)~%")))
      (test-the-fun))
   (let ((some-fun (lambda (x) (format t "Dynamically REDEFINED with args: ~a~%" x))))
       (declare (special some-fun))
       (test-the-fun "Hello"))
   (test-the-fun))

ты получаешь:

REPL> (test)
==>initial-definition
==>initial-definition
==>Dynamically REDEFINED with args: Hello
==>initial-definition