If-оператор: неполное выражение FLWOR

Question

У меня есть следующий код XQuery в редакторе BaseX, но он ошибается в предложении if, заявляя

Неполное выражение FLWOR: ожидание возврата

Код, который я пытаюсь использовать:

import module namespace functx = 'http://www.functx.com';
declare namespace file = "http://expath.org/ns/file";

let $root := 'E:\basex-index-testing\sonar-small\index'
let $ds := file:dir-separator()

(: get files in sonar-small database :)
for $f in db:list('sonar-small')
  (: remove *.xml from doc name :)
  let $corpus := substring($f, 1, string-length($f) - 4)
  for $alpino in db:open('sonar-small', $f)/treebank/alpino_ds
  (: make sure tree has sentence element :)
  where count($alpino/sentence) > 0
      let $sentenceId := data($alpino/@id)

      for $node in $alpino//node
      (: make sure there are less than 500 descendants, 
      less than 100 and more than 0 children :)
      where count($node//node) < 500 and count($node/node) > 0 
            and count($node/node) < 100
        let $catTop := data($node/@cat)

        (: create indexing pattern based on node's direct children :)
        let $childrenRelCat := ()
        for $child in $node/node
          let $childRel := data($child/@rel)
          (: use children's cat or pt attribute, default to '' :)
          let $childCat := data($child/(@cat, @pt, '')[1])
          (: concatenate childrenRelCat sequence (append to list) :)
          let $childrenRelCat := ($childrenRelCat, 
                                  string-join(($childRel, $childCat), '%'))

        let $bf := string-join(functx:sort($childrenRelCat), '_')
        let $sent := <tree id="{$sentenceId}">{$node}</tree>

        let $dir := concat($root, $ds, $catTop)
        (: this if-clause throws an error: missing return statement, 
        incomplete FWLOR:)
        if (file:exists($dir) and file:is-dir($dir))
          then ()
        else file:create-dir($dir)        

        (: append subtree to pattern-file :)
        file:append($dir || $bf || '-index.xml', $sent)
        (: doesn't have to return anything, but FWLOR demands it... :)
        return $f

Кажется, мне не хватает чего-то важного в том, как XQuery оценивает выражения или ожидает их упорядочения. Что не так в коде выше?

( Этот вопрос озаглавлен почти одинаково, но ответ, предоставленный там, не помогает, поскольку была другая ошибка в коде этого OP.)

Answer 1

Я думаю, что настоящая проблема здесь в том, что вы используете выражение if

if (file:exists($dir) and file:is-dir($dir))
          then () else file:create-dir($dir) 

чтобы добиться побочных эффектов, а не для того, чтобы вернуть результат. Хотя внешние функции, такие как file:create-dir(), могут иметь побочные эффекты, на самом деле XQuery не предназначен для работы, и поэтому вам нужно быть очень осторожным в том, как вы используете такие внешние функции. Более того, подробные правила о том, что работает, а что нет, могут варьироваться от одного процессора XQuery к другому.

Кроме того, конечно, ваш запрос должен соответствовать грамматике, и грамматика для выражения FLWOR говорит, что он состоит из последовательности предложений, каждое из которых является for, let, where, order-by, .... или пункт возврата. Так что ваше "если" выражение неуместно.

Я не знаю BaseX, но я думаю, что вероятно будет работать следующее:

let $dir := concat($root, $ds, $catTop)
return (
        if (file:exists($dir) and file:is-dir($dir))
          then ()
          else file:create-dir($dir),        
        file:append($dir || $bf || '-index.xml', $sent),
        $f
)