Используя вложенную таблицу как в параметре для процедуры

Question

У меня есть таблица T1, и я хочу вставить несколько строк одновременно через процедуру с использованием коллекции. Я написал код, но когда я пытаюсь выполнить его, выдает ошибку. Пожалуйста, порекомендуйте.

create table t1 ( id number , name varchar2(10));
/

create or replace PACKAGE PKG1 AS
   TYPE TAB_LIST IS TABLE OF T1%ROWTYPE;
   PROCEDURE PROC1 (p_val IN TAB_LIST);
END PKG1;
/

create or replace PACKAGE BODY PKG1 AS
PROCEDURE PROC1 (P_VAL IN TAB_LIST
                )
IS
BEGIN
    FOR i IN p_val.FIRST..p_val.LAST
    LOOP
        insert  INTO T1
            (
              id, name
            )
        VALUES
            (
              p_val(i).id,
              p_val(i).name
            );
        END LOOP;
    END;
END;

---

ошибка после выполнения

DECLARE
    p_val PKG1.TAB_LIST;
BEGIN
    p_val := PKG1.TAB_LIST(123,'XYZ');
END;

Error report -
ORA-06550: line 5, column 11:
PLS-00306: wrong number or types of arguments in call to 'TAB_LIST'
ORA-06550: line 5, column 11:
PLS-00306: wrong number or types of arguments in call to 'TAB_LIST'
ORA-06550: line 5, column 2:
PL/SQL: Statement ignored
06550. 00000 -  "line %s, column %s:\n%s"
*Cause:    Usually a PL/SQL compilation error.
*Action:

Answer 1

DECLARE
    P_VAL PKG1.TAB_LIST := PKG1.TAB_LIST();
BEGIN
    P_VAL.extend;
    P_VAL(1).id := 123;
    P_VAL(1).name := 'XYZ';
    PKG1.PROC1( P_VAL );
END;

пример для нескольких записей:

DECLARE
    P_VAL PKG1.TAB_LIST := PKG1.TAB_LIST();
BEGIN
    for i in 1 .. 10
    loop
        P_VAL.extend;
        P_VAL(P_VAL.LAST).id := i;
        P_VAL(P_VAL.LAST).name := 'XYZ' || i;
    end loop;
    PKG1.PROC1( P_VAL );
END;

Answer 2

@hekko": это не строка. Извините за форматирование. Множественные значения (n) могут быть переданы из приложения, как это, и все должны быть вставлены в таблицу сразу.

123  'XYZ'
456  'DFK'
866  'HKK'

@Kaushik: это не строка, а проблема форматирования. Вопрос остается прежним: "У меня есть таблица T1, и я хочу вставить несколько строк за раз через процедуру, использующую коллекцию".