InnoSetup: как добавить разрыв строки в описании компонента

Question

Я пытаюсь добавить разрыв строки в середине моего описания для моих компонентов. Но я не могу найти правильный синтаксис для этого.

[Components]
Name: Component A; Description: "This is component A:" + NewLine + "My component A has this stuff";

Answer 1

Разрывы строки не поддерживаются для [Components] записей раздела, но вы можете изменить описания элементов вашего компонента из кода (к сожалению, доступ к свойству, в котором хранится описание, индексируется, и нет способа найти индекс по имени компонента).

В этом примере показано, как изменить описание первого элемента компонента (индексирование основано на 0) и как добавить к нему разрыв строки:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[Components]
Name: "app"; Description: "Description is changed in [Code] section"
Name: "readme"; Description: "Readme File"

[Code]
procedure InitializeWizard;
begin
  WizardForm.ComponentsList.ItemCaption[0] :=
    'Lorem ipsum dolor sit amet, consectetur adipiscing elit. Sed id venenatis' + #13#10 +
    'erat, ac vehicula sapien. Etiam convallis ligula eros, in ullamcorper turpis' + #13#10 +
    'pulvinar sit amet.';
end;

Answer 2

Для описания компонента вы можете определить пользовательское сообщение, где вы можете указать разрывы строк с помощью %n теги, например:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[CustomMessages]
ComponentDescription=Lorem ipsum dolor sit amet,%nconsectetur adipiscing elit.

[Components]
Name: "app"; Description: "{cm:ComponentDescription}"
Name: "readme"; Description: "Readme File"