Как переименовать тег с помощью XSLT

Я пытаюсь переименовать тег, используя XSLT в шаблоне ESB WSO2.

Все мои попытки приводят к одной и той же ошибке: невозможно создать OMElement с использованием результата XSLT.

Один из вариантов, которые я попробовал:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>
    <xsl:param name="response_tag"/>
    <xsl:template match="RESPONSE">
        <xsl:element name="{$response_tag}" >
            <xsl:for-each select="/RESPONSE/*">
                <xsl:copy>
                    <xsl:apply-templates select="@*|node()"/>
                </xsl:copy>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

Другой это:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>

    <xsl:param name="request_tag"/>
    <xsl:template match="RESPONSE">
        <xsl:element name="{$request_tag}">
            <xsl:apply-templates select="node() | @*" />
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

Что я делаю неправильно?

PS. Параметр response_tag значение похоже на rns:NameOfResponse Пространство имен (rns) а также NameOfResponse может отличаться каждый раз. Пространство имен находится внутри тега Envelope xml, поэтому, в конце концов (если преобразование работает), xml будет действительным.

Ввод будет что-то вроде:

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:rns="http://www.example.com/example">
   <soapenv:Header/>
   <soapenv:Body>
      <RESPONSE xmlns="http://ws.apache.org/ns/synapse">
         <tag>123</tag>
         <another_tag>20160622134457473</another_tag>
        ...
     </RESPONSE>
   </soapenv:Body>
</soapenv:Envelope>

Результат должен быть:

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:rns="http://www.example.com/example">
   <soapenv:Header/>
   <soapenv:Body>
      <rns:NameOfResponse>
         <tag>123</tag>
         <another_tag>20160622134457473</another_tag>
        ...
     </rns:NameOfResponse>
   </soapenv:Body>
</soapenv:Envelope>

PPS. Попытка удаления пространства имен из тега ответа - т.е. тег ответа выглядит так: NameOfTag сейчас. Та же ошибка

Источник

2 ответа

Решение

Я предполагаю, что вы хотите сделать что-то вроде этого:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:syn="http://ws.apache.org/ns/synapse"
xmlns="http://www.example.com/example"
exclude-result-prefixes="syn">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:param name="response_tag"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="syn:RESPONSE">
    <xsl:element name="{substring-after($response_tag, ':')}" >
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

<xsl:template match="syn:*">
    <xsl:element name="{local-name()}">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

Применяется к вашему примеру ввода с параметром response_tag='rns:NameOfResponse', результат будет:

<?xml version="1.0" encoding="UTF-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
   <soapenv:Header/>
   <soapenv:Body>
      <NameOfResponse xmlns="http://www.example.com/example">
         <tag>123</tag>
         <another_tag>20160622134457473</another_tag>
        ...
     </NameOfResponse>
   </soapenv:Body>
</soapenv:Envelope>

Обратите внимание, что NameOfResponse Элемент объявляет пространство имен по умолчанию - и это наследуется его потомками, так же, как и в ваших входных данных.

ДОБАВЛЕНО:

Чтобы получить точный результат, показанный в вашем вопросе, вы можете сделать:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:syn="http://ws.apache.org/ns/synapse"
exclude-result-prefixes="syn">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:param name="response_tag"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="syn:RESPONSE">
    <xsl:element name="{$response_tag}" namespace="http://www.example.com/example">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

<xsl:template match="syn:*">
    <xsl:element name="{local-name()}">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

Предостережение: я ничего не знаю о WSO2; Вот как это должно работать в XSLT.

Источник

Отправить эту полезную нагрузку:

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
   <soapenv:Header/>
   <soapenv:Body>
      <RESPONSE>
         <tag>123</tag>
         <another_tag>20160622134457473</another_tag>
     </RESPONSE>
   </soapenv:Body>
</soapenv:Envelope>

Для этого прокси:

<?xml version="1.0" encoding="UTF-8"?>
<proxy xmlns="http://ws.apache.org/ns/synapse" name="TestSOF" transports="http" statistics="disable" trace="disable" startOnLoad="true">
    <target>
        <inSequence>
            <property name="FORCE_SC_ACCEPTED" value="true" scope="axis2"/>
            <property name="RequestTagNamespace" value="http://wso2.com"/>
            <property name="RequestTagName" value="NameOfResponse"/>
            <xslt key="SOFXSL">
                <property name="request_tag_namespace" expression="get-property('RequestTagNamespace')"/>
                <property name="request_tag" expression="get-property('RequestTagName')"/>
            </xslt>
            <log level="full"/>
        </inSequence>
    </target>
    <description/>
</proxy>

С помощью этой таблицы стилей xsl в локальных записях:

<?xml version="1.0" encoding="UTF-8"?>
<localEntry xmlns="http://ws.apache.org/ns/synapse" key="SOFXSL">
    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
        <xsl:output method="xml" encoding="utf-8" indent="yes" omit-xml-declaration="yes"/>
        <xsl:param name="request_tag_namespace"/>
        <xsl:param name="request_tag"/>
        <xsl:template match="RESPONSE">
            <xsl:element name="myns:{$request_tag}" namespace="{$request_tag_namespace}">
                <xsl:apply-templates/>
            </xsl:element>
        </xsl:template>
        <xsl:template match="@*|*|comment()">
            <xsl:copy>
                <xsl:apply-templates select="@*|*|text()|comment()|processing-instruction()"/>
            </xsl:copy>
        </xsl:template>
    </xsl:stylesheet>
   <description/>
</localEntry>

И вы получите такой результат:

<?xml version="1.0" encoding="UTF-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
  <soapenv:Body>
      <myns:tagname xmlns:myns="http://tagnamespace">
         <tag>123</tag>
         <another_tag>20160622134457473</another_tag>
     </myns:tagname>
   </soapenv:Body>
</soapenv:Envelope>
Источник
Другие вопросы по тегам