Delphi DBGrid условно dbcombo

Question

У меня есть таблица с двумя столбцами. ConfigItem и ConfigValue. Теперь я хочу заполнить это в dbgrid, где ConfigValue должен быть dbcombobox.

Образец ConfigItem (первый столбец)

Товар

Тип продукта

Тип элемента

Предметы

ConfigValue должен иметь dbcombobox, а элементы комбинированного списка должны заполняться на основе значений в первом столбце.

Пример. Если пользователь нажимает на первую строку, в которой продукт как элемент конфигурации, то для столбца ConfigValue той же строки в сетке должен быть комбинированный список со списком продуктов.

Возможно, я могу использовать событие Grid BeforeDrawCell, однако я пытаюсь найти способ, с помощью которого это можно сделать с помощью компонента adoquery или набора данных.

Может кто-нибудь, пожалуйста, руководство по решению этой проблемы.

Заранее спасибо, Дивьеш

Answer 1

Вы можете использовать AfterScrollEvent, чтобы назначить PickList для вашего столбца.
Список выбора - это список строк, назначенный объекту основного списка строк. В зависимости от версии Delphi вы можете использовать общий словарь.

unit Unit2;
interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, Grids, DBGrids, ADODB;

type
  TForm2 = class(TForm)
    ADODataSet1: TADODataSet;
    DBGrid1: TDBGrid;
    DataSource1: TDataSource;
    procedure FormCreate(Sender: TObject);
    procedure ADODataSet1AfterScroll(DataSet: TDataSet);
  private
    { Private-Deklarationen }
    FList: TStringList;
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.ADODataSet1AfterScroll(DataSet: TDataSet);
var
  idx: Integer;
begin
  if Assigned(FList) and (DBGrid1.Columns.Count > 1) then
  begin
    DBGrid1.Columns[1].ButtonStyle := cbsAuto;
    idx := FList.IndexOf(DBGrid1.Columns[0].Field.asString);
    if idx > -1 then
      DBGrid1.Columns[1].PickList := TStringList(FList.Objects[idx])
    else
      DBGrid1.Columns[1].PickList := nil;
  end;
end;

procedure TForm2.FormCreate(Sender: TObject);
var
  i: Integer;
begin  // some demo filling
  FList := TStringList.Create;
  FList.AddObject('A1A1', TStringList.Create);
  for i := 0 to 10 do
    TStringList(FList.Objects[FList.Count - 1]).Add(Format('group1_%d', [i]));
  FList.AddObject('A1A2', TStringList.Create);
  for i := 0 to 10 do
    TStringList(FList.Objects[FList.Count - 1]).Add(Format('group2_%d', [i]));
end;

procedure TForm2.FormDestroy(Sender: TObject);
var
  i: Integer;
begin
  for I := 0 to FList.Count - 1 do Flist.Objects[i].Free;
  FList.Free;
end;

end.