Создание моей собственной государственной монады

Question

Я понимаю, как использовать монады, но я не совсем понимаю, как их создать. Так что я нахожусь в путешествии, чтобы воссоздать государственную монаду.

До сих пор я создал новый тип Toto (foo по-французски) и сделал его экземпляром Monad. Сейчас я пытаюсь добавить "функцию читателя" к нему. Я создал класс TotoReader, который объявляет функцию "get". Но когда я пытаюсь создать экземпляр, все рушится. GHC говорит мне, что не может вывести (m ~ r) (полная ошибка компиляции внизу).

Но когда я создаю функцию верхнего уровня get, все работает правильно.

Итак, как я могу определить функцию get в классе и действительно ли это правильно? Что это я не понимаю?

Мой код ниже

{-# OPTIONS -XMultiParamTypeClasses #-}
{-# OPTIONS -XFlexibleInstances #-}

newtype Toto s val = Toto { runToto :: s -> (val, s) }

toto :: (a -> (b,a)) -> Toto a b
toto = Toto

class (Monad m) => TotoReader m r where
    get :: m r

instance Monad (Toto a) where
    return a = toto $ \x -> (a,x)
    p >>= v  = toto $ \x ->
                    let (val,c) = runToto p x
                    in runToto (v val) c

instance TotoReader (Toto m) r where 
    get = toto $ \x -> (x, x) -- Error here

-- This is working
-- get :: Toto a b
-- get = toto $ \s -> (s,s)


pp :: Toto String String
pp = do 
    val <- get
    return $ "Bonjour de " ++ val

main :: IO ()
main = print $ runToto pp "France"

Ошибка компиляции

test.hs:19:11:
    Could not deduce (m ~ r)
    from the context (Monad (Toto m))
      bound by the instance declaration at test.hs:18:10-30
      `m' is a rigid type variable bound by
          the instance declaration at test.hs:18:10
      `r' is a rigid type variable bound by
          the instance declaration at test.hs:18:10
    Expected type: Toto m r
      Actual type: Toto m m
    In the expression: toto $ \ x -> (x, x)
    In an equation for `get': get = toto $ \ x -> (x, x)
    In the instance declaration for `TotoReader (Toto m) r'

Answer 1

Давайте использовать ghci для проверки видов:

*Main> :k Toto
Toto :: * -> * -> *

Toto принимает два параметра типа: тип среды и тип возвращаемого значения. Если r это среда, Toto r будет конструктором типа монады.

*Main> :k TotoReader
TotoReader :: (* -> *) -> * -> Constraint

TotoReader принимает два параметра типа: конструктор типа монады и тип среды, которые в нашем случае Toto r а также r соответственно.

Итак, объявление экземпляра должно быть примерно таким:

instance TotoReader (Toto r) r where 
    get = toto $ \x -> (x, x)